[gentoo-commits] proj/kde:master commit in: kde-base/krdc/, kde-base/kdnssd/, kde-base/krfb/, kde-base/kget/, ...

[gentoo-commits] proj/kde:master commit in: kde-base/krdc/, kde-base/kdnssd/, kde-base/krfb/, kde-base/kget/, ...

[Jorge Manuel B. S. Vicetto]

commit:     d2a0def743109d9bcf7b55e19b6a41f449e0e440
Author:     Jorge Manuel B. S. Vicetto (jmbsvicetto) <jmbsvicetto <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 24 11:46:03 2011 +0000
Commit:     Jorge Manuel B. S. Vicetto <jmbsvicetto <AT> gentoo <DOT> org>
CommitDate: Fri Jun 24 11:51:17 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=d2a0def7

[kdenetwork] Bump to 4.6.90 release now that we have the tarball.

(Portage version: 2.2.0_alpha41/git/Linux x86_64, RepoMan options: --force, signed Manifest commit with key BB0E6E98)

---
 .../kdenetwork-filesharing-4.6.90.ebuild           |   13 ++
 kde-base/kdnssd/kdnssd-4.6.90.ebuild               |   23 +++
 kde-base/kget/kget-4.6.90.ebuild                   |   41 +++++
 kde-base/kopete/kopete-4.6.90.ebuild               |  164 ++++++++++++++++++++
 kde-base/krdc/krdc-4.6.90.ebuild                   |   42 +++++
 kde-base/krfb/krfb-4.6.90.ebuild                   |   20 +++
 6 files changed, 303 insertions(+), 0 deletions(-)

diff --git a/kde-base/kdenetwork-filesharing/kdenetwork-filesharing-4.6.90.ebuild b/kde-base/kdenetwork-filesharing/kdenetwork-filesharing-4.6.90.ebuild
new file mode 100644
index 0000000..50d7758
--- /dev/null
+++ b/kde-base/kdenetwork-filesharing/kdenetwork-filesharing-4.6.90.ebuild
@@ -0,0 +1,13 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KMNAME="kdenetwork"
+KMMODULE="filesharing"
+inherit kde4-meta
+
+DESCRIPTION="kcontrol filesharing config module for NFS, SMB etc"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"

diff --git a/kde-base/kdnssd/kdnssd-4.6.90.ebuild b/kde-base/kdnssd/kdnssd-4.6.90.ebuild
new file mode 100644
index 0000000..bcab399
--- /dev/null
+++ b/kde-base/kdnssd/kdnssd-4.6.90.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="A DNSSD (DNS Service Discovery - part of Rendezvous) ioslave and kded module"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug zeroconf"
+
+DEPEND="
+	zeroconf? ( $(add_kdebase_dep kdelibs zeroconf) )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	mycmakeargs=(-DWITH_Xmms=OFF -DWITH_DNSSD=ON)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kget/kget-4.6.90.ebuild b/kde-base/kget/kget-4.6.90.ebuild
new file mode 100644
index 0000000..f5010e1
--- /dev/null
+++ b/kde-base/kget/kget-4.6.90.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="An advanced download manager for KDE"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug bittorrent mms semantic-desktop sqlite webkit"
+
+RDEPEND="
+	app-crypt/qca:2
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep libkonq)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep solid)
+	bittorrent? ( >=net-libs/libktorrent-1.0.3 )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+	webkit? ( >=kde-misc/kwebkitpart-0.9.6 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with bittorrent KTorrent)
+		$(cmake-utils_use_with mms LibMms)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with sqlite)
+		$(cmake-utils_use_with webkit KWebKitPart)
+	)
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kopete/kopete-4.6.90.ebuild b/kde-base/kopete/kopete-4.6.90.ebuild
new file mode 100644
index 0000000..a6b8ced
--- /dev/null
+++ b/kde-base/kopete/kopete-4.6.90.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="KDE multi-protocol IM client"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug ssl v4l2"
+
+# tests hang, last checked for 4.2.96
+RESTRICT=test
+
+# Available plugins
+#
+#	addbookmarks: NO DEPS
+#	alias: NO DEPS (disabled upstream)
+#	autoreplace: NO DEPS
+#	contactnotes: NO DEPS
+#	highlight: NO DEPS
+#	history: NO DEPS
+#	latex: virtual/latex as RDEPEND
+#	nowlistening: NO DEPS
+#	otr: libotr
+#	pipes: NO DEPS
+#	privacy: NO DEPS
+#	statistics: dev-db/sqlite:3
+#	texteffect: NO DEPS
+#	translator: NO DEPS
+#	urlpicpreview: NO DEPS
+#	webpresence: libxml2 libxslt
+# NOTE: By default we enable all plugins that don't have any dependencies
+PLUGINS="+addbookmarks +autoreplace +contactnotes +highlight +history latex
++nowlistening otr +pipes +privacy +statistics +texteffect +translator
++urlpicpreview webpresence"
+
+# Available protocols
+#
+#	gadu: net-libs/libgadu @since 4.3
+#	groupwise: app-crypt/qca:2
+#	irc: NO DEPS, probably will fail so inform user about it
+#	xmpp: net-dns/libidn app-crypt/qca:2 ENABLED BY DEFAULT NETWORK
+#	jingle: media-libs/speex net-libs/ortp DISABLED BY UPSTREAM
+#	meanwhile: net-libs/meanwhile
+#	msn: libmsn == this is wlm plugin, we disable msn one
+#	oscar: NO DEPS
+#	qq: NO DEPS
+#   telepathy: net-libs/decibel
+#   testbed: NO DEPS
+#	winpopup: NO DEPS (we're adding samba as RDEPEND so it works)
+#	yahoo: media-libs/jasper
+#	zeroconf (bonjour): NO DEPS
+PROTOCOLS="gadu groupwise jingle meanwhile msn oscar qq skype
+sms testbed winpopup +xmpp yahoo zeroconf"
+
+# disabled protocols
+#   telepathy: net-libs/decibel
+#   irc: NO DEPS
+
+IUSE="${IUSE} ${PLUGINS} ${PROTOCOLS}"
+
+COMMONDEPEND="
+	dev-libs/libpcre
+	$(add_kdebase_dep kdepimlibs)
+	media-libs/qimageblitz
+	>=x11-libs/qt-gui-4.4.0:4[mng]
+	!aqua? ( x11-libs/libXScrnSaver )
+	gadu? ( >=net-libs/libgadu-1.8.0[threads] )
+	groupwise? ( app-crypt/qca:2 )
+	jingle? (
+		>=media-libs/mediastreamer-2.3.0
+		media-libs/speex
+		net-libs/ortp
+	)
+	meanwhile? ( net-libs/meanwhile )
+	msn? ( >=net-libs/libmsn-4.1 )
+	otr? ( >=net-libs/libotr-3.2.0 )
+	statistics? ( dev-db/sqlite:3 )
+	v4l2? ( media-libs/libv4l )
+	webpresence? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+	)
+	xmpp? (
+		app-crypt/qca:2
+		net-dns/libidn
+	)
+	yahoo? ( media-libs/jasper )
+"
+RDEPEND="${COMMONDEPEND}
+	latex? (
+		|| (
+			media-gfx/imagemagick
+			media-gfx/graphicsmagick[imagemagick]
+		)
+		virtual/latex-base
+	)
+	sms? ( app-mobilephone/smssend )
+	ssl? ( app-crypt/qca-ossl )
+	winpopup? ( net-fs/samba )
+"
+#	telepathy? ( net-libs/decibel )"
+DEPEND="${COMMONDEPEND}
+	!aqua? ( x11-proto/scrnsaverproto )
+"
+
+src_prepare() {
+	sed -e "s:lib/mozilla:$(get_libdir)/mozilla:" \
+		-i kopete/protocols/skype/skypebuttons/CMakeLists.txt || die "sed failed"
+
+	kde4-meta_src_prepare
+}
+
+src_configure() {
+	local x x2
+	# Handle common stuff
+	mycmakeargs=(
+		$(cmake-utils_use_with jingle GOOGLETALK)
+		$(cmake-utils_use_with jingle LiboRTP)
+		$(cmake-utils_use_with jingle Mediastreamer)
+		$(cmake-utils_use_with jingle Speex)
+		$(cmake-utils_use_disable v4l2 VIDEOSUPPORT)
+	)
+	# enable protocols
+	for x in ${PROTOCOLS}; do
+		case ${x/+/} in
+			msn) x2=Libmsn ;;
+			zeroconf) x2=bonjour ;;
+			xmpp) x2=jabber ;;
+			*) x2='' ;;
+		esac
+		mycmakeargs+=($(cmake-utils_use_with ${x/+/} ${x2}))
+	done
+
+	# enable plugins
+	for x in ${PLUGINS}; do
+		mycmakeargs+=($(cmake-utils_use_with ${x/+/}))
+	done
+
+	kde4-meta_src_configure
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	#if use telepathy; then
+	#	elog "To use kopete telepathy plugins, you need to start gabble first:"
+	#	elog "GABBLE_PERSIST=1 telepathy-gabble &"
+	#	elog "export TELEPATHY_DATA_PATH='${EPREFIX}/usr/share/telepathy/managers/'"
+	#fi
+
+	if ! use ssl; then
+		if use xmpp || use msn; then # || use irc; then
+			echo
+			elog "In order to use ssl in xmpp and msn you'll need to"
+			elog "install app-crypt/qca-ossl package."
+			echo
+		fi
+	fi
+}

diff --git a/kde-base/krdc/krdc-4.6.90.ebuild b/kde-base/krdc/krdc-4.6.90.ebuild
new file mode 100644
index 0000000..2d8f210
--- /dev/null
+++ b/kde-base/krdc/krdc-4.6.90.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="KDE remote desktop connection (RDP and VNC) client"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug jpeg rdesktop vnc zeroconf"
+
+#nx? ( >=net-misc/nxcl-0.9-r1 ) disabled upstream, last checked 4.3.61
+#telepathy? ( >=net-libs/telepathy-qt4-0.18 ) not yet in portage/overlay
+
+DEPEND="
+	jpeg? ( virtual/jpeg )
+	vnc? ( >=net-libs/libvncserver-0.9 )
+	zeroconf? (
+		|| (
+			net-dns/avahi
+			net-misc/mDNSResponder
+		)
+	)
+"
+RDEPEND="${DEPEND}
+	rdesktop? ( net-misc/rdesktop )
+"
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_TelepathyQt4=OFF
+		$(cmake-utils_use_with jpeg)
+		# $(cmake-utils_use_with telepathy TelepathyQt4)
+		$(cmake-utils_use_with vnc LibVNCServer)
+		$(cmake-utils_use_with zeroconf DNSSD)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/krfb/krfb-4.6.90.ebuild b/kde-base/krfb/krfb-4.6.90.ebuild
new file mode 100644
index 0000000..ca35184
--- /dev/null
+++ b/kde-base/krfb/krfb-4.6.90.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="VNC-compatible server to share KDE desktops"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	sys-libs/zlib
+	virtual/jpeg
+	!aqua? ( x11-libs/libXdamage )
+"
+RDEPEND="${DEPEND}"