[gentoo-commits] gentoo-x86 commit in app-portage/layman: ChangeLog layman-1.3.2-r2.ebuild

[gentoo-commits] gentoo-x86 commit in app-portage/layman: ChangeLog layman-1.3.2-r2.ebuild

[Sebastian Pipping (sping)]

sping       10/03/15 22:41:08

  Modified:             ChangeLog
  Added:                layman-1.3.2-r2.ebuild
  Log:
  app-portage/layman: Integrate backport patch for bug #309617
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.105                app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.105&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.105&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?r1=1.104&r2=1.105

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.104
retrieving revision 1.105
diff -u -r1.104 -r1.105
--- ChangeLog	14 Mar 2010 12:41:16 -0000	1.104
+++ ChangeLog	15 Mar 2010 22:41:07 -0000	1.105
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.104 2010/03/14 12:41:16 kolmodin Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.105 2010/03/15 22:41:07 sping Exp $
+
+*layman-1.3.2-r2 (15 Mar 2010)
+
+  15 Mar 2010; Sebastian Pipping <sping@gentoo.org> +layman-1.3.2-r2.ebuild,
+  +files/layman-1.3.2-missing-text.patch:
+  Integrate backport patch for bug #309617
 
   14 Mar 2010; Lennart Kolmodin <kolmodin@gentoo.org>
   layman-1.3.0-r1.ebuild, layman-1.3.1.ebuild, layman-1.3.2-r1.ebuild,



1.1                  app-portage/layman/layman-1.3.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.3.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.3.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: layman-1.3.2-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-1.3.2-r2.ebuild,v 1.1 2010/03/15 22:41:07 sping Exp $

EAPI="2"
NEED_PYTHON=2.5
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils

DESCRIPTION="A python script for retrieving gentoo overlays."
HOMEPAGE="http://layman.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bazaar cvs darcs git mercurial subversion test"

COMMON_DEPS="dev-lang/python[xml]"
DEPEND="${COMMON_DEPS}
	test? ( dev-util/subversion )"
RDEPEND="${COMMON_DEPS}
	bazaar? ( dev-vcs/bzr )
	cvs? ( dev-util/cvs )
	darcs? ( dev-vcs/darcs )
	git? ( dev-util/git )
	mercurial? ( dev-vcs/mercurial )
	subversion? (
		|| (
			>=dev-util/subversion-1.5.4[webdav-neon]
			>=dev-util/subversion-1.5.4[webdav-serf]
		)
	)"
RESTRICT_PYTHON_ABIS="2.4 3.*"

src_prepare() {
	epatch "${FILESDIR}"/${P}-missing-import.patch
	epatch "${FILESDIR}"/${P}-missing-text.patch
}

pkg_setup() {
	if ! has_version dev-util/subversion; then
		ewarn "You do not have dev-util/subversion installed!"
		ewarn "While layman does not exactly depend on this"
		ewarn "version control system you should note that"
		ewarn "most available overlays are offered via"
		ewarn "dev-util/subversion. If you do not install it"
		ewarn "you will be unable to use these overlays."
		ewarn
	fi
}

src_test() {
	testing() {
		for suite in layman/tests/{dtest,external}.py ; do
			PYTHONPATH="." "$(PYTHON)" ${suite} \
					|| die "test suite '${suite}' failed"
		done
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	dodir /etc/layman

	cp etc/* "${D}"/etc/layman/

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /var/lib/layman
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo "You are now ready to add overlays into your system."
	einfo
	einfo "  layman -L"
	einfo
	einfo "will display a list of available overlays."
	einfo
	elog  "Select an overlay and add it using"
	elog
	elog  "  layman -a overlay-name"
	elog
	elog  "If this is the very first overlay you add with layman,"
	elog  "you need to append the following statement to your"
	elog  "/etc/make.conf file:"
	elog
	elog  "  source /var/lib/layman/make.conf"
	elog
	elog  "If you modify the 'storage' parameter in the layman"
	elog  "configuration file (/etc/layman/layman.cfg) you will"
	elog  "need to adapt the path given above to the new storage"
	elog  "directory."
	elog
	ewarn "Please add the 'source' statement to make.conf only AFTER "
	ewarn "you added your first overlay. Otherwise portage will fail."
	epause 5
}