[gentoo-commits] gentoo-x86 commit in games-arcade/emilia-pinball: emilia-pinball-0.3.1-r1.ebuild ChangeLog

["Samuli Suominen (ssuominen)" <ssuominen@gentoo.org>]

ssuominen    10/03/05 18:41:16

  Modified:             ChangeLog
  Added:                emilia-pinball-0.3.1-r1.ebuild
  Log:
  Use system libltdl wrt #252403, thanks to Diego E. 'Flameeyes' Pettenò for reporting.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 games-arcade/emilia-pinball/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/emilia-pinball/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/emilia-pinball/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/emilia-pinball/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/emilia-pinball/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	24 Jun 2009 23:39:15 -0000	1.16
+++ ChangeLog	5 Mar 2010 18:41:15 -0000	1.17
@@ -1,6 +1,14 @@
 # ChangeLog for games-arcade/emilia-pinball
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/emilia-pinball/ChangeLog,v 1.16 2009/06/24 23:39:15 mr_bones_ Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/emilia-pinball/ChangeLog,v 1.17 2010/03/05 18:41:15 ssuominen Exp $
+
+*emilia-pinball-0.3.1-r1 (05 Mar 2010)
+
+  05 Mar 2010; Samuli Suominen <ssuominen@gentoo.org>
+  +emilia-pinball-0.3.1-r1.ebuild,
+  +files/emilia-pinball-0.3.1-libtool.patch:
+  Use system libltdl wrt #252403, thanks to Diego E. 'Flameeyes' Pettenò
+  for reporting.
 
   24 Jun 2009; Michael Sterrett <mr_bones_@gentoo.org>
   +files/emilia-pinball-0.3.1-glibc210.patch, emilia-pinball-0.3.1.ebuild:



1.1                  games-arcade/emilia-pinball/emilia-pinball-0.3.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/emilia-pinball/emilia-pinball-0.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/emilia-pinball/emilia-pinball-0.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: emilia-pinball-0.3.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/emilia-pinball/emilia-pinball-0.3.1-r1.ebuild,v 1.1 2010/03/05 18:41:15 ssuominen Exp $

EAPI=2
inherit autotools eutils games

MY_PN=${PN/emilia-/}
MY_P=${MY_PN}-${PV}
DESCRIPTION="SDL OpenGL pinball game"
HOMEPAGE="http://pinball.sourceforge.net/"
SRC_URI="mirror://sourceforge/pinball/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE=""

RDEPEND="virtual/opengl
	x11-libs/libSM
	media-libs/libsdl[opengl,video,X]
	media-libs/sdl-image[png]
	media-libs/sdl-mixer[vorbis]
	>=sys-devel/libtool-2.2.6b"
DEPEND="${RDEPEND}
	x11-libs/libXt"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-glibc210.patch \
		"${FILESDIR}"/${P}-libtool.patch
	rm -rf libltdl
	eautoreconf
}

src_configure() {
	egamesconf --with-x
}

src_compile() {
	emake -j1 CXXFLAGS="${CXXFLAGS}" || die "emake failed"
}

src_install() {
	dodoc README || die "dodoc failed"
	emake DESTDIR="${D}" install || die "emake install failed"
	dosym "${GAMES_BINDIR}"/pinball "${GAMES_BINDIR}"/emilia-pinball
	mv "${D}/${GAMES_PREFIX}/include" "${D}/usr/" \
		|| die "mv failed (include)"
	dodir /usr/bin
	mv "${D}/${GAMES_BINDIR}/pinball-config" "${D}/usr/bin/" \
		|| die "mv failed (bin)"
	sed -i \
		-e 's:-I${prefix}/include/pinball:-I/usr/include/pinball:' \
		"${D}"/usr/bin/pinball-config || die "sed failed"
	newicon data/pinball.xpm ${PN}.xpm
	make_desktop_entry emilia-pinball "Emilia pinball"
	prepgamesdirs
}