[gentoo-dev] [RFC PATCH 01/10] net-print/libcupsfilters: new package, add 2.0.0

[Eli Schwartz <eschwartz93@gmail.com>]

Part of the CUPS v3 evolution. Now, cups-filters has been split out into
multiple sub-packages. This is the core library.

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
---
 net-print/libcupsfilters/Manifest             |  1 +
 .../libcupsfilters-2.0.0.ebuild               | 60 +++++++++++++++++++
 net-print/libcupsfilters/metadata.xml         | 14 +++++
 3 files changed, 75 insertions(+)
 create mode 100644 net-print/libcupsfilters/Manifest
 create mode 100644 net-print/libcupsfilters/libcupsfilters-2.0.0.ebuild
 create mode 100644 net-print/libcupsfilters/metadata.xml

diff --git a/net-print/libcupsfilters/Manifest b/net-print/libcupsfilters/Manifest
new file mode 100644
index 000000000000..9145aecf6f6d
--- /dev/null
+++ b/net-print/libcupsfilters/Manifest
@@ -0,0 +1 @@
+DIST libcupsfilters-2.0.0.tar.xz 1279856 BLAKE2B ce9d839bb700017c303c1301c7a97fd02e3657a908e685377be49557d995574a7fc5a31d4fcbda5eeb9ba2d3cd07858224540dbf0bc9fa078cfd25a58ee15a41 SHA512 279bff6dcfa76312b10dae97480914345defd90eab79c4716d4553870f73e0f9db404786fd7e2948a86ae5aedb10dca0c2984ccb4222acbd4e835cd572030d6a
diff --git a/net-print/libcupsfilters/libcupsfilters-2.0.0.ebuild b/net-print/libcupsfilters/libcupsfilters-2.0.0.ebuild
new file mode 100644
index 000000000000..511d423289b8
--- /dev/null
+++ b/net-print/libcupsfilters/libcupsfilters-2.0.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="library for developing printing features, split out of cups-filters"
+HOMEPAGE="https://github.com/OpenPrinting/libcupsfilters"
+SRC_URI="https://github.com/OpenPrinting/libcupsfilters/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="dbus exif jpeg pdf +poppler +postscript png test tiff"
+KEYWORDS="~amd64"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-text/qpdf-8.3.0:=
+	media-libs/fontconfig
+	media-libs/lcms:2
+	>=net-print/cups-2
+	!<net-print/cups-filters-2.0.0
+
+	exif? ( media-libs/libexif )
+	dbus? ( sys-apps/dbus )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	poppler? ( >=app-text/poppler-0.32[cxx] )
+	png? ( media-libs/libpng:= )
+	tiff? ( media-libs/tiff:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	test? ( media-fonts/dejavu )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-imagefilters
+		--localstatedir="${EPREFIX}"/var
+		--with-cups-rundir="${EPREFIX}"/run/cups
+
+		$(use_enable exif)
+		$(use_enable dbus)
+		$(use_enable poppler)
+		$(use_enable postscript)
+		$(use_enable pdf mutool)
+		$(use_with jpeg)
+		$(use_with png)
+		$(use_with tiff)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-print/libcupsfilters/metadata.xml b/net-print/libcupsfilters/metadata.xml
new file mode 100644
index 000000000000..d31059e1c097
--- /dev/null
+++ b/net-print/libcupsfilters/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>printing@gentoo.org</email>
+		<name>Gentoo Printing Project</name>
+	</maintainer>
+	<use>
+		<flag name="poppler">Build the pdftoraster filter</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">OpenPrinting/libcupsfilters</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
2.41.0