[gentoo-commits] gentoo-x86 commit in app-emulation/ganeti: ChangeLog ganeti-2.1.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-emulation/ganeti: ChangeLog ganeti-2.1.0.ebuild

[Lance Albertson (ramereth)]

ramereth    10/03/07 20:56:04

  Modified:             ChangeLog
  Added:                ganeti-2.1.0.ebuild
  Log:
  Version bump, init script fix
  (Portage version: 2.1.7.16/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 app-emulation/ganeti/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/ganeti/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	8 Feb 2010 22:38:59 -0000	1.17
+++ ChangeLog	7 Mar 2010 20:56:03 -0000	1.18
@@ -1,6 +1,16 @@
 # ChangeLog for app-emulation/ganeti
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.17 2010/02/08 22:38:59 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.18 2010/03/07 20:56:03 ramereth Exp $
+
+*ganeti-2.1.0 (07 Mar 2010)
+
+  07 Mar 2010; Lance Albertson <ramereth@gentoo.org> +ganeti-2.1.0.ebuild,
+  files/ganeti-2.1.initd:
+  Version bump, init script fix
+
+  Ganeti starts/stops drbd on its own and thus requiring the drbd init
+  script is
+  pointless so removing it.
 
   08 Feb 2010; Lance Albertson <ramereth@gentoo.org>
   ganeti-2.1.0_rc4.ebuild, files/ganeti-2.1.initd, +files/ganeti.confd:



1.1                  app-emulation/ganeti/ganeti-2.1.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/ganeti/ganeti-2.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/ganeti/ganeti-2.1.0.ebuild?rev=1.1&content-type=text/plain

Index: ganeti-2.1.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ganeti-2.1.0.ebuild,v 1.1 2010/03/07 20:56:03 ramereth Exp $

EAPI=2

inherit eutils confutils bash-completion

MY_PV="${PV/_rc/~rc}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Ganeti is a virtual server management software tool"
HOMEPAGE="http://code.google.com/p/ganeti/"
SRC_URI="http://ganeti.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="kvm xen drbd"

S="${WORKDIR}/${MY_P}"

DEPEND="xen? ( >=app-emulation/xen-3.0 )
	kvm? ( app-emulation/qemu-kvm )
	drbd? ( >=sys-cluster/drbd-8.0 )
	dev-libs/openssl
	dev-python/pyopenssl
	dev-python/pyparsing
	dev-python/pyinotify
	dev-python/simplejson
	net-analyzer/arping
	net-misc/bridge-utils
	net-misc/openssh
	net-misc/socat
	sys-apps/iproute2
	sys-fs/lvm2"
RDEPEND="${DEPEND}"

src_prepare () {
	epatch "${FILESDIR}/${PN}-2.1.0_rc1-fix-brctl-path-for-gentoo.patch"
}

pkg_setup () {
	confutils_require_any kvm xen
}

src_configure () {
	econf --localstatedir=/var \
		--docdir=/usr/share/doc/${P} \
		--with-ssh-initscript=/etc/init.d/sshd \
		--with-export-dir=/var/lib/ganeti-storage/export \
		--with-os-search-path=/usr/share/ganeti/os \
		--with-file-storage-dir=/var/lib/ganeti-storage/file
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"
	newinitd "${FILESDIR}"/ganeti-2.1.initd ganeti
	newconfd "${FILESDIR}"/ganeti.confd ganeti
	dobashcompletion doc/examples/bash_completion ganeti
	dodoc INSTALL NEWS README doc/*.{rst,png}
	rm -rf "${D}"/usr/share/doc/ganeti
	docinto examples
	dodoc doc/examples/{dumb-allocator,ganeti.cron,gnt-config-backup}
	docinto examples/hooks
	dodoc doc/examples/hooks/{ipsec,ethers}

	keepdir /var/{lib,log,run}/ganeti/
	keepdir /usr/share/ganeti/os/
	keepdir /var/lib/ganeti-storage/{export,file}/
}

pkg_postinst () {
	bash-completion_pkg_postinst
}