[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: metadata.xml ChangeLog stunnel-4.29-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: metadata.xml ChangeLog stunnel-4.29-r1.ebuild

[Lance Albertson (ramereth)]

ramereth    10/03/07 21:36:29

  Modified:             metadata.xml ChangeLog
  Added:                stunnel-4.29-r1.ebuild
  Log:
  Add X-Forwarded-For support via xforward useflag/patch, closes #306127
  (Portage version: 2.1.7.16/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-misc/stunnel/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	15 Jul 2006 13:23:48 -0000	1.3
+++ metadata.xml	7 Mar 2010 21:36:28 -0000	1.4
@@ -13,4 +13,7 @@
 		protocols (like POP, IMAP, LDAP, etc) by having Stunnel provide the
 		encryption, requiring no changes to the daemon's code.
 	</longdescription>
+	<use>
+		<flag name="xforward">Enable X-Forwarded-For support for Stunnel</flag>
+	</use>
 </pkgmetadata>



1.111                net-misc/stunnel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.111&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.111&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/ChangeLog?r1=1.110&r2=1.111

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v
retrieving revision 1.110
retrieving revision 1.111
diff -u -r1.110 -r1.111
--- ChangeLog	7 Mar 2010 21:17:13 -0000	1.110
+++ ChangeLog	7 Mar 2010 21:36:28 -0000	1.111
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/stunnel
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.110 2010/03/07 21:17:13 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.111 2010/03/07 21:36:28 ramereth Exp $
+
+*stunnel-4.29-r1 (07 Mar 2010)
+
+  07 Mar 2010; Lance Albertson <ramereth@gentoo.org>
+  +stunnel-4.29-r1.ebuild, +files/stunnel-4.29-x-forwarded-for.patch,
+  metadata.xml:
+  Add X-Forwarded-For support via xforward useflag/patch, closes #306127
 
 *stunnel-4.31 (07 Mar 2010)
 



1.1                  net-misc/stunnel/stunnel-4.29-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/stunnel-4.29-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/stunnel/stunnel-4.29-r1.ebuild?rev=1.1&content-type=text/plain

Index: stunnel-4.29-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-4.29-r1.ebuild,v 1.1 2010/03/07 21:36:28 ramereth Exp $

EAPI="2"

inherit autotools ssl-cert eutils

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://stunnel.mirt.net/"
SRC_URI="http://www.stunnel.org/download/stunnel/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="ipv6 selinux tcpd xforward"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=dev-libs/openssl-0.9.8k"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-4.21-libwrap.patch"
	use xforward && epatch "${FILESDIR}/${P}-x-forwarded-for.patch"
	eautoreconf

	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_configure() {
	econf $(use_enable ipv6) \
		$(use_enable tcpd libwrap) || die "econf died"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -rf "${D}"/usr/share/doc/${PN}
	rm -f "${D}"/etc/stunnel/stunnel.conf-sample "${D}"/usr/bin/stunnel3 \
		"${D}"/usr/share/man/man8/stunnel.{fr,pl}.8

	# The binary was moved to /usr/bin with 4.21,
	# symlink for backwards compatibility
	dosym ../bin/stunnel /usr/sbin/stunnel

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	doins "${FILESDIR}"/stunnel.conf
	newinitd "${FILESDIR}"/stunnel.initd stunnel

	keepdir /var/run/stunnel
	fowners stunnel:stunnel /var/run/stunnel
}

pkg_postinst() {
	if [ ! -f "${ROOT}"/etc/stunnel/stunnel.key ]; then
		install_cert /etc/stunnel/stunnel
		chown stunnel:stunnel "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
		chmod 0640 "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
	fi

	einfo "If you want to run multiple instances of stunnel, create a new config"
	einfo "file ending with .conf in /etc/stunnel/. **Make sure** you change "
	einfo "\'pid= \' with a unique filename."
}