[gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

[-- Attachment #1: Type: text/plain, Size: 791 bytes --]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

https://bugs.gentoo.org/show_bug.cgi?id=417383

reasons:
* cleaner
* easier to update/fix
* proper config protection

any reason this was not done as a separate package in the first place?
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7jhAAAoJEFpvPKfnPDWzgUQIAKk1sWnA1RZK8AY+Fjk2N62O
QPt8UnVDkdNUfQ1KlTsjviCA9rrfez3ZcJho7e7ymDXYAvYY2XZlEeQmFBqanzgx
Jx/knYRaGX2GvYjl47OikJG8D6PrsptVS/QwQJsV5UsuFM63+DCMhsQs6owVKZR+
6zHFQMOmGosC985+Kp38LmPZqL3hhtLyY5B5WtyKrc2hEUYzYSCDXLECkduh4q65
9oeWNi6y+Q0TRvxBG0nZWq+ovTa/1leWSKWQiKuauy9ETOV5F+Ta16qLqB4/hkup
X1JAzXE7uvtpm5c8lnzda0kFzePhNN4C5U+v8mx2RcHNIPiMsN3GIFZV7uabKiw=
=qpea
-----END PGP SIGNATURE-----

[-- Attachment #2: gentoo-envd-0.ebuild --]
[-- Type: text/plain, Size: 1639 bytes --]

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

inherit games

DESCRIPTION="Environment file for gentoo games"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"

RDEPEND=""
DEPEND=""

S=${WORKDIR}

pkg_setup() {
	games_pkg_setup
	if [[ -z "${REPLACING_VERSIONS}" ]] ; then
		if [[ "${EROOT%/}/etc/env.d/${GAMES_ENVD}" ]] ; then
			old_envd="$(cat "${EROOT%/}/etc/env.d/${GAMES_ENVD}")"
			rm -v "${EROOT%/}/etc/env.d/${GAMES_ENVD}" || die
		fi
	fi
}

src_prepare() {
	local d libdirs

	for d in $(get_all_libdirs) ; do
		libdirs="${libdirs}:${GAMES_PREFIX}/${d}"
	done

	cat <<-EOF > ${GAMES_ENVD} || die
	LDPATH="${libdirs:1}"
	PATH="${GAMES_BINDIR}"
	EOF
}

src_configure() { :; }

src_compile() { :; }

src_install() {
	doenvd ${GAMES_ENVD} || die
	gamesowners "${ED%/}"/etc/env.d/${GAMES_ENVD} || die
	gamesperms  "${ED%/}"/etc/env.d/${GAMES_ENVD} || die
}

pkg_preinst() { :; }

pkg_postinst() {
	if [[ -z "${REPLACING_VERSIONS}" ]] ; then
		if [[ ${old_envd} ]] ; then
			elog "If you have previously modified /etc/env.d/${GAMES_ENVD}"
			elog "then you have to reapply your changes since this file was"
			elog "overwritten. The old content is:"
			elog
			elog "${old_envd}"
			elog
		fi
	fi
}

[-- Attachment #3: games.eclass.patch --]
[-- Type: text/x-patch, Size: 1481 bytes --]

move /etc/env.d/90games to a separate package wrt #417383

--- eclass/games.eclass
+++ eclass/games.eclass
@@ -18,6 +18,11 @@
 	2|3|4|5) EXPORT_FUNCTIONS pkg_setup src_configure src_compile pkg_preinst pkg_postinst ;;
 	*) die "no support for EAPI=${EAPI} yet" ;;
 esac
+
+if [[ ${PN} != "gentoo-envd" ]] ; then
+	# environment file
+	RDEPEND="games-misc/gentoo-envd"
+fi
 
 export GAMES_PREFIX=${GAMES_PREFIX:-/usr/games}
 export GAMES_PREFIX_OPT=${GAMES_PREFIX_OPT:-/opt}
@@ -124,23 +129,6 @@
 	find "${D}/${GAMES_BINDIR}" -maxdepth 1 -type f -exec chmod 750 '{}' \;
 }
 
-gamesenv() {
-	local d libdirs
-
-	for d in $(get_all_libdirs) ; do
-		libdirs="${libdirs}:${GAMES_PREFIX}/${d}"
-	done
-
-	# Wish we could use doevnd here, but we dont want the env
-	# file to be tracked in the CONTENTS of every game
-	cat <<-EOF > "${ROOT}"/etc/env.d/${GAMES_ENVD}
-	LDPATH="${libdirs:1}"
-	PATH="${GAMES_BINDIR}"
-	EOF
-	gamesowners "${ROOT}"/etc/env.d/${GAMES_ENVD}
-	gamesperms  "${ROOT}"/etc/env.d/${GAMES_ENVD}
-}
-
 games_pkg_setup() {
 	tc-export CC CXX LD AR RANLIB
 
@@ -183,9 +171,8 @@
 	done < <(find "${D}/${GAMES_STATEDIR}" -type f -printf '%P\n' 2>/dev/null)
 }
 
-# pkg_postinst function ... create env.d entry and warn about games group
+# pkg_postinst function ... warn about games group
 games_pkg_postinst() {
-	gamesenv
 	if [[ -z "${GAMES_SHOW_WARNING}" ]] ; then
 		ewarn "Remember, in order to play games, you have to"
 		ewarn "be in the '${GAMES_GROUP}' group."

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 02/02/2014 01:21 PM, hasufell wrote:
> https://bugs.gentoo.org/show_bug.cgi?id=417383
> 
> reasons: * cleaner * easier to update/fix * proper config
> protection
> 
> any reason this was not done as a separate package in the first
> place?
> 

On second thought... those REPLACING_VERSIONS and elog things probably
don't make a lot of sense since the file is overwritten
unconditionally anyway via eclass.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7joJAAoJEFpvPKfnPDWzI4kH/iPzPZloRT1TwoycNH2nFvMP
9maFBI38ReDWnaeIml94e3b5imZBPcUSp2zMvu2sdcEv1Qpc/PS20eT39o+s9Y1R
FTlP17Pt6zAUnjV1KC7hUXUE3LDHgiOVj8ItF2HYW/IxkIjnMid4CeTNGft2X28t
Zfw1bxBXVnS++OxAlWi61I63yeUhsjUvYwcDfH82ZeyhmDAUQxmPrc4P2w546ABX
wDRWe+a3S9gcGaiwnb7ROE/iJXnKFHC/9Sxhll7CuuSYAd4/3xO3nTvD9ufBerZY
CAdFl/ejzyAAtabaeuhJltwOSssYqgr+OAUUl8YLha9Hegt0ur1n64q6UULviaQ=
=jOMb
-----END PGP SIGNATURE-----

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[Ulrich Mueller]

[-- Attachment #1: Type: text/plain, Size: 412 bytes --]

>>>>> On Sun, 02 Feb 2014, hasufell  wrote:

> https://bugs.gentoo.org/show_bug.cgi?id=417383

[gentoo-envd-0.ebuild]

> EAPI=3

Why not newest EAPI?

> SRC_URI=""

Not needed.

> RDEPEND=""
> DEPEND=""

Ditto.

[games.eclass.patch]

> +if [[ ${PN} != "gentoo-envd" ]] ; then

Better include ${CATEGORY} in this test, especially with such a
generic package name. (Or call the package gentoo-games-envd?)

Ulrich

[-- Attachment #2: Type: application/pgp-signature, Size: 490 bytes --]

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 02/02/2014 01:48 PM, Ulrich Mueller wrote:
>>>>>> On Sun, 02 Feb 2014, hasufell  wrote:
> 
>> https://bugs.gentoo.org/show_bug.cgi?id=417383
> 
> [gentoo-envd-0.ebuild]
> 
>> EAPI=3
> 
> Why not newest EAPI?
> 

I didn't feel comfortable about it since this is not a generic games
package, but I guess upgrade path is not an argument here anymore.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7kCAAAoJEFpvPKfnPDWzCmQH/20dWBlESo5/NdxY95nckBdn
yM70U3aV3+ulXU/1t2092uhcZR7rCyYUU1gbm65r/e/p9AMuAaSdWEebhfBJhShD
Fmireby3iQqOEgRdbEUM2cuzzxPU5ny99y4fIjq46fAYKhK7W0sHuKeDQQ1WSy8+
psK6KEkW239TTxPBywmhlc+JCJmer0qjUKSVZFjWZFf2UNDT/Ext++qkYiIonuLz
CeGQ9SogAATwAuMbRsenV32QnSnLB/nFDdZEyI5XfYV6jE64oaceEnoaep3IQ25A
4pf1fLqDx6ASt4nE5BsvOXWkA2DDiP8Zg5vHAkH3X4Wh9jG75poeJ9ym02bjhEE=
=2nrW
-----END PGP SIGNATURE-----

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 02/02/2014 01:48 PM, Ulrich Mueller wrote:
>>>>>> On Sun, 02 Feb 2014, hasufell  wrote:
>> SRC_URI=""
> 
> Not needed.
> 

Seems safer to me with "" in case games.eclass or any of those that it
inherits add stuff to SRC_URI in the future.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7kOQAAoJEFpvPKfnPDWzDakH/RlqN2YDgoRZZNpUxWflRXmC
KTN1gAVCFrTr6IoKdRJBiNC282XZz9HHRv/W7TbNmbWzO1nvvMYUWmCkt8AAfuCd
t5fdKRWFms1Ccsawj9tdDjM4i6AGjxo2UHpbILG7X3+VBXL+fX03DKKeXjshyb4O
LUra0WgOc5gcWE6Cn4u5XT2QUDXJ4A/eELi8d6qPFKJ7kZvTN3qf89tCrvcMw3Zn
Q9qoqA5cjixOi0MuwA1O616FpvrELt5z2KaWmIH9WQMq5P0KpQoofw9Mm8l9nWh1
1rZDCGMPtd0tUObIbhLwNRPz6hQz28YMn0GhPoOiumaEKI+Yct5lMlXD3uRbHQs=
=L4G5
-----END PGP SIGNATURE-----

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

[-- Attachment #1: Type: text/plain, Size: 749 bytes --]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

ebuild:
* use EAPI-5
* drop RDEPEND/DEPEND
* drop useless elog
* set homepage to games project page

eclass:
* use ${CATEGORY}/${PN} for the check
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7kn2AAoJEFpvPKfnPDWz5O4IAKHuUnOtQIIlkG7Le93fBLCw
axMSpepFfnY4qD1MAOWBrSt3ECbh8iArtxIImNL8FdzmIdz7YPU79SkmUqAqIpMY
bAp3vGUfwaSqK8kWYSBRtvSOAloEMncdVmROk0FDR21BnXBUnfVMY1hrlQNo4lJH
hhUCqZ/YYWIPdfYhHimguTSyH6D6wbZ/UMTlH0o0a9gRAaHj7tTo7TB0iiX/qCtr
4Gsls4Y4THY9ZI6gZKEac/3Qab3/k0UEUNlo2EEDYVbtbHQKGkJybfTwwGR0gjPV
BwICpY9Kot/nlBldO5ZyigAu7WyMjQvpgciXdN++cZ9vDgM6RvSL4Yx1yHy5Foc=
=fPXY
-----END PGP SIGNATURE-----

[-- Attachment #2: games.eclass.patch --]
[-- Type: text/x-patch, Size: 1504 bytes --]

move /etc/env.d/90games to a separate package wrt #417383

--- eclass/games.eclass
+++ eclass/games.eclass
@@ -18,6 +18,11 @@
 	2|3|4|5) EXPORT_FUNCTIONS pkg_setup src_configure src_compile pkg_preinst pkg_postinst ;;
 	*) die "no support for EAPI=${EAPI} yet" ;;
 esac
+
+if [[ ${CATEGORY}/${PN} != "games-misc/gentoo-envd" ]] ; then
+	# environment file
+	RDEPEND="games-misc/gentoo-envd"
+fi
 
 export GAMES_PREFIX=${GAMES_PREFIX:-/usr/games}
 export GAMES_PREFIX_OPT=${GAMES_PREFIX_OPT:-/opt}
@@ -124,23 +129,6 @@
 	find "${D}/${GAMES_BINDIR}" -maxdepth 1 -type f -exec chmod 750 '{}' \;
 }
 
-gamesenv() {
-	local d libdirs
-
-	for d in $(get_all_libdirs) ; do
-		libdirs="${libdirs}:${GAMES_PREFIX}/${d}"
-	done
-
-	# Wish we could use doevnd here, but we dont want the env
-	# file to be tracked in the CONTENTS of every game
-	cat <<-EOF > "${ROOT}"/etc/env.d/${GAMES_ENVD}
-	LDPATH="${libdirs:1}"
-	PATH="${GAMES_BINDIR}"
-	EOF
-	gamesowners "${ROOT}"/etc/env.d/${GAMES_ENVD}
-	gamesperms  "${ROOT}"/etc/env.d/${GAMES_ENVD}
-}
-
 games_pkg_setup() {
 	tc-export CC CXX LD AR RANLIB
 
@@ -183,9 +171,8 @@
 	done < <(find "${D}/${GAMES_STATEDIR}" -type f -printf '%P\n' 2>/dev/null)
 }
 
-# pkg_postinst function ... create env.d entry and warn about games group
+# pkg_postinst function ... warn about games group
 games_pkg_postinst() {
-	gamesenv
 	if [[ -z "${GAMES_SHOW_WARNING}" ]] ; then
 		ewarn "Remember, in order to play games, you have to"
 		ewarn "be in the '${GAMES_GROUP}' group."

[-- Attachment #3: gentoo-envd-0.ebuild --]
[-- Type: text/plain, Size: 1273 bytes --]

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit games

DESCRIPTION="Environment file for gentoo games"
HOMEPAGE="http://www.gentoo.org/proj/en/desktop/games/index.xml"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"

S=${WORKDIR}

pkg_setup() {
	games_pkg_setup
	if [[ -z "${REPLACING_VERSIONS}" ]] ; then
		if [[ "${EROOT%/}/etc/env.d/${GAMES_ENVD}" ]] ; then
			rm -v "${EROOT%/}/etc/env.d/${GAMES_ENVD}" || die
		fi
	fi
}

src_prepare() {
	local d libdirs

	for d in $(get_all_libdirs) ; do
		libdirs="${libdirs}:${GAMES_PREFIX}/${d}"
	done

	cat <<-EOF > ${GAMES_ENVD} || die
	LDPATH="${libdirs:1}"
	PATH="${GAMES_BINDIR}"
	EOF
}

src_configure() { :; }

src_compile() { :; }

src_install() {
	doenvd ${GAMES_ENVD}
	gamesowners "${ED%/}"/etc/env.d/${GAMES_ENVD}
	gamesperms  "${ED%/}"/etc/env.d/${GAMES_ENVD}
}

pkg_preinst() { :; }

pkg_postinst() { :; }

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[Ciaran McCreesh]

[-- Attachment #1: Type: text/plain, Size: 200 bytes --]

On Sun, 02 Feb 2014 14:36:54 +0100
hasufell <hasufell@gentoo.org> wrote:
> * set homepage to games project page

Why? Eclasses setting a homepage was never a good idea...

-- 
Ciaran McCreesh

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 198 bytes --]

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 02/02/2014 02:43 PM, Ciaran McCreesh wrote:
> On Sun, 02 Feb 2014 14:36:54 +0100 hasufell <hasufell@gentoo.org>
> wrote:
>> * set homepage to games project page
> 
> Why? Eclasses setting a homepage was never a good idea...
> 

The ebuild sets the homepage as described in that mail.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7kvoAAoJEFpvPKfnPDWz4g0H/10SClsfe/8Gnllk+1/yk5oN
2ov9PkptmlMoVIjPUqok4Ud05UamieBYaCTaeUTONegDY/QxirdwfiwWV+KRZDid
1vJcU/sHPUHfE8YEYioinK5PwjteLcwZoFJI5R4XJcQLRfsjVPXoUjGrq1zJ73DU
hLkFrrLiD9JVbc/jwYIm/NUCjibbw/tHK9kz/9N7I0hFfkEXqSRGvyGN/QD49iOo
xz5KlYxL4z0Edlg/aDEvyQZDAcf0ScRVx/9LVuJnA+929VsWRr5b8n6yS63cESOr
hYzZEZszl4GhBfwRr7S/kRV/JDWMND7TPqoZXTonNj3kK2a7EBuL8iPy/Bn6qrM=
=0aJ7
-----END PGP SIGNATURE-----

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[Ciaran McCreesh]

[-- Attachment #1: Type: text/plain, Size: 468 bytes --]

On Sun, 02 Feb 2014 14:45:12 +0100
hasufell <hasufell@gentoo.org> wrote:
> On 02/02/2014 02:43 PM, Ciaran McCreesh wrote:
> > On Sun, 02 Feb 2014 14:36:54 +0100 hasufell <hasufell@gentoo.org>
> > wrote:
> >> * set homepage to games project page
> > 
> > Why? Eclasses setting a homepage was never a good idea...
> > 
> 
> The ebuild sets the homepage as described in that mail.

Uh huh, so why specify something in the eclass too?

-- 
Ciaran McCreesh

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 198 bytes --]

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[hasufell]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 02/02/2014 02:47 PM, Ciaran McCreesh wrote:
> On Sun, 02 Feb 2014 14:45:12 +0100 hasufell <hasufell@gentoo.org>
> wrote:
>> On 02/02/2014 02:43 PM, Ciaran McCreesh wrote:
>>> On Sun, 02 Feb 2014 14:36:54 +0100 hasufell
>>> <hasufell@gentoo.org> wrote:
>>>> * set homepage to games project page
>>> 
>>> Why? Eclasses setting a homepage was never a good idea...
>>> 
>> 
>> The ebuild sets the homepage as described in that mail.
> 
> Uh huh, so why specify something in the eclass too?
> 

You seem confused. Please read the attached ebuild and eclass patch.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v2.0.22 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://www.enigmail.net/

iQEcBAEBAgAGBQJS7kzBAAoJEFpvPKfnPDWzgE0H/2Q6tLIdEWVAcBw5W50Jnldy
2vsde45M6d3eV8qOW8GJVbX6mUdHH1asKM7VGQHwIRclTHdzR9KCFFztObUogQNM
pWNT31SJwnNKOnnmP2vU90bu7ady0FMNQN6T0XCAieGMg/ugkVfNIyywcaGwyn8F
0R/3lcUIx7Y4BshTMlvnJmOE10daJBN+Q4uGsWpl8Qi8nFFwlDtaBeMP3SCxl8hI
g0KdCJY9ZJnJZfzDtNvTmlcjP13C74K3Q3tiEpfGjV1Gj5e2AXOY0il9X5tlQR0J
/NE71QywCRdpX2IFI5g9zuGHksyZDKl7addhAV+2YGWVrO52wtRlQcn7T8EtT9Q=
=dcUn
-----END PGP SIGNATURE-----

Re: [gentoo-dev] [RFC] games.eclass: move /etc/env.d/90games to a separate package

[Ulrich Mueller]

[-- Attachment #1: Type: text/plain, Size: 217 bytes --]

>>>>> On Sun, 02 Feb 2014, hasufell  wrote:

[gentoo-envd-0.ebuild]

Seems I had missed this one:

>			rm -v "${EROOT%/}/etc/env.d/${GAMES_ENVD}" || die

POSIX rm doesn't have a -v option, so better avoid it.

Ulrich

[-- Attachment #2: Type: application/pgp-signature, Size: 490 bytes --]