[gentoo-commits] gentoo-x86 commit in dev-lang/yap: ChangeLog yap-6.0.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/yap: ChangeLog yap-6.0.1.ebuild

[Keri Harris (keri)]

keri        10/03/03 08:23:05

  Modified:             ChangeLog
  Added:                yap-6.0.1.ebuild
  Log:
  Version bump
  (Portage version: 2.1.7.16/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 dev-lang/yap/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	10 Dec 2009 05:24:03 -0000	1.31
+++ ChangeLog	3 Mar 2010 08:23:05 -0000	1.32
@@ -1,6 +1,14 @@
 # ChangeLog for dev-lang/yap
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.31 2009/12/10 05:24:03 keri Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.32 2010/03/03 08:23:05 keri Exp $
+
+*yap-6.0.1 (03 Mar 2010)
+
+  03 Mar 2010; <keri@gentoo.org> +yap-6.0.1.ebuild,
+  +files/yap-6.0.1-bootfile.patch, +files/yap-6.0.1-dynamic-lib.patch,
+  +files/yap-6.0.1-mpi-include.patch, +files/yap-6.0.1-multilib.patch,
+  +files/yap-6.0.1-myddas-include.patch, +files/yap-6.0.1-yapsharedir.patch:
+  Version bump
 
   10 Dec 2009; <keri@gentoo.org> -yap-5.1.1.ebuild,
   -files/yap-5.1.1-SONAME.patch, -files/yap-5.1.1-analyst.patch,



1.1                  dev-lang/yap/yap-6.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/yap-6.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/yap-6.0.1.ebuild?rev=1.1&content-type=text/plain

Index: yap-6.0.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/yap-6.0.1.ebuild,v 1.1 2010/03/03 08:23:05 keri Exp $

inherit eutils java-pkg-opt-2

MY_P="Yap-${PV}"

DESCRIPTION="YAP is a high-performance Prolog compiler."
HOMEPAGE="http://www.ncc.up.pt/~vsc/Yap/"
SRC_URI="http://www.ncc.up.pt/~vsc/Yap/yap-6.0.1.tar.gz"

LICENSE="Artistic LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug doc examples gmp java mpi mysql odbc readline static tk threads"

DEPEND="gmp? ( dev-libs/gmp )
	java? ( >=virtual/jdk-1.4 )
	mpi? ( virtual/mpi )
	mysql? ( virtual/mysql )
	odbc? ( dev-db/unixODBC )
	readline? ( sys-libs/readline )
	doc? ( app-text/texi2html )"

RDEPEND="${DEPEND}
	tk? ( dev-lang/tk )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-bootfile.patch
	epatch "${FILESDIR}"/${P}-dynamic-lib.patch
	epatch "${FILESDIR}"/${P}-mpi-include.patch
	epatch "${FILESDIR}"/${P}-myddas-include.patch
	epatch "${FILESDIR}"/${P}-multilib.patch
	epatch "${FILESDIR}"/${P}-yapsharedir.patch
}

src_compile() {
	local myddas_conf
	if use mysql || use odbc; then
		myddas_conf="--enable-myddas \
				--enable-myddas-stats \
				--enable-myddas-top-level"
	else
		myddas_conf="--disable-myddas"
	fi

	econf \
		--libdir=/usr/$(get_libdir) \
		--enable-cut-c \
		$(use_enable !static dynamic-loading) \
		$(use_enable threads) \
		$(use_enable threads pthread-locking) \
		$(use_enable debug debug-yap) \
		$(use_enable debug low-level-tracer) \
		$(use_with gmp) \
		$(use_with readline) \
		$(use_with mpi) \
		$(use_with mpi mpe) \
		$(use_with java jpl) \
		${myddas_conf} \
		|| die "econf failed"

	emake || die "emake failed"

	if use doc ; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" -j1 install || die "make install failed."

	if use tk ; then
		exeinto /usr/bin
		doexe misc/tkyap
	fi

	dodoc changes*.html README

	if use doc ; then
		dodoc yap.html
	fi

	if use examples ; then
		docinto examples/chr
		dodoc packages/chr/Examples/*.{chr,pl}
		docinto examples/plunit
		dodoc packages/plunit/examples/*.pl
		if use java ; then
			docinto examples/jpl/prolog
			dodoc packages/jpl/examples/prolog/*.pl
			docinto examples/jpl/java
			dodoc packages/jpl/examples/java/*/*.java
		fi
		if use mpi ; then
			docinto examples/mpi
			dodoc library/mpi/examples/*.pl
		fi
	fi
}