[gentoo-commits] gentoo-x86 commit in media-sound/qmpdclient: ChangeLog qmpdclient-1.1.2-r2.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/qmpdclient: ChangeLog qmpdclient-1.1.2-r2.ebuild

[Markos Chandras (hwoarang)]

hwoarang    10/03/15 15:37:17

  Modified:             ChangeLog
  Added:                qmpdclient-1.1.2-r2.ebuild
  Log:
  Patch to fix empty directory listing (gcc-4.4). Fixes bug #284524
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 media-sound/qmpdclient/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	14 Jan 2010 12:33:46 -0000	1.63
+++ ChangeLog	15 Mar 2010 15:37:16 -0000	1.64
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/qmpdclient
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v 1.63 2010/01/14 12:33:46 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v 1.64 2010/03/15 15:37:16 hwoarang Exp $
+
+*qmpdclient-1.1.2-r2 (15 Mar 2010)
+
+  15 Mar 2010; Markos Chandras <hwoarang@gentoo.org>
+  +files/directory_listing_gcc44.patch, +qmpdclient-1.1.2-r2.ebuild:
+  Apply patch from upstream to fix empty directory listing when qmpdclient
+  is compiled with gcc-4.4. Fixes bug #284524
 
   14 Jan 2010; Christian Faulhammer <fauli@gentoo.org>
   qmpdclient-1.1.2.ebuild:



1.1                  media-sound/qmpdclient/qmpdclient-1.1.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: qmpdclient-1.1.2-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.2-r2.ebuild,v 1.1 2010/03/15 15:37:16 hwoarang Exp $

EAPI="2"

LANGSLONG="cs_CZ de_DE fr_FR it_IT nl_NL nn_NO no_NO ru_RU sv_SE tr_TR uk_UA"
LANGS="zh_CN zh_TW pt_BR "

inherit qt4-r2

DESCRIPTION="QMPDClient with NBL additions, such as lyrics' display"
HOMEPAGE="http://bitcheese.net/wiki/QMPDClient"
SRC_URI="http://dump.bitcheese.net/files/dedycec/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="debug dbus"

DEPEND="x11-libs/qt-gui:4[dbus?]"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

PATCHES="${FILESDIR}/directory_listing_gcc44.patch"
DOCS="AUTHORS README THANKSTO Changelog"

src_prepare() {
	# Fix the install path
	sed -i -e "s:PREFIX = /usr/local:PREFIX = /usr:" ${PN}.pro \
		|| die "sed failed (install path)"

	# Fix package version
	sed -i -e "s:1.1.1:${PV}:" ${PN}.pro || die "failed to fix package version"
	# nostrip fix
	sed -i -e "s:CONFIG += :CONFIG += nostrip :" ${PN}.pro \
		|| die "sed failed (nostrip)"

	sed -i -e "s:+= -O2 -g0 -s:+= -O2 -g0:" ${PN}.pro \
		|| die "sed failed (nostrip)"

	# fix installation folder name
	sed -i "s/share\/QMPDClient/share\/qmpdclient/" ${PN}.pro src/config.cpp \
		|| die "failed to fix installation directory"

	# check dbus
	if ! use dbus; then
		sed -i -e "s/message(DBus notifier:\ enabled)/message(DBus notifier:\ disabled)/" \
			-e "s/CONFIG\ +=\ nostrip\ qdbus//" \
			-e "s/SOURCES\ +=\ src\/notifications_dbus.cpp/SOURCES\ +=\ src\/notifications_nodbus.cpp/" \
			${PN}.pro || die "disabling dbus failed"
	fi
	qt4-r2_src_prepare
}

src_compile() {
	emake || die "emake failed"
	# generate translations
	emake translate || die "failed to generate translations"
	cd "${S}"/lang
	for X in *.ts;do
		lrelease "${X}" || die "lrelease failed"
	done
}

src_install() {
	qt4-r2_src_install
	for res in 16 22 64 ; do
		insinto /usr/share/icons/hicolor/${res}x${res}/apps/
		newins icons/qmpdclient${res}.png ${PN}.png || die "Installing icons failed"
	done

	#install translations
	insinto /usr/share/${PN}/translations/
	local LANG=
	for LANG in ${LINGUAS};do
	    for X in ${LANGSLONG};do
			if [[ ${LANG} == ${X%_*} ]];then
		    	doins -r lang/${X}.qm || die "failed to install translations"
			fi
	    done
		for X in ${LANGS};do
			if [[ ${LANG} == ${X} ]]; then
				doins -r lang/${X}.qm || die "failed to install translations"
			fi
		done
	done
}