[gentoo-commits] gentoo-x86 commit in sci-biology/ncbi-tools++: ncbi-tools++-2009.05.15-r3.ebuild ChangeLog ncbi-tools++-2009.05.15-r2.ebuild

[gentoo-commits] gentoo-x86 commit in sci-biology/ncbi-tools++: ncbi-tools++-2009.05.15-r3.ebuild ChangeLog ncbi-tools++-2009.05.15-r2.ebuild

[Andrey Kislyuk (weaver)]

weaver      10/03/11 20:49:58

  Modified:             ChangeLog
  Added:                ncbi-tools++-2009.05.15-r3.ebuild
  Removed:              ncbi-tools++-2009.05.15-r2.ebuild
  Log:
  Enable --with-mt
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 sci-biology/ncbi-tools++/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	7 Mar 2010 09:19:05 -0000	1.11
+++ ChangeLog	11 Mar 2010 20:49:57 -0000	1.12
@@ -1,6 +1,12 @@
 # ChangeLog for sci-biology/ncbi-tools++
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog,v 1.11 2010/03/07 09:19:05 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/ncbi-tools++/ChangeLog,v 1.12 2010/03/11 20:49:57 weaver Exp $
+
+*ncbi-tools++-2009.05.15-r3 (11 Mar 2010)
+
+  11 Mar 2010; Andrey Kislyuk <weaver@gentoo.org>
+  -ncbi-tools++-2009.05.15-r2.ebuild, +ncbi-tools++-2009.05.15-r3.ebuild:
+  Enable --with-mt
 
   07 Mar 2010; Justin Lecher (jlec) <jlec@gentoo.org>
   ncbi-tools++-2009.05.15-r2.ebuild:



1.1                  sci-biology/ncbi-tools++/ncbi-tools++-2009.05.15-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/ncbi-tools++/ncbi-tools++-2009.05.15-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/ncbi-tools++/ncbi-tools++-2009.05.15-r3.ebuild?rev=1.1&content-type=text/plain

Index: ncbi-tools++-2009.05.15-r3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/ncbi-tools++/ncbi-tools++-2009.05.15-r3.ebuild,v 1.1 2010/03/11 20:49:57 weaver Exp $

EAPI="3"

inherit eutils multilib

MY_TAG="May_15_2009"
MY_Y="${MY_TAG/*_/}"
MY_P="ncbi_cxx--${MY_TAG}"

DESCRIPTION="NCBI C++ Toolkit, including NCBI BLAST+"
HOMEPAGE="http://www.ncbi.nlm.nih.gov/books/bv.fcgi?rid=toolkit"
SRC_URI="ftp://ftp.ncbi.nih.gov/toolbox/ncbi_tools++/${MY_Y}/${MY_TAG}/${MY_P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
#IUSE="X unicode opengl gnutls test"
IUSE="sqlite"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"

# wxGTK: must run eselect wxwindows after installing wxgtk or build will fail. Check and abort here.
# dev-libs/xalan-c - problems detecting, api mismatch?

# apparently gbench-only dependencies
#	dev-libs/libxml2
#	dev-libs/libxslt
#	dev-libs/xerces-c
#	dev-libs/lzo:2
#	dev-libs/boost
#	app-text/sablotron
#	media-libs/libpng
#	media-libs/tiff
#	media-libs/jpeg
#	x11-libs/libXpm
#	unicode? ( dev-libs/icu )
#	opengl? ( media-libs/glut
#		media-libs/mesa )
#	gnutls? ( net-libs/gnutls )
#	X? ( x11-libs/fltk:1.1
#		x11-libs/wxGTK )

DEPEND="sqlite? ( dev-db/sqlite:3 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gcc44.patch
	sed -i -e 's/-print-file-name=libstdc++.a//' src/build-system/configure
}

src_configure() {
	# required with gcc-4.4 and code turned on by --with-mt
	export CPPFLAGS="${CPPFLAGS} -fpermissive"

	# econf fails
	# --with-bin-release and --without-ftds are workarounds for build system bugs
	# NB: build system supports ICC
	"${S}"/configure --without-debug \
		--with-bin-release \
		--without-static \
		--with-dll \
		--without-ftds \
		--prefix="${ED}"/usr \
		--libdir="${ED}"/usr/$(get_libdir)/${PN} \
		--with-z="${EPREFIX}/usr" \
		--with-bz2="${EPREFIX}/usr" \
		--with-pcre="${EPREFIX}/usr" \
		--with-openssl="${EPREFIX}/usr" \
		--with-mt \
		|| die

# apparently gbench-only configs
#		--with-boost="/usr" \
#		--with-sablot="/usr" \
#		--with-icu="/usr" \
#		--with-fltk="/usr" \
#		--with-mesa="/usr" \
#		--with-glut="/usr" \
#		--with-wxwidgets="/usr" \
# problems detecting this
#		--with-xalan="/usr" \
}

src_compile() {
	emake all_r -C GCC*-Release*/build || die
}

src_install() {
	emake install || die
	# File collisions with sci-biology/ncbi-tools
	rm -f "${ED}"/usr/bin/{asn2asn,rpsblast,test_regexp}

	echo "LD_LIBRARY_PATH=${EPREFIX}/usr/$(get_libdir)/${PN}" > ${S}/99${PN}
	doenvd "${S}/99${PN}"
}

pkg_postinst() {
	einfo 'Please run "source /etc/profile" before using this package in the current shell.'
}