[gentoo-commits] gentoo-x86 commit in sci-biology/emboss: ChangeLog emboss-6.1.0-r1.ebuild

[gentoo-commits] gentoo-x86 commit in sci-biology/emboss: ChangeLog emboss-6.1.0-r1.ebuild

[Justin Lecher (jlec)]

jlec        10/03/07 20:58:43

  Modified:             ChangeLog
  Added:                emboss-6.1.0-r1.ebuild
  Log:
  Moved to EAPI=3 for PREFIX support, imported prefix patches from overlay, keyworded as in overlay
  (Portage version: 2.2_rc65/cvs/Linux x86_64)

Revision  Changes    Path
1.55                 sci-biology/emboss/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/emboss/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/emboss/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/emboss/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-biology/emboss/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	1 Sep 2009 21:57:55 -0000	1.54
+++ ChangeLog	7 Mar 2010 20:58:42 -0000	1.55
@@ -1,6 +1,13 @@
 # ChangeLog for sci-biology/emboss
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/emboss/ChangeLog,v 1.54 2009/09/01 21:57:55 ribosome Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/emboss/ChangeLog,v 1.55 2010/03/07 20:58:42 jlec Exp $
+
+*emboss-6.1.0-r1 (07 Mar 2010)
+
+  07 Mar 2010; Justin Lecher (jlec) <jlec@gentoo.org>
+  +emboss-6.1.0-r1.ebuild:
+  Moved to EAPI=3 for PREFIX support, imported prefix patches from overlay,
+  keyworded as in overlay
 
   01 Sep 2009; Olivier Fisette <ribosome@gentoo.org> metadata.xml:
   Giving up maintainership of this package.



1.1                  sci-biology/emboss/emboss-6.1.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/emboss/emboss-6.1.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-biology/emboss/emboss-6.1.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: emboss-6.1.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/emboss/emboss-6.1.0-r1.ebuild,v 1.1 2010/03/07 20:58:42 jlec Exp $

EAPI="3"

inherit eutils

DESCRIPTION="The European Molecular Biology Open Software Suite - A sequence analysis package"
HOMEPAGE="http://emboss.sourceforge.net/"
SRC_URI="ftp://${PN}.open-bio.org/pub/EMBOSS/EMBOSS-${PV}.tar.gz"
LICENSE="GPL-2 LGPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="X png minimal"

DEPEND="X? ( x11-libs/libXt )
	png? (
		sys-libs/zlib
		media-libs/libpng
		media-libs/gd
	)
	!minimal? (
		sci-biology/primer3
		sci-biology/clustalw
	)"

RDEPEND="${DEPEND}"

PDEPEND="!minimal? (
		sci-biology/aaindex
		sci-biology/cutg
		sci-biology/prints
		sci-biology/prosite
		>=sci-biology/rebase-707
		sci-biology/transfac
	)"

S="${WORKDIR}/EMBOSS-${PV}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-5.0.0-as-needed.patch

	local link_string="-lX11";
	if use png; then
		link_string="${link_string} -lgd -lpng"
	fi
	sed -e "s:PATCH_PLPLOT:${link_string}:" -i plplot/Makefile.in \
		|| die "Failed to patch ajax Makefile"
}

src_configure() {
	EXTRA_CONF="--includedir=${ED}/usr/include/emboss"
	! use X && EXTRA_CONF="${EXTRA_CONF} --without-x"
	! use png && EXTRA_CONF="${EXTRA_CONF} --without-pngdriver"

	econf ${EXTRA_CONF} || die
	# Do not install the JEMBOSS component (the --without-java configure option
	# does not work). JEMBOSS will eventually be available as a separate package.
	sed -i -e "s/SUBDIRS = plplot ajax nucleus emboss test doc jemboss/SUBDIRS = plplot ajax nucleus emboss test doc/" \
			Makefile || die
}

src_install() {
	einstall || die "Failed to install program files."

	dodoc AUTHORS ChangeLog FAQ NEWS README THANKS \
			|| die "Failed to install documentation."
	newdoc "${FILESDIR}"/${PN}-README.Gentoo-1 README.Gentoo \
			|| die "Failed to install Gentoo readme file."

	# Install env file for setting libplplot and acd files path.
	cat <<- EOF > 22emboss
		# plplot libs dir
		PLPLOT_LIB="${EPREFIX}/usr/share/EMBOSS/"
		# ACD files location
		EMBOSS_ACDROOT="${EPREFIX}/usr/share/EMBOSS/acd"
	EOF
	doenvd 22emboss || die "Failed to install environment file."

	# Symlink preinstalled docs to "/usr/share/doc".
	dosym /usr/share/EMBOSS/doc/manuals /usr/share/doc/${PF}/manuals || die
	dosym /usr/share/EMBOSS/doc/programs /usr/share/doc/${PF}/programs || die
	dosym /usr/share/EMBOSS/doc/tutorials /usr/share/doc/${PF}/tutorials || die
	dosym /usr/share/EMBOSS/doc/html /usr/share/doc/${PF}/html || die

	# Remove frestdist documentation conflicting with the EMBASSY philypnew
	# package.
	rm "${ED}"/usr/share/EMBOSS/doc/programs/text/frestdist.txt || \
			die "Failed to remove duplicated documentation."

	# Remove useless dummy files from the image.
	rm "${ED}"/usr/share/EMBOSS/data/{AAINDEX,PRINTS,PROSITE,REBASE}/dummyfile \
			|| die "Failed to remove dummy files."

	# Move the provided codon files to a different directory. This will avoid
	# user confusion and file collisions on case-insensitive file systems (see
	# bug #115446). This change is documented in "README.Gentoo".
	mv "${ED}"/usr/share/EMBOSS/data/CODONS \
			"${ED}"/usr/share/EMBOSS/data/CODONS.orig || \
			die "Failed to move CODON directory."

	# Move the provided restriction enzyme prototypes file to a different name.
	# This avoids file collisions with versions of rebase that install their
	# own enzyme prototypes file (see bug #118832).
	mv "${ED}"/usr/share/EMBOSS/data/embossre.equ \
			"${ED}"/usr/share/EMBOSS/data/embossre.equ.orig || \
			die "Failed to move enzyme equivalence file."
}