* [gentoo-commits] gentoo-x86 commit in app-portage/gentoolkit: ChangeLog gentoolkit-0.3.0_rc9.ebuild gentoolkit-0.2.4.6.ebuild
@ 2010-02-18 19:58 Paul Varner (fuzzyray)
0 siblings, 0 replies; only message in thread
From: Paul Varner (fuzzyray) @ 2010-02-18 19:58 UTC (permalink / raw
To: gentoo-commits
fuzzyray 10/02/18 19:58:12
Modified: ChangeLog
Added: gentoolkit-0.3.0_rc9.ebuild
gentoolkit-0.2.4.6.ebuild
Log:
gentoolkit-0.3.0_rc9 and gentoolkit-0.2.4.6 version bump.
Bug 237964 tracks changes to gentoolkit-0.3.0
Bug 305793 tracks the changes for gentoolkit-0.2.4.6.
(Portage version: 2.2_rc62/cvs/Linux i686)
Revision Changes Path
1.179 app-portage/gentoolkit/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.179&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.179&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?r1=1.178&r2=1.179
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v
retrieving revision 1.178
retrieving revision 1.179
diff -u -r1.178 -r1.179
--- ChangeLog 5 Feb 2010 20:48:48 -0000 1.178
+++ ChangeLog 18 Feb 2010 19:58:12 -0000 1.179
@@ -1,6 +1,16 @@
# ChangeLog for app-portage/gentoolkit
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.178 2010/02/05 20:48:48 fuzzyray Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.179 2010/02/18 19:58:12 fuzzyray Exp $
+
+*gentoolkit-0.3.0_rc9 (18 Feb 2010)
+*gentoolkit-0.2.4.6 (18 Feb 2010)
+
+ 18 Feb 2010; Paul Varner <fuzzyray@gentoo.org> +gentoolkit-0.2.4.6.ebuild,
+ +gentoolkit-0.3.0_rc9.ebuild:
+ gentoolkit-0.3.0_rc9 version bump. Bug 237964 tracks changes to
+ gentoolkit-0.3.0.
+ gentoolkit-0.2.4.6 version bump. This is gentoolkit-0.2.4.5 with
+ revdep-rebuild from gentoolkit-0.3.0. Bug 305793 tracks the changes.
05 Feb 2010; Paul Varner <fuzzyray@gentoo.org>
gentoolkit-0.3.0_rc8-r1.ebuild:
1.1 app-portage/gentoolkit/gentoolkit-0.3.0_rc9.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc9.ebuild?rev=1.1&content-type=text/plain
Index: gentoolkit-0.3.0_rc9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc9.ebuild,v 1.1 2010/02/18 19:58:12 fuzzyray Exp $
EAPI="2"
SUPPORT_PYTHON_ABIS="1"
inherit distutils
DESCRIPTION="Collection of administration scripts for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~fuzzyray/distfiles/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
IUSE=""
# Drop ~m68k ~s390 ~sh ~sparc-fbsd ~x86-fbsd due to app-misc/realpath dependency
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
DEPEND="sys-apps/portage
dev-lang/python[xml]
dev-lang/perl
sys-apps/grep
sys-apps/gawk"
RDEPEND="${DEPEND}
app-misc/realpath"
RESTRICT_PYTHON_ABIS="3.*"
distutils_src_compile_pre_hook() {
echo VERSION="$PVR" "$(PYTHON)" setup.py set_version
VERSION="$PVR" "$(PYTHON)" setup.py set_version
}
src_install() {
distutils_src_install
# Create cache directory for revdep-rebuild
dodir /var/cache/revdep-rebuild
keepdir /var/cache/revdep-rebuild
fowners root:root /var/cache/revdep-rebuild
fperms 0700 /var/cache/revdep-rebuild
# Can distutils handle this?
dosym eclean-$(PYTHON --ABI -f) /usr/bin/eclean-dist
dosym eclean-$(PYTHON --ABI -f) /usr/bin/eclean-pkg
}
pkg_postinst() {
distutils_pkg_postinst
# Make sure that our ownership and permissions stuck
chown root:root "${ROOT}/var/cache/revdep-rebuild"
chmod 0700 "${ROOT}/var/cache/revdep-rebuild"
einfo
elog "The default location for revdep-rebuild files has been moved"
elog "to /var/cache/revdep-rebuild when run as root."
einfo
einfo "Another alternative to equery is app-portage/portage-utils"
einfo
einfo "For further information on gentoolkit, please read the gentoolkit"
einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
einfo
ewarn "This version of gentoolkit contains a rewritten version of equery"
ewarn "and the gentoolkit library. Because of this, the documentation is"
ewarn "out of date. Please check http://bugs.gentoo.org/269071 when"
ewarn "filing bugs to see if your issue is being addressed."
ewarn
ewarn "glsa-check since gentoolkit 0.3 has modified some output,"
ewarn "options and default behavior. The list of injected GLSAs"
ewarn "has moved to /var/lib/portage/glsa_injected, please"
ewarn "run 'glsa-check -p affected' before copying the existing checkfile."
}
1.1 app-portage/gentoolkit/gentoolkit-0.2.4.6.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6.ebuild?rev=1.1&content-type=text/plain
Index: gentoolkit-0.2.4.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6.ebuild,v 1.1 2010/02/18 19:58:12 fuzzyray Exp $
EAPI=2
inherit eutils python
DESCRIPTION="Collection of administration scripts for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~fuzzyray/distfiles/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
IUSE=""
# Drop ~m68k ~s390 ~sh ~sparc-fbsd ~x86-fbsd due to app-misc/realpath dependency
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
DEPEND="sys-apps/portage
dev-lang/python[xml]
dev-lang/perl
sys-apps/grep"
RDEPEND="${DEPEND}
app-misc/realpath"
RESTRICT="test"
src_install() {
emake DESTDIR="${D}" install-gentoolkit || die "install-gentoolkit failed"
# Create cache directory for revdep-rebuild
dodir /var/cache/revdep-rebuild
keepdir /var/cache/revdep-rebuild
fowners root:root /var/cache/revdep-rebuild
fperms 0700 /var/cache/revdep-rebuild
}
pkg_postinst() {
# Make sure that our ownership and permissions stuck
chown root:root "${ROOT}/var/cache/revdep-rebuild"
chmod 0700 "${ROOT}/var/cache/revdep-rebuild"
python_mod_optimize /usr/lib/gentoolkit
einfo
elog "The default location for revdep-rebuild files has been moved"
elog "to /var/cache/revdep-rebuild when run as root."
einfo
einfo "Another alternative to equery is app-portage/portage-utils"
einfo
einfo "For further information on gentoolkit, please read the gentoolkit"
einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
einfo
}
pkg_postrm() {
python_mod_cleanup /usr/lib/gentoolkit
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-02-18 19:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-02-18 19:58 [gentoo-commits] gentoo-x86 commit in app-portage/gentoolkit: ChangeLog gentoolkit-0.3.0_rc9.ebuild gentoolkit-0.2.4.6.ebuild Paul Varner (fuzzyray)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox