public inbox for gentoo-dev@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-dev] gnome-games.eclass: Eclass for installing all gnome-games
@ 2013-05-02 10:41 Pacho Ramos
  2013-05-02 12:34 ` hasufell
  0 siblings, 1 reply; 10+ messages in thread
From: Pacho Ramos @ 2013-05-02 10:41 UTC (permalink / raw
  To: gentoo-dev; +Cc: gnome, games

[-- Attachment #1: Type: text/plain, Size: 288 bytes --]

gnome-games was splitted in separate packages per game and, then, we
need an eclass to also set proper settings inherited from gnome2 and
games eclasses. This should also solve:
https://bugs.gentoo.org/show_bug.cgi?id=432848

eclass and ebuild (games-puzzle/five-or-more) to try attached

[-- Attachment #2: gnome-games.eclass --]
[-- Type: text/plain, Size: 2889 bytes --]

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/eclass/python-single-r1.eclass,v 1.16 2013/04/07 17:02:52 mgorny Exp $

# @ECLASS: gnome-games
# @MAINTAINER:
# Gnome team <gnome@gentoo.org>
# @AUTHOR:
# Author: Pacho Ramos <pacho@gentoo.org>
# @BLURB: An eclass to build gnome-games.
# @DESCRIPTION:
# An eclass to build gnome-games using proper phases from gnome2 and
# games eclasses.

case "${EAPI:-0}" in
	0|1)
		die "Unsupported EAPI=${EAPI:-0} (too old) for ${ECLASS}"
		;;
	2|3|4|5)
		;;
	*)
		die "Unsupported EAPI=${EAPI} (unknown) for ${ECLASS}"
		;;
esac

inherit games gnome2

EXPORT_FUNCTIONS pkg_setup src_prepare src_configure src_compile src_install pkg_preinst pkg_postinst pkg_postrm

if [[ ! ${_GNOME_GAMES} ]]; then

RDEPEND="!gnome-extra/gnome-games"

# @FUNCTION: gnome-games_pkg_setup
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_pkg_setup() {
	debug-print-function ${FUNCNAME} "${@}"
	games_pkg_setup
}

# @FUNCTION: gnome-games_src_prepare
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_src_prepare() {
	debug-print-function ${FUNCNAME} "${@}"
	gnome2_src_prepare
}

# @FUNCTION: gnome-games_src_configure
# @DESCRIPTION:
# Set proper phase defaults, relying on gnome2_src_configure
# and passing extra arguments from egamesconf (games.eclass)
gnome-games_src_configure() {
	debug-print-function ${FUNCNAME} "${@}"
	gnome2_src_configure \
		--bindir="${GAMES_BINDIR}" \
		--libdir="$(games_get_libdir)" \
		--sysconfdir="${GAMES_SYSCONFDIR}" \
		--localstatedir="${GAMES_STATEDIR}" \
		"$@"
# GAMES_DATADIR causes games to fail to run due schemas and other
# files getting installed in unexpected places
# --datadir="${GAMES_DATADIR}"
#
# We need to not set GAMES_PREFIX to get translations working
# --localedir="${EPREFIX}"/usr/share/locale is not enough
# --prefix="${GAMES_PREFIX}" -> setting bindir instead
}

# @FUNCTION: gnome-games_src_compile
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_src_compile() {
	debug-print-function ${FUNCNAME} "${@}"
	gnome2_src_compile
}

# @FUNCTION: gnome-games_src_install
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_src_install() {
	debug-print-function ${FUNCNAME} "${@}"
	gnome2_src_install
}

# @FUNCTION: gnome-games_pkg_preinst
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_pkg_preinst() {
	debug-print-function ${FUNCNAME} "${@}"
	gnome2_pkg_preinst
	games_pkg_preinst
}

# @FUNCTION: gnome-games_pkg_preinst
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_pkg_postinst() {
	debug-print-function ${FUNCNAME} "${@}"
        gnome2_pkg_postinst
	games_pkg_postinst
}

# @FUNCTION: gnome-games_pkg_postrm
# @DESCRIPTION:
# Set proper phase defaults
gnome-games_pkg_postrm() {
	debug-print-function ${FUNCNAME} "${@}"
        gnome2_pkg_postrm
}

_GNOME_GAMES=1
fi

[-- Attachment #3: five-or-more-3.8.1.ebuild --]
[-- Type: text/plain, Size: 485 bytes --]

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome-games

DESCRIPTION="Five or More Game for GNOME"
HOMEPAGE="https://live.gnome.org/Five%20or%20more"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="
	dev-libs/glib:2
	>=gnome-base/librsvg-2.32.0
	>=x11-libs/gtk+-3.4.0:3
"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.35.0
	dev-util/itstool
	virtual/pkgconfig
"

^ permalink raw reply	[flat|nested] 10+ messages in thread
end of thread, other threads:[~2013-06-27 20:43 UTC | newest]

Thread overview: 10+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-05-02 10:41 [gentoo-dev] gnome-games.eclass: Eclass for installing all gnome-games Pacho Ramos
2013-05-02 12:34 ` hasufell
2013-05-02 13:40   ` Pacho Ramos
2013-05-02 13:54     ` hasufell
2013-05-02 15:12       ` Pacho Ramos
2013-05-02 15:16         ` hasufell
2013-05-02 15:35           ` Pacho Ramos
2013-06-27 20:25             ` Pacho Ramos
2013-06-27 20:38               ` hasufell
2013-06-27 20:43                 ` Pacho Ramos

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox