[gentoo-dev] Ebuild for Bangla Font support in Gentoo Linux

[gentoo-dev] Ebuild for Bangla Font support in Gentoo Linux

[Archan]

Hi,

I have made ebuild for installing "Unicode compliant Open Type Bengali fonts" in Gentoo Linux System. Bangla is my native language. Bangla is the one of the Language spoken in India and Bangladesh. Historically Bangla is originated from a language called "Prakrit" which had its root in Sanskrit.

Following project is developing Unicode compliant Open Type Bengla fonts
http://www.nongnu.org/freebangfont/index.html

It is a subproject of http://www.bengalinux.org/
http://www.bengalinux.org/

Possibly it is the first Bangla Font support initiative for Gentoo Linux. I have submitted the formal inclusion request at http://bugs.gentoo.org/show_bug.cgi?id=26381

iti
Archan

----cut here----
# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2

DESCRIPTION="Unicode compliant Open Type Bangla fonts"
HOMEPAGE="http://www.nongnu.org/freebangfont/index.html"
SRC_BASE="http://savannah.nongnu.org/download/freebangfont"
SRC_URI="${SRC_BASE}/Akaash.pkg/0.8.5/Akaash-0.8.5.tar.gz
	${SRC_BASE}/Ani.pkg/0.8.0/Ani-0.8.0.tar.gz
	${SRC_BASE}/Likhan.pkg/0.5/Likhan-0.5.tar.gz
	${SRC_BASE}/Sagar.pkg/0.6.0/Sagar-0.60.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="virtual/x11"

S="${WORKDIR}"
FONTDIR="/usr/share/fonts/ttf/bangla/free-bangla-font/"

src_unpack() {
	cd ${S}
	for gz in ${A}; do
		tar -xzf ${DISTDIR}/${gz}
	done
}

src_install() {
	insopts -m0644
    insinto ${FONTDIR}

	doins ${S}/Akaash/*ttf
	doins ${S}/ani/*ttf
	doins ${S}/Likhan-0.5/*ttf
	doins ${S}/Sagar/*ttf
	
	mkfontscale ${D}/${FONTDIR}
	newins ${D}/${FONTDIR}/fonts.scale fonts.dir
}

pkg_postinst() {
    einfo "You need you add following line into /etc/X11/XftConfig"
    einfo ""
    einfo "\t dir \"${FONTDIR}\""
    einfo ""
}

pkg_postrm(){
    einfo "You need you remove following line into /etc/X11/XftConfig"
    einfo ""
    einfo "\t dir \"${FONTDIR}\""
    einfo ""
}
----cut here----



--
gentoo-dev@gentoo.org mailing list

Re: [gentoo-dev] Ebuild for Bangla Font support in Gentoo Linux

[Mike Frysinger]

On Monday 11 August 2003 04:16, Archan wrote:
> SRC_BASE="http://savannah.nongnu.org/download/freebangfont"
> SRC_URI="${SRC_BASE}/Akaash.pkg/0.8.5/Akaash-0.8.5.tar.gz
> 	${SRC_BASE}/Ani.pkg/0.8.0/Ani-0.8.0.tar.gz
> 	${SRC_BASE}/Likhan.pkg/0.5/Likhan-0.5.tar.gz
> 	${SRC_BASE}/Sagar.pkg/0.6.0/Sagar-0.60.tar.gz"

might it be useful to split the pkg since each font appears to be version 
tracked separately ?

> src_unpack() {
> 	cd ${S}
> 	for gz in ${A}; do
> 		tar -xzf ${DISTDIR}/${gz}
> 	done
> }

i think if you deleted this function all together the ebuild would work just 
fine

> 	doins ${S}/Akaash/*ttf
> 	doins ${S}/ani/*ttf
> 	doins ${S}/Likhan-0.5/*ttf
> 	doins ${S}/Sagar/*ttf

since the default working directory of src_install is ${S}, you dont need to 
prefix each of these paths

other than that, it looks good ... kind of cool to support Sanskrit based 
languages ... wonder if we have nepali support hiding somewhere ...
-mike

--
gentoo-dev@gentoo.org mailing list