[gentoo-dev] OSL 1.11.8.0 ebuild

[gentoo-dev] OSL 1.11.8.0 ebuild

[Luke A. Guest]

[-- Attachment #1: Type: text/plain, Size: 115 bytes --]

Hi,

I copied and updated the osl ebuild. There's a bit of a hack in there to 
find the LLVM_ROOT. But it builds.


[-- Attachment #2: osl-1.11.8.0.ebuild --]
[-- Type: text/plain, Size: 1976 bytes --]

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit cmake llvm toolchain-funcs

# check this on updates
LLVM_MAX_SLOT=9

DESCRIPTION="Advanced shading language for production GI renderers"
HOMEPAGE="http://opensource.imageworks.com/?p=osl"
SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~x86"

X86_CPU_FEATURES=(
	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
)
CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )

IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*}"

RDEPEND="
	dev-libs/boost:=
	dev-libs/pugixml
	media-libs/openexr:=
	media-libs/openimageio:=
	<sys-devel/clang-10:=
	sys-libs/zlib:=
	partio? ( media-libs/partio )
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtwidgets:5
	)
	dev-python/pybind11
"

DEPEND="${RDEPEND}"
BDEPEND="
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
"

# PATCHES=(
# 	"${FILESDIR}/${PN}-1.10.5-fix-install-shaders.patch"
# )

# Restricting tests as Make file handles them differently
RESTRICT="test"

S="${WORKDIR}/OpenShadingLanguage-Release-${PV}"

llvm_check_deps() {
	has_version -r "sys-devel/clang:${LLVM_SLOT}"
}

src_configure() {
	local cpufeature
	local mysimd=()
	for cpufeature in "${CPU_FEATURES[@]}"; do
		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
	done

	# If no CPU SIMDs were used, completely disable them
	[[ -z ${mysimd} ]] && mysimd=("0")

	local gcc=$(tc-getCC)
	# LLVM needs CPP11. Do not disable.
	local mycmakeargs=(
		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
		-DENABLERTTI=OFF
		-DINSTALL_DOCS=$(usex doc)
		-DLLVM_STATIC=OFF
		-DOSL_BUILD_TESTS=$(usex test)
		-DSTOP_ON_WARNING=OFF
		-DUSE_PARTIO=$(usex partio)
		-DUSE_QT=$(usex qt5)
		-DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
		-DLLVM_ROOT=/usr/lib/llvm/${LLVM_MAX_SLOT}
	)

	cmake_src_configure
}

Re: [gentoo-dev] OSL 1.11.8.0 ebuild

[Sam James]

[-- Attachment #1: Type: text/plain, Size: 314 bytes --]

Hi,

Can you submit this on Bugzilla and/or via a GitHub pullrequest?

Thanks!

> On 9 Oct 2020, at 19:31, Luke A. Guest <laguest@archeia.com> wrote:
> 
> Hi,
> 
> I copied and updated the osl ebuild. There's a bit of a hack in there to find the LLVM_ROOT. But it builds.
> 
> <osl-1.11.8.0.ebuild>


[-- Attachment #2: Message signed with OpenPGP --]
[-- Type: application/pgp-signature, Size: 358 bytes --]

Re: [gentoo-dev] OSL 1.11.8.0 ebuild

[Luke A. Guest]

https://bugs.gentoo.org/747475

On 09/10/2020 19:36, Sam James wrote:
> Hi,
> 
> Can you submit this on Bugzilla and/or via a GitHub pullrequest?
> 
> Thanks!
> 
>> On 9 Oct 2020, at 19:31, Luke A. Guest <laguest@archeia.com> wrote:
>>
>> Hi,
>>
>> I copied and updated the osl ebuild. There's a bit of a hack in there to find the LLVM_ROOT. But it builds.
>>
>> <osl-1.11.8.0.ebuild>
>