# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
CHECKREQS_DISK_BUILD="1G"

inherit check-reqs eutils

MY_PN="${PN/-community-bin/}"
MY_PNF="${PN/-bin/}"
MY_FILE_64="${MY_PN}-${PV}-community-linux-x64-installer.run"
MY_FILE_86="${MY_PN}-${PV}-community-linux-installer.run"

DESCRIPTION="An electronic document and records management system (EDRMS)."
HOMEPAGE="http://www.openkm.org"
SRC_URI="amd64? ( mirror://sourceforge/${MY_PN}/${MY_FILE_64} )
		x86? ( mirror://sourceforge/${MY_PN}/${MY_FILE_86} )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND=""
RDEPEND="${DEPEND}"

QA_PREBUILT="opt/${MY_PNF}/*"
S="${WORKDIR}"

src_unpack() {
	cp -v ${DISTDIR}/"${A}" "${WORKDIR}" || die
	chmod +x "${WORKDIR}/${A}" || die
}

src_install() {
	local runfile
	use amd64 && runfile="${MY_FILE_64}"
	use x86 && runfile="${MY_FILE_86}"

	einfo "Ignore warnings of failure - it's just because it can't set menu entries"
	./${runfile} --mode unattended --prefix "${ED}/opt/${MY_PNF}"

	pushd "${ED}/opt/${MY_PNF}" || die

	# fix paths
	sed -e "s:${ED}::" -i openkm_stop.desktop -i openkm_start.desktop \
		-i tomcat/bin/setenv.sh || die
	
	# fix desktop files
	sed -e ':^Version:d' -i openkm_stop.desktop -i openkm_start.desktop || die
	sed -e 's:Office:&;:' -i openkm_stop.desktop -i openkm_start.desktop || die

	doicon --size 48 "${MY_PN}_48x48.png" || die "failed installing ${MY_PN}_48x48.png"
	domenu "${MY_PN}_start.desktop" || die "failed installing ${MY_PN}_start.desktop"
	domenu "${MY_PN}_stop.desktop" || die "failed installing ${MY_PN}_stop.desktop"
	popd || die
}