[gentoo-commits] gentoo-x86 commit in games-arcade/teeworlds: teeworlds-0.5.2.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in games-arcade/teeworlds: teeworlds-0.5.2.ebuild ChangeLog metadata.xml

[Mounir Lamouri (volkmar)]

volkmar     10/03/25 17:58:18

  Added:                teeworlds-0.5.2.ebuild ChangeLog metadata.xml
  Log:
  Initial commit.
  Fix bug 206287.
  (Portage version: 15511-svn/cvs/Linux i686)

Revision  Changes    Path
1.1                  games-arcade/teeworlds/teeworlds-0.5.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/teeworlds-0.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/teeworlds-0.5.2.ebuild?rev=1.1&content-type=text/plain

Index: teeworlds-0.5.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/teeworlds/teeworlds-0.5.2.ebuild,v 1.1 2010/03/25 17:58:18 volkmar Exp $

EAPI=2

inherit eutils python games

DESCRIPTION="Online multi-player platform 2D shooter"
HOMEPAGE="http://www.teeworlds.com/"
SRC_URI="http://www.teeworlds.com/files/${P}-src.tar.gz"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug dedicated server"

RDEPEND="
	!dedicated? ( media-libs/pnglite
		media-libs/libsdl[X,audio,opengl,video]
		media-sound/wavpack
		virtual/opengl
		x11-libs/libX11 )
	sys-libs/zlib"
DEPEND="${RDEPEND}
	=dev-lang/python-2*
	<=dev-util/bam-0.2.0"

S=${WORKDIR}/${P}-src

pkg_setup() {
	python_set_active_version 2
	games_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-system-libs.patch \
		"${FILESDIR}"/${P}-wavpack.patch

	# fix includes
	sed -i -e "s:.engine/external/pnglite/pnglite.h.:<pnglite.h>:" \
		src/engine/client/ec_gfx.c src/tools/dilate.c \
		src/tools/tileset_borderfix.c \
		|| die "sed failed"
	sed -i -e "s:.engine/external/wavpack/wavpack.h.:<wavpack/wavpack.h>:" \
		src/engine/client/ec_snd.c || die "sed failed"

	# use ${GAMES_DATADIR} instead of ./data
	sed -i -e \
		"s:^\(#define DATA_DIR\) \"data\":\1 \"${GAMES_DATADIR}/${PN}\":" \
		src/engine/e_engine.c || die "sed failed"
}

src_configure() {
	bam config || die "bam config failed"
}

src_compile() {
	local myopt

	if use dedicated || use server; then
		if use debug; then
			myopt=" server_debug"
		else
			myopt=" server_release"
		fi
	fi
	if ! use dedicated; then
		if use debug; then
			myopt+=" client_debug"
		else
			myopt+=" client_release"
		fi
	fi

	bam ${myopt} || die "bam failed"
}

src_install() {
	if use dedicated || use server; then
		if use debug; then
			newgamesbin ${PN}_srv_d ${PN}_srv || die "newgamesbin failed"
		else
			dogamesbin ${PN}_srv || die "dogamesbin failed"
		fi
	fi
	if ! use dedicated; then
		if use debug; then
			newgamesbin ${PN}_d ${PN} || die "newgamesbin failed"
		else
			dogamesbin ${PN} || die "dogamesbin failed"
		fi

		doicon "${FILESDIR}"/${PN}.xpm || die "doicon failed"
		make_desktop_entry ${PN} Teeworlds

		insinto "${GAMES_DATADIR}"/${PN}
		doins -r data/* || die "doins failed"
	else
		insinto "${GAMES_DATADIR}"/${PN}/maps
		doins -r data/maps/* || die "doins failed"
	fi

	dodoc readme.txt || die "dodoc failed"

	prepgamesdirs
}



1.1                  games-arcade/teeworlds/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for games-arcade/teeworlds
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/teeworlds/ChangeLog,v 1.1 2010/03/25 17:58:18 volkmar Exp $

*teeworlds-0.5.2 (25 Mar 2010)

  25 Mar 2010; Mounir Lamouri <volkmar@gentoo.org> +teeworlds-0.5.2.ebuild,
  +files/teeworlds-0.5.2-system-libs.patch,
  +files/teeworlds-0.5.2-wavpack.patch, +files/teeworlds.xpm, +metadata.xml:
  Initial commit. Fix bug 206287




1.1                  games-arcade/teeworlds/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/teeworlds/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>games</herd>
	<maintainer>
		<email>volkmar@gentoo.org</email>
		<name>Mounir Lamouri</name>
	</maintainer>
	<use>
		<flag name="server">Enable compilation of server</flag>
	</use>
</pkgmetadata>