[gentoo-commits] gentoo-x86 commit in net-irc/irssi: ChangeLog irssi-0.8.15.ebuild

["Sven Wegener (swegener)" <swegener@gentoo.org>]

swegener    10/04/04 20:42:29

  Modified:             ChangeLog
  Added:                irssi-0.8.15.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.158                net-irc/irssi/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/irssi/ChangeLog?rev=1.158&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/irssi/ChangeLog?rev=1.158&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/irssi/ChangeLog?r1=1.157&r2=1.158

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v
retrieving revision 1.157
retrieving revision 1.158
diff -u -r1.157 -r1.158
--- ChangeLog	22 Mar 2010 20:16:58 -0000	1.157
+++ ChangeLog	4 Apr 2010 20:42:29 -0000	1.158
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/irssi
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v 1.157 2010/03/22 20:16:58 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v 1.158 2010/04/04 20:42:29 swegener Exp $
+
+*irssi-0.8.15 (04 Apr 2010)
+
+  04 Apr 2010; Sven Wegener <swegener@gentoo.org> +irssi-0.8.15.ebuild:
+  Version bump.
 
 *irssi-0.8.15_rc1 (22 Mar 2010)
 



1.1                  net-irc/irssi/irssi-0.8.15.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/irssi/irssi-0.8.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/irssi/irssi-0.8.15.ebuild?rev=1.1&content-type=text/plain

Index: irssi-0.8.15.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/irssi-0.8.15.ebuild,v 1.1 2010/04/04 20:42:29 swegener Exp $

EAPI="2"

inherit perl-module

# Keep for _rc compability
MY_P="${P/_/-}"

DESCRIPTION="A modular textUI IRC client with IPv6 support"
HOMEPAGE="http://irssi.org/"
SRC_URI="http://irssi.org/files/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="ipv6 +perl ssl socks5"

RDEPEND="sys-libs/ncurses
	>=dev-libs/glib-2.2.1
	ssl? ( dev-libs/openssl )
	perl? ( dev-lang/perl )
	socks5? ( >=net-proxy/dante-1.1.18 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0"
RDEPEND="${RDEPEND}
	perl? ( !net-im/silc-client )
	!net-irc/irssi-svn"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	epunt_cxx
}

src_configure() {
	econf \
		--with-proxy \
		--with-ncurses \
		--with-perl-lib=vendor \
		$(use_with perl) \
		$(use_with socks5 socks) \
		$(use_enable ssl) \
		$(use_enable ipv6) \
		|| die "econf failed"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		docdir=/usr/share/doc/${PF} \
		install || die "make install failed"

	use perl && fixlocalpod

	dodoc AUTHORS ChangeLog README TODO NEWS || die "dodoc failed"
}