* [gentoo-commits] proj/gnome:master commit in: gnome-extra/gnome-contacts/, gnome-extra/yelp/, gnome-extra/yelp-xsl/, ...
@ 2011-11-04 20:19 Alexandre Restovtsev
0 siblings, 0 replies; only message in thread
From: Alexandre Restovtsev @ 2011-11-04 20:19 UTC (permalink / raw
To: gentoo-commits
commit: fe25908a8632da745b1e2ac827ae11ebe79dab5c
Author: Alexandre Rostovtsev <tetromino <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 4 20:18:27 2011 +0000
Commit: Alexandre Restovtsev <tetromino <AT> gmail <DOT> com>
CommitDate: Fri Nov 4 20:18:27 2011 +0000
URL: http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=fe25908a
brasero, yelp{,tools,xsl}, folks, empathy, gnome-contacts, gnome-user-docs: moved to gx86
---
app-cdr/brasero/brasero-3.2.0.ebuild | 107 ----------------
app-text/yelp-tools/yelp-tools-3.2.1.ebuild | 33 -----
dev-libs/folks/folks-0.6.4.1.ebuild | 81 -------------
gnome-base/gnome-common/gnome-common-3.1.0.ebuild | 21 ----
.../gnome-contacts/gnome-contacts-3.2.2.ebuild | 54 --------
.../gnome-user-docs/gnome-user-docs-3.2.1.ebuild | 48 --------
| 30 -----
.../yelp/files/yelp-3.0.3-man-compatibility.patch | 117 ------------------
| 59 ---------
net-im/empathy/empathy-3.2.1.1.ebuild | 127 --------------------
10 files changed, 0 insertions(+), 677 deletions(-)
diff --git a/app-cdr/brasero/brasero-3.2.0.ebuild b/app-cdr/brasero/brasero-3.2.0.ebuild
deleted file mode 100644
index b9e1bb4..0000000
--- a/app-cdr/brasero/brasero-3.2.0.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
-
-inherit autotools eutils gnome2 multilib
-if [[ ${PV} = 9999 ]]; then
- inherit gnome2-live
-fi
-
-DESCRIPTION="Brasero (aka Bonfire) is yet another application to burn CD/DVD for the gnome desktop."
-HOMEPAGE="http://projects.gnome.org/brasero/"
-
-LICENSE="GPL-2"
-SLOT="0"
-if [[ ${PV} = 9999 ]]; then
- KEYWORDS=""
-else
- KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-fi
-IUSE="+css doc +introspection +libburn mp3 nautilus packagekit playlist test tracker"
-
-COMMON_DEPEND="
- >=dev-libs/glib-2.29.14:2
- >=x11-libs/gtk+-3.0.0:3[introspection?]
- >=media-libs/gstreamer-0.10.15:0.10
- >=media-libs/gst-plugins-base-0.10:0.10
- >=dev-libs/libxml2-2.6:2
- >=x11-libs/libnotify-0.6.1
-
- media-libs/libcanberra[gtk3]
- x11-libs/libICE
- x11-libs/libSM
-
- introspection? ( >=dev-libs/gobject-introspection-0.6.3 )
- libburn? (
- >=dev-libs/libburn-0.4
- >=dev-libs/libisofs-0.6.4 )
- nautilus? ( >=gnome-base/nautilus-2.91.90 )
- playlist? ( >=dev-libs/totem-pl-parser-2.29.1 )
- tracker? ( >=app-misc/tracker-0.12 )"
-RDEPEND="${COMMON_DEPEND}
- media-libs/gst-plugins-good:0.10
- media-plugins/gst-plugins-gconf:0.10
- media-plugins/gst-plugins-meta:0.10[mp3?]
- x11-themes/hicolor-icon-theme
- css? ( media-libs/libdvdcss:1.2 )
- !libburn? (
- app-cdr/cdrdao
- app-cdr/dvd+rw-tools
- virtual/cdrtools )
- mp3? ( media-libs/gst-plugins-ugly:0.10 )
- packagekit? ( app-admin/packagekit-base )"
-DEPEND="${COMMON_DEPEND}
- app-text/gnome-doc-utils
- dev-util/pkgconfig
- sys-devel/gettext
- dev-util/intltool
- gnome-base/gnome-common:3
- >=dev-util/gtk-doc-am-1.12
- doc? ( >=dev-util/gtk-doc-1.12 )
- test? ( app-text/docbook-xml-dtd:4.3 )"
-# eautoreconf deps
-# gnome-base/gnome-common
-# dev-util/gtk-doc-am
-PDEPEND="gnome-base/gvfs"
-
-pkg_setup() {
- G2CONF="${G2CONF}
- --disable-scrollkeeper
- --disable-caches
- --disable-dependency-tracking
- $(use_enable !libburn cdrtools)
- $(use_enable !libburn cdrkit)
- $(use_enable !libburn cdrdao)
- $(use_enable !libburn growisofs)
- $(use_enable introspection)
- $(use_enable libburn libburnia)
- $(use_enable nautilus)
- $(use_enable playlist)
- $(use_enable tracker search)"
-
- DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
-}
-
-src_prepare() {
- # Fix linking against installed libraries, bug #340767, gnome #641233
- epatch "${FILESDIR}/${PN}-2.91.6-build-plugins-against-local-library.patch"
-
- if [[ ${PV} != 9999 ]]; then
- intltoolize --force --copy --automake || die "intltoolize failed"
- eautoreconf
- fi
-
- gnome2_src_prepare
-}
-
-pkg_postinst() {
- gnome2_pkg_postinst
-
- echo
- elog "If ${PN} doesn't handle some music or video format, please check"
- elog "your USE flags on media-plugins/gst-plugins-meta"
-}
diff --git a/app-text/yelp-tools/yelp-tools-3.2.1.ebuild b/app-text/yelp-tools/yelp-tools-3.2.1.ebuild
deleted file mode 100644
index 8e0c6d7..0000000
--- a/app-text/yelp-tools/yelp-tools-3.2.1.ebuild
+++ /dev/null
@@ -1,33 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="no"
-
-inherit gnome2
-if [[ ${PV} = 9999 ]]; then
- inherit gnome2-live
-fi
-
-DESCRIPTION="Collection of tools for building and converting documentation"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-2 freedist" # yelp.m4 is freely distributable
-SLOT="0"
-if [[ ${PV} = 9999 ]]; then
- KEYWORDS=""
-else
- KEYWORDS="~amd64 ~x86"
-fi
-IUSE=""
-
-RDEPEND=">=dev-libs/libxml2-2.6.12
- >=dev-libs/libxslt-1.1.8
- dev-util/itstool
- gnome-extra/yelp-xsl
- sys-apps/gawk"
-DEPEND="${RDEPEND}
- dev-util/pkgconfig"
-
-DOCS="AUTHORS NEWS README"
diff --git a/dev-libs/folks/folks-0.6.4.1.ebuild b/dev-libs/folks/folks-0.6.4.1.ebuild
deleted file mode 100644
index 6195bc0..0000000
--- a/dev-libs/folks/folks-0.6.4.1.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-
-inherit autotools eutils gnome2
-
-DESCRIPTION="libfolks is a library that aggregates people from multiple sources"
-HOMEPAGE="http://telepathy.freedesktop.org/wiki/Folks"
-
-LICENSE="LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
-IUSE="eds socialweb test tracker vala"
-
-COMMON_DEPEND=">=dev-libs/glib-2.24:2
- >=net-libs/telepathy-glib-0.13.1
- dev-libs/dbus-glib
- <dev-libs/libgee-0.7:0[introspection]
- dev-libs/libxml2
- >=gnome-base/gconf-2.31
- sys-libs/ncurses
- sys-libs/readline
-
- eds? ( >=gnome-extra/evolution-data-server-3.1.5 )
- socialweb? ( >=net-libs/libsocialweb-0.25.15 )
- tracker? ( >=app-misc/tracker-0.12 )"
-
-# telepathy-mission-control needed at runtime; it is used by the telepathy
-# backend via telepathy-glib's AccountManager binding.
-RDEPEND="${COMMON_DEPEND}
- net-im/telepathy-mission-control"
-
-# folks socialweb backend requires that libsocialweb be built with USE=vala,
-# even when building folks with --disable-vala.
-DEPEND="${COMMON_DEPEND}
- >=dev-libs/gobject-introspection-0.9.12
- >=dev-util/intltool-0.35.0
- >=dev-util/pkgconfig-0.21
- sys-devel/gettext
-
- socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
- test? ( sys-apps/dbus )
- vala? (
- >=dev-lang/vala-0.13.4:0.14[vapigen]
- >=net-libs/telepathy-glib-0.13.1[vala]
- eds? ( >=gnome-extra/evolution-data-server-3.0.1[vala] ) )"
-
-# XXX: tests appear to use installed version of folks
-RESTRICT="test"
-
-pkg_setup() {
- DOCS="AUTHORS ChangeLog NEWS README"
- # Rebuilding docs needs valadoc, which has no release
- G2CONF="${G2CONF}
- $(use_enable eds eds-backend)
- $(use_enable socialweb libsocialweb-backend)
- $(use_enable tracker tracker-backend)
- $(use_enable vala)
- $(use_enable vala inspect-tool)
- --enable-import-tool
- --disable-docs
- --disable-Werror"
- if use vala; then
- G2CONF="${G2CONF}
- VALAC=$(type -p valac-0.14)
- VAPIGEN=$(type -p vapigen-0.14)"
- fi
-}
-
-src_test() {
- # FIXME: several eds backend tests fail
- sed -e 's/check: .*/check: /' \
- -i tests/eds/Makefile || die "sed failed"
- # Don't run make check in po/
- cd tests
- dbus-launch emake check
-}
diff --git a/gnome-base/gnome-common/gnome-common-3.1.0.ebuild b/gnome-base/gnome-common/gnome-common-3.1.0.ebuild
deleted file mode 100644
index 1fce8b5..0000000
--- a/gnome-base/gnome-common/gnome-common-3.1.0.ebuild
+++ /dev/null
@@ -1,21 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-
-inherit base gnome.org
-
-DESCRIPTION="Common files for development of Gnome packages"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-3"
-SLOT="3"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE=""
-
-src_install() {
- base_src_install
- mv doc-build/README README.doc-build || die "renaming doc-build/README failed"
- dodoc ChangeLog README* doc/usage.txt || die "dodoc failed"
-}
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.2.2.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.2.2.ebuild
deleted file mode 100644
index 6a81d3d..0000000
--- a/gnome-extra/gnome-contacts/gnome-contacts-3.2.2.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="no"
-
-inherit gnome2
-if [[ ${PV} = 9999 ]]; then
- inherit gnome2-live
-fi
-
-DESCRIPTION="GNOME contact management application"
-HOMEPAGE="https://live.gnome.org/Design/Apps/Contacts"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE=""
-if [[ ${PV} = 9999 ]]; then
- KEYWORDS=""
-else
- KEYWORDS="~amd64 ~x86"
-fi
-
-RDEPEND=">=dev-libs/folks-0.6.1.1
- >=dev-libs/glib-2.29.12:2
- dev-libs/libgee:0
- >=gnome-extra/evolution-data-server-3[gnome-online-accounts]
- >=gnome-base/gnome-desktop-3.0:3
- net-libs/gnome-online-accounts
- net-libs/telepathy-glib
- x11-libs/cairo
- x11-libs/gdk-pixbuf:2
- >=x11-libs/gtk+-3.0:3
- x11-libs/libnotify
- x11-libs/pango"
-DEPEND="${RDEPEND}
- dev-util/pkgconfig
- >=dev-util/intltool-0.40
- >=sys-devel/gettext-0.17"
-
-if [[ ${PV} = 9999 ]]; then
- DEPEND="${DEPEND}
- >=dev-lang/vala-0.14.0:0.14
- net-libs/telepathy-glib[vala]"
-fi
-
-pkg_setup() {
- DOCS="AUTHORS ChangeLog NEWS" # README is empty
- # configure checks for valac, but will not use it when building from tarball
- if [[ ${PV} = 9999 ]]; then
- G2CONF="${G2CONF} VALAC=$(type -p valac-0.14)"
- fi
-}
diff --git a/gnome-extra/gnome-user-docs/gnome-user-docs-3.2.1.ebuild b/gnome-extra/gnome-user-docs/gnome-user-docs-3.2.1.ebuild
deleted file mode 100644
index 5783a61..0000000
--- a/gnome-extra/gnome-user-docs/gnome-user-docs-3.2.1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-GCONF_DEBUG="no"
-
-inherit gnome2
-
-DESCRIPTION="GNOME end user documentation"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="CC-Attribution-3.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="test"
-
-# Newer gnome-doc-utils is needed for RNGs
-# libxml2 needed for xmllint
-# scrollkeeper is referenced in gnome-user-docs.spec, but is not used
-RDEPEND=""
-DEPEND="test? (
- >=app-text/gnome-doc-utils-0.20.5
- dev-libs/libxml2 )"
-# eautoreconf requires:
-# app-text/yelp-tools
-# rebuilding translations requires:
-# dev-libs/libxml2
-# dev-util/gettext
-# dev-util/itstool
-
-# This ebuild does not install any binaries
-RESTRICT="binchecks strip"
-
-DOCS="AUTHORS ChangeLog NEWS README"
-
-pkg_setup() {
- # itstool is only needed for rebuilding translations
- G2CONF="${G2CONF} ITSTOOL=$(type -P true)"
- # xmllint is only needed for tests
- use test || G2CONF="${G2CONF} XMLLINT=$(type -P true)"
-}
-
-src_compile() {
- # Do not compile; "make all" with unset LINGUAS rebuilds all translations,
- # which can takes > 2 hours on a Core i7.
- return
-}
diff --git a/gnome-extra/yelp-xsl/yelp-xsl-3.2.1.ebuild b/gnome-extra/yelp-xsl/yelp-xsl-3.2.1.ebuild
deleted file mode 100644
index 223b72f..0000000
--- a/gnome-extra/yelp-xsl/yelp-xsl-3.2.1.ebuild
+++ /dev/null
@@ -1,30 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-
-inherit gnome.org
-
-DESCRIPTION="XSL stylesheets for yelp"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-2 LGPL-2.1"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE=""
-
-RDEPEND=">=dev-libs/libxml2-2.6.12
- >=dev-libs/libxslt-1.1.8"
-DEPEND="${RDEPEND}
- sys-apps/gawk
- sys-devel/gettext
- >=dev-util/intltool-0.40
- dev-util/itstool
- >=dev-util/pkgconfig-0.9"
-
-src_install() {
- emake DESTDIR="${D}" install || die "emake install failed"
-
- dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"
-}
diff --git a/gnome-extra/yelp/files/yelp-3.0.3-man-compatibility.patch b/gnome-extra/yelp/files/yelp-3.0.3-man-compatibility.patch
deleted file mode 100644
index b57591c..0000000
--- a/gnome-extra/yelp/files/yelp-3.0.3-man-compatibility.patch
+++ /dev/null
@@ -1,117 +0,0 @@
-From 7e181e8d74f7e67b8b3acb8524fc85157ed39c8e Mon Sep 17 00:00:00 2001
-From: Alexandre Rostovtsev <tetromino@gmail.com>
-Date: Sun, 1 May 2011 22:52:14 -0400
-Subject: [PATCH] Enable compatibility with traditional man (#648854)
-
-As of commit 46a82ade3e6f0fac8f08b18e7fc23d8665f6f728, Yelp runs
-"man -Z -Tutf8 -EUTF-8 [FILE]" to obtain the groff intermediate format
-of the man page. However, the only implementation of man that accepts
-these options is man-db (used by Debian, Fedora, SUSE & Ubuntu).
-The traditional Linux man used by other distros and man implementations
-on non-Linux Unixes (FreeBSD, Solaris) do not have command-line options
-for outputting groff intermediate format.
-Therefore, on systems that do not use man-db, we need to manually
-uncompress the nroff source file and feed it to groff. This is best done
-using a small shell script (/usr/libexec/yelp-groff), both for for
-clarity and for ease of modification on systems with weird man setups.
-
-Signed-off-by: Alexandre Rostovtsev <tetromino@gmail.com>
----
- libyelp/Makefile.am | 2 +
- libyelp/yelp-groff | 49 +++++++++++++++++++++++++++++++++++++++++++++
- libyelp/yelp-man-parser.c | 4 +-
- 3 files changed, 53 insertions(+), 2 deletions(-)
- create mode 100755 libyelp/yelp-groff
-
-diff --git a/libyelp/Makefile.am b/libyelp/Makefile.am
-index a4dd68b..5d55bf1 100644
---- a/libyelp/Makefile.am
-+++ b/libyelp/Makefile.am
-@@ -1,4 +1,5 @@
- lib_LTLIBRARIES = libyelp.la
-+libexec_SCRIPTS = yelp-groff
-
- libyelp_la_SOURCES = \
- yelp-bookmarks.c \
-@@ -49,6 +50,7 @@ endif
- libyelp_la_CFLAGS = \
- $(YELP_CFLAGS) \
- -DDATADIR=\""$(datadir)"\" \
-+ -DLIBEXECDIR=\"$(libexecdir)\" \
- -DYELP_ICON_PATH=\"$(YELP_ICON_PATH)\"
-
- libyelp_la_LIBADD = $(YELP_LIBS)
-diff --git a/libyelp/yelp-groff b/libyelp/yelp-groff
-new file mode 100755
-index 0000000..5348024
---- /dev/null
-+++ b/libyelp/yelp-groff
-@@ -0,0 +1,49 @@
-+#!/bin/sh
-+#
-+# Copyright (c) 2011 Alexandre Rostovtsev <tetromino@gmail.com>
-+#
-+# This program is free software; you can redistribute it and/or
-+# modify it under the terms of the GNU General Public License as
-+# published by the Free Software Foundation; either version 2 of the
-+# License, or (at your option) any later version.
-+#
-+# This program is distributed in the hope that it will be useful,
-+# but WITHOUT ANY WARRANTY; without even the implied warranty of
-+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
-+# General Public License for more details.
-+#
-+# You should have received a copy of the GNU General Public
-+# License along with this program; if not, write to the
-+# Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
-+# Boston, MA 02110-1301, USA.
-+#
-+###
-+#
-+# Process the requested compressed source nroff file and output groff
-+# intermediate format.
-+#
-+
-+filename=$1
-+
-+if [ -z ${filename} ] ; then
-+ echo "Usage: yelp-groff [FILE]" >&2
-+ echo "Process a man FILE and output groff intermediate format."
-+ exit 1
-+fi
-+
-+# If "man -Z -Tutf8 -EUTF-8" works (i.e. if man is man-db), use that.
-+man -Z -Tutf8 -EUTF-8 ${filename} 2>/dev/null && exit 0
-+
-+# Otherwise, manually uncompress the file ...
-+cat="cat"
-+case ${filename} in
-+ *.bz2) cat="bzip2 -c -d" ;;
-+ *.gz) cat="gunzip -c" ;;
-+ *.lzma) cat="unlzma -c -d" ;;
-+ *.xz) cat="unxz -c" ;;
-+ *.Z) cat="zcat" ;;
-+esac
-+
-+# ... and run groff to get the intermediate format; preprocess with tbl
-+# unless MANROFFSEQ is defined.
-+${cat} ${filename} | groff -${MANROFFSEQ:-t} -man -Z -Tutf8
-diff --git a/libyelp/yelp-man-parser.c b/libyelp/yelp-man-parser.c
-index 4001d38..9818803 100644
---- a/libyelp/yelp-man-parser.c
-+++ b/libyelp/yelp-man-parser.c
-@@ -371,9 +371,9 @@ get_troff (gchar *path, GError **error)
- {
- gint stdout;
- GError *err = NULL;
-- gchar *argv[] = { "man", "-Z", "-Tutf8", "-EUTF-8", NULL, NULL };
-+ gchar *argv[] = { LIBEXECDIR "/yelp-groff", NULL, NULL };
-
-- argv[4] = path;
-+ argv[1] = path;
-
- if (!g_spawn_async_with_pipes (NULL, argv, NULL,
- G_SPAWN_SEARCH_PATH, NULL, NULL,
---
-1.7.5.rc3
-
diff --git a/gnome-extra/yelp/yelp-3.2.1.ebuild b/gnome-extra/yelp/yelp-3.2.1.ebuild
deleted file mode 100644
index 2b5bee6..0000000
--- a/gnome-extra/yelp/yelp-3.2.1.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/yelp/yelp-2.30.1-r1.ebuild,v 1.1 2010/06/13 20:04:06 pacho Exp $
-
-EAPI="4"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-
-inherit autotools eutils gnome2
-
-DESCRIPTION="Help browser for GNOME"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~sparc ~x86 ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
-# FIXME: gtk-doc scanner fails assertion in gtk_icon_theme_get_for_screen().
-# How? Why?
-IUSE="" # doc
-
-# yelp-xsl-3.1.1 neded due to commit ee830ed9
-RDEPEND="
- >=x11-libs/gtk+-2.91.8:3
- >=dev-libs/glib-2.25.11:2
- >=dev-libs/libxml2-2.6.5:2
- >=dev-libs/libxslt-1.1.4
- >=dev-libs/dbus-glib-0.71
- >=gnome-extra/yelp-xsl-3.1.1
- >=net-libs/webkit-gtk-1.3.2:3
- >=app-arch/xz-utils-4.9
- app-arch/bzip2
- dev-db/sqlite:3"
-DEPEND="${RDEPEND}
- >=sys-devel/gettext-0.17
- >=dev-util/intltool-0.41.0
- >=dev-util/pkgconfig-0.9
- gnome-base/gnome-common"
-# doc? ( >=dev-util/gtk-doc-1.13 )
-# If eautoreconf:
-# gnome-base/gnome-common
-
-pkg_setup() {
- DOCS="AUTHORS ChangeLog NEWS README TODO"
- G2CONF="${G2CONF}
- --disable-static
- --disable-schemas-compile
- --enable-bz2
- --enable-lzma"
-}
-
-src_prepare() {
- # Fix compatibility with Gentoo's sys-apps/man
- # https://bugzilla.gnome.org/show_bug.cgi?id=648854
- epatch "${FILESDIR}/${PN}-3.0.3-man-compatibility.patch"
-
- eautoreconf
-
- gnome2_src_prepare
-}
diff --git a/net-im/empathy/empathy-3.2.1.1.ebuild b/net-im/empathy/empathy-3.2.1.1.ebuild
deleted file mode 100644
index 4bc195d..0000000
--- a/net-im/empathy/empathy-3.2.1.1.ebuild
+++ /dev/null
@@ -1,127 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-2.32.2.ebuild,v 1.6 2011/02/05 17:10:33 ssuominen Exp $
-
-EAPI="4"
-GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
-PYTHON_DEPEND="2:2.4"
-
-inherit gnome2 python
-if [[ ${PV} = 9999 ]]; then
- inherit gnome2-live
-fi
-
-DESCRIPTION="Telepathy client and library using GTK+"
-HOMEPAGE="http://live.gnome.org/Empathy"
-
-LICENSE="GPL-2"
-SLOT="0"
-if [[ ${PV} = 9999 ]]; then
- KEYWORDS=""
-else
- KEYWORDS="~amd64 ~x86 ~x86-linux"
-fi
-IUSE="call debug eds +map +geoloc gnome-online-accounts +networkmanager sendto spell test +v4l"
-
-# FIXME: gst-plugins-bad is required for the valve plugin. This should move to good
-# eventually at which point the dep can be dropped
-# libgee extensively used in libempathy
-# gdk-pixbuf and pango extensively used in libempathy-gtk
-RDEPEND=">=dev-libs/glib-2.28:2
- x11-libs/gdk-pixbuf:2
- >=x11-libs/gtk+-3.0.2:3
- x11-libs/pango
- >=dev-libs/dbus-glib-0.51
- >=dev-libs/folks-0.6.2
- dev-libs/libgee:0
- >=gnome-base/gnome-keyring-2.91.4-r300
- >=media-libs/libcanberra-0.25[gtk3]
- media-sound/pulseaudio[glib]
- >=net-libs/gnutls-2.8.5
- >=net-libs/telepathy-glib-0.16.0
- >=net-libs/webkit-gtk-1.3.13:3
- >=x11-libs/libnotify-0.7
-
- dev-libs/libxml2:2
- gnome-base/gsettings-desktop-schemas
- media-libs/gstreamer:0.10
- media-libs/gst-plugins-base:0.10
- media-libs/gst-plugins-bad
- >=net-im/telepathy-logger-0.2.8
- net-libs/farsight2
- >=net-libs/telepathy-farsight-0.0.14
- net-voip/telepathy-connection-managers
- x11-libs/libX11
-
- call? (
- >=media-libs/clutter-1.7.14:1.0
- >=media-libs/clutter-gtk-0.90.3:1.0
- media-libs/clutter-gst:1.0
- net-libs/telepathy-farstream )
- eds? ( >=gnome-extra/evolution-data-server-1.2 )
- geoloc? ( >=app-misc/geoclue-0.11 )
- gnome-online-accounts? ( net-libs/gnome-online-accounts )
- map? (
- >=media-libs/clutter-1.7.14:1.0
- >=media-libs/clutter-gtk-0.90.3:1.0
- media-libs/libchamplain:0.12[gtk] )
- networkmanager? ( >=net-misc/networkmanager-0.7 )
- sendto? ( >=gnome-extra/nautilus-sendto-2.90.0 )
- spell? (
- >=app-text/enchant-1.2
- >=app-text/iso-codes-0.35 )
- v4l? (
- || ( sys-fs/udev[gudev] sys-fs/udev[extras] )
- media-plugins/gst-plugins-v4l2:0.10
- >=media-video/cheese-2.91.91.1 )
-"
-DEPEND="${RDEPEND}
- app-text/scrollkeeper
- >=app-text/gnome-doc-utils-0.17.3
- >=dev-util/intltool-0.35.0
- >=dev-util/pkgconfig-0.16
- >=sys-devel/gettext-0.17
- test? (
- sys-apps/grep
- >=dev-libs/check-0.9.4 )
- dev-libs/libxslt
-"
-PDEPEND=">=net-im/telepathy-mission-control-5.7.6"
-
-pkg_setup() {
- DOCS="CONTRIBUTORS AUTHORS ChangeLog NEWS README"
- G2CONF="${G2CONF}
- --disable-coding-style-checks
- --disable-schemas-compile
- --disable-static
- --disable-meego
- --disable-Werror
- $(use_enable call)
- $(use_enable debug)
- $(use_with eds)
- $(use_enable geoloc location)
- $(use_enable gnome-online-accounts goa)
- $(use_enable map)
- $(use_with networkmanager connectivity nm)
- $(use_enable sendto nautilus-sendto)
- $(use_enable spell)
- $(use_with v4l cheese)
- $(use_enable v4l gudev)"
-
- # Build time python tools need python2
- python_set_active_version 2
- python_pkg_setup
-}
-
-src_test() {
- unset DBUS_SESSION_BUS_ADDRESS
- emake check
-}
-
-pkg_postinst() {
- gnome2_pkg_postinst
- elog "Empathy needs telepathy's connection managers to use any IM protocol."
- elog "See the USE flags on net-voip/telepathy-connection-managers"
- elog "to install them."
-}
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2011-11-04 20:19 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-11-04 20:19 [gentoo-commits] proj/gnome:master commit in: gnome-extra/gnome-contacts/, gnome-extra/yelp/, gnome-extra/yelp-xsl/, Alexandre Restovtsev
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox