[gentoo-commits] dev/maekke:master commit in: media-gfx/hugin/

["Markus Meier" <maekke@gentoo.org>]

commit:     bb47db364eaff9dded738039f82a9e99fc4a5453
Author:     Markus Meier <maekke <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 17 21:01:51 2011 +0000
Commit:     Markus Meier <maekke <AT> gentoo <DOT> org>
CommitDate: Sun Jul 17 21:01:51 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=dev/maekke.git;a=commit;h=bb47db36

version bump

---
 media-gfx/hugin/hugin-2011.2.0_rc1.ebuild |   66 +++++++++++++++++++++++++++++
 1 files changed, 66 insertions(+), 0 deletions(-)

diff --git a/media-gfx/hugin/hugin-2011.2.0_rc1.ebuild b/media-gfx/hugin/hugin-2011.2.0_rc1.ebuild
new file mode 100644
index 0000000..9722617
--- /dev/null
+++ b/media-gfx/hugin/hugin-2011.2.0_rc1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2011.0.0.ebuild,v 1.1 2011/05/29 21:07:01 maekke Exp $
+
+EAPI=3
+WX_GTK_VER="2.8"
+PYTHON_DEPEND="python? 2:2.6 3"
+
+inherit python wxwidgets versionator cmake-utils
+
+DESCRIPTION="GUI for the creation & processing of panoramic images"
+HOMEPAGE="http://hugin.sf.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+LICENSE="GPL-2 SIFT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+LANGS=" bg ca cs de en_GB es fi fr hu it ja ko nl pl pt_BR ro ru sk sl sv uk zh_CN zh_TW"
+IUSE="lapack python sift $(echo ${LANGS//\ /\ linguas_})"
+
+CDEPEND="
+	!!dev-util/cocom
+	app-arch/zip
+	dev-cpp/tclap
+	>=dev-libs/boost-1.35.0-r5
+	dev-libs/zthread
+	>=media-gfx/enblend-4.0
+	media-gfx/exiv2
+	media-libs/freeglut
+	>=media-libs/libpano13-2.9.18
+	media-libs/libpng
+	media-libs/openexr
+	media-libs/tiff
+	sys-libs/zlib
+	virtual/jpeg
+	x11-libs/wxGTK:2.8[X,opengl,-odbc]
+	lapack? ( virtual/lapack )
+	sift? ( media-gfx/autopano-sift-C )"
+RDEPEND="${CDEPEND}
+	media-libs/exiftool"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig
+	python? ( >=dev-lang/swig-2.0.4 )"
+
+S=${WORKDIR}/${PN}-$(get_version_component_range 1-3)
+
+pkg_setup() {
+	DOCS="authors.txt README TODO"
+	mycmakeargs=(
+		$(cmake-utils_use_enable lapack LAPACK)
+		$(cmake-utils_use_build python HSI)
+	)
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	for lang in ${LANGS} ; do
+		case ${lang} in
+			ca) dir=ca_ES;;
+			cs) dir=cs_CZ;;
+			*) dir=${lang};;
+		esac
+		use linguas_${lang} || rm -r "${D}"/usr/share/locale/${dir}
+	done
+}