Re: [gentoo-lisp] Finally, a fix for bug #335418, now what?

[Erik Falor <ewfalor@gmail.com>]

[-- Attachment #1.1: Type: text/plain, Size: 1097 bytes --]

On Thu, Feb 23, 2012 at 10:14:07AM +0100, Marijn wrote:
> Hi Erik,
> 
> I notice that the SRC_URI contains an explicit version. Ideally we
> shouldn't have to adjust it once 4.7.1 and 4.8.0 come out. Would ${PV}
> not accomplish that?

${PV} does accomplish that.  Thank you for pointing this out.

> I also notice that the ebuild still unsets some variables (A ARCH). I
> consider it a bug if this is necessary. Have you checked whether it is
> still necessary? If so what is the state of fixing portage so we don't
> need to do this unsetting?

Unfortunately, this step is still necessary as those variables are
still in conflict with the Makefiles.

I was not aware that there had been any discussion by the portage devs
about this issue.  The only bug I could find is #127560 - is that the
effort you are talking about?  Or are you suggesting that we file a
new bug?

> Otherwise looks good.
> 
> Marijn

If you feel good about just the ${PV} fix, I'll check this in to the
overlay tonight.

-- 
Erik Falor
Registered Linux User #445632 http://linuxcounter.net

[-- Attachment #1.2: chicken-4.7.0.ebuild --]
[-- Type: text/plain, Size: 2159 bytes --]

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $


EAPI="3"

inherit eutils multilib

DESCRIPTION="Chicken is a Scheme interpreter and native Scheme to C compiler"
HOMEPAGE="http://www.call-cc.org/"
SRC_URI="http://code.call-cc.org/releases/${PV}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
IUSE="emacs"

DEPEND="sys-apps/texinfo
		emacs? ( virtual/emacs )"
RDEPEND="emacs? ( virtual/emacs app-emacs/scheme-complete )"

## the major mode for Chicken source
SITEFILE=50hen-gentoo.el

src_prepare() {
	#Because chicken's Upstream have a custom to use variables that also
	#portage uses. Fixes #393561
	unset A ARCH
	sed "s,\$(PREFIX)/lib,\$(PREFIX)/$(get_libdir)," -i defaults.make || die "sed failed"
	sed "s,\$(DATADIR)/doc,\$(SHAREDIR)/doc/${P}," -i defaults.make || die "sed failed"
}

src_compile() {
	OPTIONS="PLATFORM=linux PREFIX=/usr"
	#Because chicken's Upstream have a custom to use variables that also
	#portage uses. Fixes #393561
	unset A ARCH

	#upstream does not yet support parallel builds, bug 265881
	#LINKER_OPTIONS doesn't seem to be incorporated into Makefile.linux -
	#might have to patch it...
	emake -j1 ${OPTIONS} C_COMPILER_OPTIMIZATION_OPTIONS="${CFLAGS}" \
		LINKER_OPTIONS="${LDFLAGS}" \
		HOSTSYSTEM="${CBUILD}" || die "emake failed"
}

# chicken's testsuite is not runnable before install
# upstream has been notified of the issue
RESTRICT=test

src_install() {
	#Because chicken's Upstream have a custom to use variables that also
	#portage uses. Fixes #393561
	unset A ARCH

	#upstream does not yet support parallel builds, bug 265881
	emake -j1 ${OPTIONS} DESTDIR="${D}" HOSTSYSTEM="${CBUILD}" \
		LINKER_OPTIONS="${LDFLAGS}" \
	install || die

	rm "${D}"/usr/share/doc/${P}/LICENSE || die
	dodoc NEWS || die

	if use emacs; then
		elisp-install ${PN} hen.{el,elc} || die
		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
	fi
}

pkg_postinst()
{
	#Because we pass DESTDIR= to make back in src_install(), the build
	#won't automatically run chicken-install -update-db at that time.
	chicken-install -update-db
}

[-- Attachment #2: Type: application/pgp-signature, Size: 198 bytes --]