[gentoo-commits] gentoo-x86 commit in app-cdr/k3b: ChangeLog k3b-1.90.0_rc1.ebuild

[gentoo-commits] gentoo-x86 commit in app-cdr/k3b: ChangeLog k3b-1.90.0_rc1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/03/05 19:53:01

  Modified:             ChangeLog
  Added:                k3b-1.90.0_rc1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.242                app-cdr/k3b/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-cdr/k3b/ChangeLog?rev=1.242&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-cdr/k3b/ChangeLog?rev=1.242&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-cdr/k3b/ChangeLog?r1=1.241&r2=1.242

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v
retrieving revision 1.241
retrieving revision 1.242
diff -u -r1.241 -r1.242
--- ChangeLog	1 Mar 2010 11:35:30 -0000	1.241
+++ ChangeLog	5 Mar 2010 19:53:01 -0000	1.242
@@ -1,6 +1,12 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.241 2010/03/01 11:35:30 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.242 2010/03/05 19:53:01 ssuominen Exp $
+
+*k3b-1.90.0_rc1 (05 Mar 2010)
+
+  05 Mar 2010; Samuli Suominen <ssuominen@gentoo.org>
+  +k3b-1.90.0_rc1.ebuild:
+  Version bump.
 
   01 Mar 2010; Samuli Suominen <ssuominen@gentoo.org>
   k3b-1.70.0_beta1.ebuild:



1.1                  app-cdr/k3b/k3b-1.90.0_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-cdr/k3b/k3b-1.90.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-cdr/k3b/k3b-1.90.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: k3b-1.90.0_rc1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.90.0_rc1.ebuild,v 1.1 2010/03/05 19:53:01 ssuominen Exp $

EAPI=2
WEBKIT_REQUIRED=always
KDE_MINIMAL=4.4
inherit kde4-base

DESCRIPTION="The CD/DVD Kreator for KDE"
HOMEPAGE="http://www.k3b.org/"
SRC_URI="mirror://sourceforge/${PN}/${P/_}.tar.bz2"

LICENSE="GPL-2 FDL-1.2"
SLOT="4"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug dvd emovix encode ffmpeg flac mad lame musepack musicbrainz sndfile sox taglib vcd vorbis +wav"

DEPEND=">=kde-base/libkcddb-${KDE_MINIMAL}
	media-libs/libsamplerate
	dvd? ( media-libs/libdvdread )
	ffmpeg? ( >=media-video/ffmpeg-0.5 )
	flac? ( >=media-libs/flac-1.2[cxx] )
	encode? ( lame? ( media-sound/lame ) )
	mad? ( media-libs/libmad )
	musepack? ( >=media-sound/musepack-tools-444 )
	musicbrainz? ( media-libs/musicbrainz:1 )
	sndfile? ( media-libs/libsndfile )
	taglib? ( >=media-libs/taglib-1.5 )
	vorbis? ( media-libs/libvorbis )"
RDEPEND="${DEPEND}
	sys-apps/hal
	app-cdr/cdrdao
	media-sound/cdparanoia
	virtual/cdrtools
	dvd? ( >=app-cdr/dvd+rw-tools-7
		encode? ( media-video/transcode[dvd] ) )
	emovix? ( media-video/emovix )
	encode? ( sox? ( media-sound/sox ) )
	vcd? ( media-video/vcdimager )"

DOCS="ChangeLog FAQ PERMISSIONS README RELEASE_HOWTO TODO"

S=${WORKDIR}/${P/_*}

src_configure() {
	mycmakeargs+=( "-DK3B_BUILD_K3BSETUP=OFF"
		$(cmake-utils_use debug K3B_DEBUG)
		$(cmake-utils_use musicbrainz K3B_ENABLE_MUSICBRAINZ)
		$(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
		$(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
		"-DK3B_BUILD_API_DOCS=OFF"
		$(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
		$(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
		$(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
		$(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
		$(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
		$(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
		$(cmake-utils_use wav K3B_BUILD_WAVE_DECODER_PLUGIN)
		$(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN) )

	if use encode; then
		mycmakeargs+=( $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
			$(cmake-utils_use lame K3B_BUILD_LAME_ENCODER_PLUGIN)
			$(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN) )
	fi

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	echo
	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
	elog "If you get warnings on start-up, uncheck the \"Check system"
	elog "configuration\" option in the \"Misc\" settings window."
	echo

	local group=cdrom
	use kernel_linux || group=operator
	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
	elog "Usually, it is sufficient to be in the ${group} group."
	echo
}