[gentoo-commits] gentoo-x86 commit in sci-geosciences/mapnik: ChangeLog mapnik-0.6.1-r2.ebuild mapnik-0.6.1-r1.ebuild

[gentoo-commits] gentoo-x86 commit in sci-geosciences/mapnik: ChangeLog mapnik-0.6.1-r2.ebuild mapnik-0.6.1-r1.ebuild

[Steve Arnold (nerdboy)]

nerdboy     10/03/07 21:15:51

  Modified:             ChangeLog
  Added:                mapnik-0.6.1-r2.ebuild
  Removed:              mapnik-0.6.1-r1.ebuild
  Log:
  Added group-hack to work around broken scons boost detection; fixes bug
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.15                 sci-geosciences/mapnik/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/mapnik/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/mapnik/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/mapnik/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/mapnik/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	13 Feb 2010 05:37:07 -0000	1.14
+++ ChangeLog	7 Mar 2010 21:15:50 -0000	1.15
@@ -1,6 +1,15 @@
 # ChangeLog for sci-geosciences/mapnik
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/mapnik/ChangeLog,v 1.14 2010/02/13 05:37:07 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/mapnik/ChangeLog,v 1.15 2010/03/07 21:15:50 nerdboy Exp $
+
+*mapnik-0.6.1-r2 (07 Mar 2010)
+
+  07 Mar 2010; Steve Arnold <nerdboy@gentoo.org> -mapnik-0.6.1-r1.ebuild,
+  +mapnik-0.6.1-r2.ebuild:
+  Had to hack around broken scons build script in order to force a given 
+  boost version (see bug #301674).  Many thanks to Sebastian Luther 
+  <SebastianLuther@gmx.de> and Juergen Rose <rose@rz.uni-potsdam.de> for 
+  providing the initial basis for the complete hack.
 
   13 Feb 2010; Steve Arnold <nerdboy@gentoo.org> mapnik-0.6.1-r1.ebuild:
   Updated boost depend for gpsdrive; can cause subtle breakage if built



1.1                  sci-geosciences/mapnik/mapnik-0.6.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/mapnik/mapnik-0.6.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/mapnik/mapnik-0.6.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: mapnik-0.6.1-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/mapnik/mapnik-0.6.1-r2.ebuild,v 1.1 2010/03/07 21:15:50 nerdboy Exp $

EAPI=2

inherit eutils python distutils toolchain-funcs versionator

DESCRIPTION="A Free Toolkit for developing mapping applications."
HOMEPAGE="http://www.mapnik.org/"
SRC_URI="mirror://berlios/${PN}/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="cairo curl debug doc +gdal postgres python sqlite"

RDEPEND="<dev-libs/boost-1.41.0
	dev-libs/libxml2
	dev-libs/icu
	media-libs/libpng
	media-libs/jpeg
	media-libs/tiff
	media-libs/freetype:2
	sci-libs/proj
	x11-libs/agg[gpc,truetype]
	media-fonts/dejavu
	python? ( <dev-libs/boost-1.41.0[python] )
	cairo? ( x11-libs/cairo
		dev-cpp/cairomm )
	postgres? (
		>=virtual/postgresql-base-8.0
		>=dev-db/postgis-1.1.2
	)
	gdal? ( sci-libs/gdal )
	sqlite? ( dev-db/sqlite:3 )
	curl? ( net-misc/curl )"

DEPEND="${RDEPEND}
	>=dev-util/scons-1.0.0"

src_prepare() {
	sed -i -e "s|/usr/local|/usr|g" \
		-e "s|Action(env\[config\]|Action('%s --help' % env\[config\]|" \
		SConstruct || die

	sed -i -e "s:mapniklibpath + '/fonts':'/usr/share/fonts/dejavu/':g" \
	    bindings/python/SConscript || die "sed 1 failed"
	rm -rf agg
	epatch "${FILESDIR}"/${P}-libagg.patch
}

src_configure() {
	MAKEOPTS="SYSTEM_FONTS=/usr/share/fonts/dejavu"

	MAKEOPTS="${MAKEOPTS} INPUT_PLUGINS="
	use postgres && MAKEOPTS="${MAKEOPTS}postgis,"
	use gdal     && MAKEOPTS="${MAKEOPTS}gdal,ogr,"
	use sqlite   && MAKEOPTS="${MAKEOPTS}sqlite,"
	use curl     && MAKEOPTS="${MAKEOPTS}osm,"
	MAKEOPTS="${MAKEOPTS}shape,raster"

	use cairo  || MAKEOPTS="${MAKEOPTS} CAIRO=false"
	use python || MAKEOPTS="${MAKEOPTS} BINDINGS=none"
	use debug  && MAKEOPTS="${MAKEOPTS} DEBUG=yes"

	use postgres && use sqlite && MAKEOPTS="${MAKEOPTS} PGSQL2SQLITE=yes"

	BOOST_PKG="$(best_version "<dev-libs/boost-1.41.0")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	export BOOST_VERSION="$(replace_all_version_separators _ "${BOOST_VER}")"
	elog "${P} BOOST_VERSION is ${BOOST_VERSION}"
	export BOOST_INC="/usr/include/boost-${BOOST_VERSION}"
	elog "${P} BOOST_INC is ${BOOST_INC}"
	BOOST_LIBDIR_SCHEMA="$(get_libdir)/boost-${BOOST_VERSION}"
	export BOOST_LIB="/usr/${BOOST_LIBDIR_SCHEMA}"
	elog "${P} BOOST_LIB is ${BOOST_LIB}"

	# Passing things doesn't seem to hit all the right paths; another
	# poster-child for just a bit too much complexity for its own good.
	# See bug #301674 for more info.
#	sed -i -e "s|BOOST_INCLUDE_DIR = None|BOOST_INCLUDE_DIR = \'${BOOST_INC}\'|" \
#		-i -e "s|BOOST_LIB_DIR = None|BOOST_LIB_DIR = \'${BOOST_LIB}\'|" \
	sed -i -e "s|searchDir, LIBDIR_SCHEMA|searchDir, \'${BOOST_LIBDIR_SCHEMA}\'|" \
		-i -e "s|include/boost*|include/boost-${BOOST_VERSION}|" \
		"${S}"/SConstruct || die "sed boost paths failed..."

	scons CXX="$(tc-getCXX)" ${MAKEOPTS} DESTDIR="${D}" configure \
		|| die "scons configure failed"
}

src_compile() {
	scons BOOST_INCLUDES=${BOOST_INC} BOOST_LIBS=${BOOST_LIB} \
		BOOST_VERSION=${BOOST_VERSION} || die "scons make failed"
}

src_install() {
	scons install || die "scons install failed"

	if use python ; then
	    distutils_python_version
	    fperms 0755 /usr/$(get_libdir)/python${PYVER}/site-packages/mapnik/paths.py
	    dobin utils/stats/mapdef_stats.py
	    insinto /usr/share/doc/${P}/examples
	    doins utils/ogcserver/*
	fi

	dodoc AUTHORS CHANGELOG README
	use doc && dohtml -r docs/api_docs/python/*
}

pkg_postinst() {
	elog ""
	elog "See the home page or the OpenStreetMap wiki for more info, and"
	elog "the installed examples for the default mapnik ogcserver config."
	elog ""
}