[gentoo-commits] gentoo-x86 commit in sci-libs/blas-reference: ChangeLog blas-reference-20070226-r1.ebuild

["Justin Lecher (jlec)" <jlec@gentoo.org>]

jlec        10/03/07 19:11:23

  Modified:             ChangeLog
  Added:                blas-reference-20070226-r1.ebuild
  Log:
  Moved to EAPI=3 for PREFIX support, imported prefix patches from overlay, keyworded {amd64,x86}-linux
  (Portage version: 2.2_rc65/cvs/Linux x86_64)

Revision  Changes    Path
1.45                 sci-libs/blas-reference/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/blas-reference/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/blas-reference/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/blas-reference/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/blas-reference/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	22 Aug 2008 17:31:50 -0000	1.44
+++ ChangeLog	7 Mar 2010 19:11:22 -0000	1.45
@@ -1,6 +1,13 @@
 # ChangeLog for sci-libs/blas-reference
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/blas-reference/ChangeLog,v 1.44 2008/08/22 17:31:50 bicatali Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/blas-reference/ChangeLog,v 1.45 2010/03/07 19:11:22 jlec Exp $
+
+*blas-reference-20070226-r1 (07 Mar 2010)
+
+  07 Mar 2010; Justin Lecher (jlec) <jlec@gentoo.org>
+  +blas-reference-20070226-r1.ebuild:
+  Moved to EAPI=3 for PREFIX support, imported prefix patches from overlay,
+  keyworded {amd64,x86}-linux
 
   22 Aug 2008; Sébastien Fabbro <bicatali@gentoo.org>
   files/blas-reference-20070226-autotool.patch:



1.1                  sci-libs/blas-reference/blas-reference-20070226-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/blas-reference/blas-reference-20070226-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/blas-reference/blas-reference-20070226-r1.ebuild?rev=1.1&content-type=text/plain

Index: blas-reference-20070226-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/blas-reference/blas-reference-20070226-r1.ebuild,v 1.1 2010/03/07 19:11:22 jlec Exp $

EAPI="3"

inherit eutils autotools fortran multilib flag-o-matic

LAPACKPV="3.1.1"
LAPACKPN="lapack-lite"

DESCRIPTION="Basic Linear Algebra Subprograms F77 reference implementations"
HOMEPAGE="http://www.netlib.org/blas/"
SRC_URI="http://www.netlib.org/lapack/${LAPACKPN}-${LAPACKPV}.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="doc"

DEPEND="app-admin/eselect-blas"
RDEPEND="${DEPEND}
	doc? ( app-doc/blas-docs )"

S="${WORKDIR}/${LAPACKPN}-${LAPACKPV}"

pkg_setup() {
	FORTRAN="g77 gfortran ifc"
	fortran_pkg_setup
	if  [[ ${FORTRANC} == if* ]]; then
		ewarn "Using Intel Fortran at your own risk"
		LDFLAGS="$(raw-ldflags)"
	fi
	ESELECT_PROF=reference
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-autotool.patch
	eautoreconf

	cp "${FILESDIR}"/eselect.blas.reference "${T}"/
	sed -i -e "s:/usr:${EPREFIX}/usr:" "${T}"/eselect.blas.reference || die
	if [[ ${CHOST} == *-darwin* ]] ; then
		sed -i -e 's/\.so\([\.0-9]\+\)\?/\1.dylib/g' \
			"${T}"/eselect.blas.reference || die
	fi
}

src_configure() {
	econf \
		--libdir="${EPREFIX}"/usr/$(get_libdir)/blas/reference \
		|| die "econf failed"
}

src_compile() {
	emake LDFLAGS="${LDFLAGS}" || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	eselect blas add $(get_libdir) "${T}"/eselect.blas.reference ${ESELECT_PROF}
}

pkg_postinst() {
	local p=blas
	local current_lib=$(eselect ${p} show | cut -d' ' -f2)
	if [[ ${current_lib} == ${ESELECT_PROF} || -z ${current_lib} ]]; then
		# work around eselect bug #189942
		local configfile="${EROOT}"/etc/env.d/${p}/$(get_libdir)/config
		[[ -e ${configfile} ]] && rm -f ${configfile}
		eselect ${p} set ${ESELECT_PROF}
		elog "${p} has been eselected to ${ESELECT_PROF}"
	else
		elog "Current eselected ${p} is ${current_lib}"
		elog "To use ${p} ${ESELECT_PROF} implementation, you have to issue (as root):"
		elog "\t eselect ${p} set ${ESELECT_PROF}"
	fi
}