[gentoo-dev] [RFC PATCH 02/10] net-print/libppd: new package, add 2.0.0

[Eli Schwartz <eschwartz93@gmail.com>]

Part of the CUPS v3 evolution. Now, cups-filters has been split out into
multiple sub-packages. This is the legacy PPD filters core library.

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
---
 net-print/libppd/Manifest            |  1 +
 net-print/libppd/libppd-2.0.0.ebuild | 52 ++++++++++++++++++++++++++++
 net-print/libppd/metadata.xml        | 14 ++++++++
 3 files changed, 67 insertions(+)
 create mode 100644 net-print/libppd/Manifest
 create mode 100644 net-print/libppd/libppd-2.0.0.ebuild
 create mode 100644 net-print/libppd/metadata.xml

diff --git a/net-print/libppd/Manifest b/net-print/libppd/Manifest
new file mode 100644
index 000000000000..bc6ba554c08c
--- /dev/null
+++ b/net-print/libppd/Manifest
@@ -0,0 +1 @@
+DIST libppd-2.0.0.tar.xz 580716 BLAKE2B 8505c5ab5b515104308624a8f78505343b894df08ab8ac2727d7bd82d0d65d256d22ecaf384b212d9a5c45d2a619a6311722a8c5ed954b7a8a9780477aedb458 SHA512 8be9e67552528606fd804ba13b05710938ed7d02316c1c902ee657bc0e5fade663ffacb5b032609a1c1fdc80d976e7e54d2ca2f71db83cb8fdcee6a371e6bad4
diff --git a/net-print/libppd/libppd-2.0.0.ebuild b/net-print/libppd/libppd-2.0.0.ebuild
new file mode 100644
index 000000000000..174c775a213f
--- /dev/null
+++ b/net-print/libppd/libppd-2.0.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Legacy library for PPD files, split out of cups-filters"
+HOMEPAGE="https://github.com/OpenPrinting/libppd"
+SRC_URI="https://github.com/OpenPrinting/libppd/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+postscript +poppler"
+KEYWORDS="~amd64"
+
+# pdftops has various possible implementations, but the default
+# really needs to be decent
+REQUIRED_USE="|| ( postscript poppler )"
+
+RDEPEND="
+	>=net-print/cups-2
+	net-print/libcupsfilters
+	!<net-print/cups-filters-2.0.0
+	postscript? ( >=app-text/ghostscript-gpl-9.09[cups] )
+	poppler? ( >=app-text/poppler-0.32[utils] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myeconfargs=(
+		--localstatedir="${EPREFIX}"/var
+		--with-cups-rundir="${EPREFIX}"/run/cups
+		# This does build time checks for (preferred) tool interfaces.
+		$(use_enable postscript ghostscript)
+		$(use_enable poppler pdftops)
+		# These fallbacks are just probed for the path. Always enable them.
+		--with-mutool-path="${EPREFIX}"/usr/bin/mutool
+		--with-pdftocairo-path="${EPREFIX}"/usr/bin/pdftocairo # from poppler
+		# unpackaged
+		--disable-acroread
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-print/libppd/metadata.xml b/net-print/libppd/metadata.xml
new file mode 100644
index 000000000000..67a6452ca268
--- /dev/null
+++ b/net-print/libppd/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>printing@gentoo.org</email>
+		<name>Gentoo Printing Project</name>
+	</maintainer>
+	<use>
+		<flag name="poppler">Use the <pkg>app-text/poppler</pkg> pdftops filter</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">OpenPrinting/libppd</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
2.41.0