From: "Justin Lecher (jlec)" <jlec@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in sci-chemistry/ccp4-apps: ChangeLog ccp4-apps-6.1.3-r1.ebuild ccp4-apps-6.1.3.ebuild
Date: Sun, 14 Feb 2010 15:10:16 +0000 [thread overview]
Message-ID: <E1Ngg6y-0008HL-Tp@stork.gentoo.org> (raw)
jlec 10/02/14 15:10:16
Modified: ChangeLog
Added: ccp4-apps-6.1.3-r1.ebuild
Removed: ccp4-apps-6.1.3.ebuild
Log:
Fixed CLIB to multilib compatible
(Portage version: 2.2_rc62/cvs/Linux x86_64)
Revision Changes Path
1.2 sci-chemistry/ccp4-apps/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog?r1=1.1&r2=1.2
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog 6 Feb 2010 00:37:43 -0000 1.1
+++ ChangeLog 14 Feb 2010 15:10:16 -0000 1.2
@@ -1,6 +1,12 @@
# ChangeLog for sci-chemistry/ccp4-apps
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog,v 1.1 2010/02/06 00:37:43 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/ccp4-apps/ChangeLog,v 1.2 2010/02/14 15:10:16 jlec Exp $
+
+*ccp4-apps-6.1.3-r1 (14 Feb 2010)
+
+ 14 Feb 2010; Justin Lecher (jlec) <jlec@gentoo.org>
+ -ccp4-apps-6.1.3.ebuild, +ccp4-apps-6.1.3-r1.ebuild:
+ Fixed CLIB to multilib compatible
*ccp4-apps-6.1.3 (06 Feb 2010)
1.1 sci-chemistry/ccp4-apps/ccp4-apps-6.1.3-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/ccp4-apps/ccp4-apps-6.1.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/ccp4-apps/ccp4-apps-6.1.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: ccp4-apps-6.1.3-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/ccp4-apps/ccp4-apps-6.1.3-r1.ebuild,v 1.1 2010/02/14 15:10:16 jlec Exp $
EAPI="2"
inherit fortran eutils flag-o-matic gnuconfig toolchain-funcs autotools
FORTRAN="g77 gfortran ifc"
MY_P="${PN/-apps}-${PV}"
SRC="ftp://ftp.ccp4.ac.uk/ccp4"
#UPDATE="04_03_09"
#PATCHDATE="090511"
PATCH_TOT="0"
# Here's a little scriptlet to generate this list from the provided
# index.patches file
#
# i=1; while read -a line; do [[ ${line//#} != ${line} ]] && continue;
# echo "PATCH${i}=( ${line[1]}"; echo "${line[0]} )"; (( i++ )); done <
# index.patches
#PATCH1=( src/topp_
#topp.f-r1.16.2.5-r1.16.2.6.diff )
#PATCH2=( .
#configure-r1.372.2.18-r1.372.2.19.diff )
DESCRIPTION="Protein X-ray crystallography toolkit"
HOMEPAGE="http://www.ccp4.ac.uk/"
RESTRICT="mirror"
SRC_URI="
${SRC}/${PV}/${MY_P}-core-src.tar.gz
http://dev.gentooexperimental.org/~jlec/distfiles/${PV}-oasis4.0.patch.bz2"
# patch tarball from upstream
[[ -n ${UPDATE} ]] && SRC_URI="${SRC_URI} ${SRC}/${PV}/updates/${P}-src-patch-${UPDATE}.tar.gz"
# patches created by us
[[ -n ${PATCHDATE} ]] && SRC_URI="${SRC_URI} http://dev.gentooexperimental.org/~jlec/science-dist/${PV}-${PATCHDATE}-updates.patch.bz2"
for i in $(seq $PATCH_TOT); do
NAME="PATCH${i}[1]"
SRC_URI="${SRC_URI}
${SRC}/${PV}/patches/${!NAME}"
done
LICENSE="ccp4"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples X"
X11DEPS="
x11-libs/libX11
x11-libs/libXaw
x11-libs/libXt
x11-libs/libjwc_c
x11-libs/libjwc_f
x11-libs/libxdl_view"
TKDEPS="
>=dev-lang/tk-8.3
>=dev-tcltk/blt-2.4
dev-tcltk/iwidgets
dev-tcltk/itcl
dev-tcltk/itk
>=dev-tcltk/tdom-0.8
dev-tcltk/tkimg
dev-tcltk/tktreectrl"
SCILIBS="
~sci-libs/ccp4-libs-${PV}
sci-libs/clipper
=sci-libs/fftw-2*
virtual/blas
virtual/lapack"
SCIAPPS="
sci-chemistry/pdb-extract
sci-chemistry/pymol
sci-chemistry/rasmol
sci-chemistry/oasis"
RDEPEND="X? ( ${X11DEPS} )
${TKDEPS}
${SCILIBS}
app-shells/tcsh
dev-python/pyxml
dev-libs/libxml2
dev-libs/boehm-gc
!app-office/sc
!<sci-chemistry/ccp4-6.1.2"
DEPEND="${RDEPEND}
=sys-devel/automake-1.6*
X? (
x11-misc/imake
x11-proto/inputproto
x11-proto/xextproto
)"
PDEPEND="${SCIAPPS}"
S="${WORKDIR}/${MY_P}"
src_prepare() {
einfo "Applying upstream patches ..."
for patch in $(seq $PATCH_TOT); do
base="PATCH${patch}"
dir=$(eval echo \${${base}[0]})
p=$(eval echo \${${base}[1]})
pushd "${dir}" >& /dev/null
ccp_patch ${DISTDIR}/"${p}"
popd >& /dev/null
done
einfo "Done."
echo
[[ -n ${PATCHDATE} ]] && epatch "${WORKDIR}"/${PV}-${PATCHDATE}-updates.patch
einfo "Applying Gentoo patches ..."
# it tries to create libdir, bindir etc on live system in configure
ccp_patch "${FILESDIR}"/${PV}-dont-make-dirs-in-configure.patch
# We already have sci-chemistry/rasmol
# Also remember to create the bindir.
ccp_patch "${FILESDIR}"/${PV}-dont-build-double-and-make-bindir.patch
# libraries come from sci-libs/ccp4-libs
ccp_patch "${FILESDIR}"/${PV}-dont-build-libs.patch
# coreutils installs a binary called truncate
ccp_patch "${FILESDIR}"/${PV}-rename-truncate.patch
mv ./doc/truncate.doc ./doc/ftruncate.doc || die
mv ./html/truncate.html ./html/ftruncate.html || die
# conflicts with media-libs/raptor
ccp_patch "${FILESDIR}"/${PV}-rename-rapper.patch
mv ./doc/rapper.doc ./doc/rappermc.doc || die
mv ./html/rapper.html ./html/rappermc.html || die
# molref is provided as binary and dynamically linked against icc
ccp_patch "${FILESDIR}"/${PV}-dont-build-molref.patch
# no xia
ccp_patch "${FILESDIR}"/${PV}-dont-build-xia.patch
# We build scala ourself
ccp_patch "${FILESDIR}"/${PV}-dont-build-scala.patch
# We build scala ourself
ccp_patch "${FILESDIR}"/${PV}-dont-build-imosflm.patch
# don't configure what is not build
ccp_patch "${FILESDIR}"/${PV}-dont-configure.patch
# Set python paths correctly
ccp_patch "${FILESDIR}"/${PV}-pythonpath.patch
# Set python paths correctly
ccp_patch "${FILESDIR}"/${PV}-pisa.patch
# Set python paths correctly
ccp_patch "${FILESDIR}"/${PV}-clipper-template.patch
# Update things for oasis 4 usage
epatch "${WORKDIR}"/${PV}-oasis4.0.patch
sed 's: oasis : :g' -i src/Makefile.in || die
einfo "Done." # done applying Gentoo patches
echo
# Don't build refmac binaries available from the standalone version
sed -i -e "/^REFMACTARGETS/s:refmac5 libcheck makecif molrep sfcheck::g" configure
# Rapper bundles libxml2 and boehm-gc. Don't build, use or install those.
pushd src/rapper 2>/dev/null
sed -i \
-e '/^AC_CONFIG_SUBDIRS(\[gc7.0 libxml2\])/d' \
configure.ac
sed -i \
-e '/^SUBDIRS/s:libxml2 gc7.0::g' \
Makefile.am
sed -i \
-e '/^rappermc_LDADD/s:../gc7.0/libgc.la ../libxml2/libxml2.la:-lgc -lxml2:g' \
LOOP/Makefile.am
sed -i \
-e '/^INCLUDES/s:-I../gc7.0/include -I../libxml2/include:-I/usr/include/gc -I/usr/include/libxml2:g' \
LOOP/Makefile.am
eautoreconf
popd 2>/dev/null
gnuconfig_update
}
src_configure() {
# Build system is broken if we set LDFLAGS
unset LDFLAGS
# These are broken with ./src/procheck/ps.f
filter-flags "-floop-*"
# GENTOO_OSNAME can be one of:
# irix irix64 sunos sunos64 aix hpux osf1 linux freebsd
# linux_compaq_compilers linux_intel_compilers generic Darwin
# ia64_linux_intel Darwin_ibm_compilers linux_ibm_compilers
if [[ "${FORTRANC}" = "ifc" ]]; then
if use ia64; then
GENTOO_OSNAME="ia64_linux_intel"
else
# Should be valid for x86, maybe amd64
GENTOO_OSNAME="linux_intel_compilers"
fi
else
# Should be valid for x86 and amd64, at least
GENTOO_OSNAME="linux"
fi
# Sets up env
ln -s \
ccp4.setup-bash \
"${S}"/include/ccp4.setup
# We agree to the license by emerging this, set in LICENSE
sed -i \
-e "s~^\(^agreed=\).*~\1yes~g" \
"${S}"/configure
# Fix up variables -- need to reset CCP4_MASTER at install-time
sed -i \
-e "s~^\(setenv CCP4_MASTER.*\)/.*~\1${WORKDIR}~g" \
-e "s~^\(export CCP4_MASTER.*\)/.*~\1${WORKDIR}~g" \
-e "s~^\(setenv CCP4I_TCLTK.*\)/usr/local/bin~\1/usr/bin~g" \
-e "s~^\(export CCP4I_TCLTK.*\)/usr/local/bin~\1/usr/bin~g" \
"${S}"/include/ccp4.setup*
# Set up variables for build
source "${S}"/include/ccp4.setup
export CC=$(tc-getCC)
export CXX=$(tc-getCXX)
export COPTIM=${CFLAGS}
export CXXOPTIM=${CXXFLAGS}
# Default to -O2 if FFLAGS is unset
export FC=${FORTRANC}
export FOPTIM=${FFLAGS:- -O2}
export BINSORT_SCR="${T}"
export CCP4_MASTER="${WORKDIR}"
export CCP4I_TCLTK="/usr/bin"
# Can't use econf, configure rejects unknown options like --prefix
./configure \
$(use_enable X x) \
--with-shared-libs \
--with-fftw=/usr \
--with-warnings \
--disable-pdb_extract \
--disable-cctbx \
--disable-phaser \
--disable-diffractionImg \
--disable-clipper \
--disable-mosflm \
--disable-mrbump \
--tmpdir="${TMPDIR}" \
${GENTOO_OSNAME} || die "econf failed"
# We do this manually, since disabling the clipper libraries also
# disables the clipper programs
pushd src/clipper_progs 2>/dev/null
econf \
--prefix="${S}" \
--with-ccp4="${S}" \
--with-clipper=/usr \
--with-fftw=/usr \
--with-mmdb=/usr \
CXX=$(tc-getCXX) \
|| die
popd 2>/dev/null
}
src_compile() {
# fsplit is required for the programs
pushd lib/src 2>/dev/null
emake fsplit -j1 || die
popd 2>/dev/null
# We do this manually, since disabling the clipper libraries also
# disables the clipper programs
pushd src/clipper_progs 2>/dev/null
emake || die
popd 2>/dev/null
emake -j1 || die "emake failed"
}
src_install() {
# Set up variables for build
source "${S}"/include/ccp4.setup
# make install || die "install failed"
# if we don't make this, a ton of programs fail to install
mkdir "${S}"/bin || die
# We do this manually, since disabling the clipper libraries also
# disables the clipper programs
pushd "${S}"/src/clipper_progs 2>/dev/null
emake install || die
popd 2>/dev/null
einstall || die "install failed"
# Fix env
# -e "s~^\(.*setenv PYTHONPATH .*\)\${CCP4}.*~\1\${CCP4}/share/ccp4/python~g" \
# -e "s~^\(.*export PYTHONPATH.*\)\${CCP4}.*~\1\${CCP4}/share/ccp4/python~g" \
sed -i \
-e "s~^\(setenv CCP4_MASTER.*\)${WORKDIR}~\1/usr~g" \
-e "s~^\(setenv CCP4.*\$CCP4_MASTER\).*~\1~g" \
-e "s~^\(setenv CCP4I_TOP\).*~\1 \$CCP4/$(get_libdir)/ccp4/ccp4i~g" \
-e "s~^\(setenv DBCCP4I_TOP\).*~\1 \$CCP4/share/ccp4/dbccp4i~g" \
-e "s~^\(.*setenv CINCL.*\$CCP4\).*~\1/share/ccp4/include~g" \
-e "s~^\(.*setenv CLIBD .*\$CCP4\).*~\1/share/ccp4/data~g" \
-e "s~^\(.*setenv CLIBD_MON .*\)\$CCP4.*~\1\$CCP4/share/ccp4/data/monomers/~g" \
-e "s~^\(.*setenv MOLREPLIB .*\)\$CCP4.*~\1\$CCP4/share/ccp4/data/monomers/~g" \
-e "s~^\(.*setenv CLIB .*\)\$CCP4.*~\1\$CCP4/$(get_libdir)~g" \
-e "s~^\(export CCP4_MASTER.*\)${WORKDIR}~\1/usr~g" \
-e "s~^\(export CCP4.*\$CCP4_MASTER\).*~\1~g" \
-e "s~^\(export CCP4I_TOP\).*~\1=\$CCP4/$(get_libdir)/ccp4/ccp4i~g" \
-e "s~^\(export DBCCP4I_TOP\).*~\1=\$CCP4/share/ccp4/dbccp4i~g" \
-e "s~^\(.*export CINCL.*\$CCP4\).*~\1/share/ccp4/include~g" \
-e "s~^\(.*export CLIBD.*\$CCP4\).*~\1/share/ccp4/data~g" \
-e "s~^\(.*export CLIBD_MON.*\)\$CCP4.*~\1\$CCP4/share/ccp4/data/monomers/~g" \
-e "s~^\(.*export MOLREPLIB.*\)\$CCP4.*~\1\$CCP4/share/ccp4/data/monomers/~g" \
-e "s~^\(.*export CLIB=.*\)\$CCP4.*~\1\$CCP4/$(get_libdir)~g" \
-e "/IMOSFLM_VERSION/d" \
"${S}"/include/ccp4.setup* || die
# -e "s~\$CCP4/share/XIAROOT/setup.sh~\$CCP4/share/ccp4/XIAROOT/setup.sh~g" \
# Don't check for updates on every sourcing of /etc/profile
sed -i \
-e "s:\(eval python.*\):#\1:g"
"${S}"/include/ccp4.setup* || die
# Collision with sci-chemistry/mrbump
rm -f "${S}"/bin/{mrbump,pydbviewer} || die
# Bins
dobin "${S}"/bin/* || die
# Libs
for file in "${S}"/lib/*; do
if [[ -d ${file} ]]; then
continue
elif [[ -x ${file} ]]; then
dolib.so ${file} || die
else
insinto /usr/$(get_libdir)
doins ${file} || die
fi
done
sed \
-e 's:test "LD_LIBRARY_PATH":test "$LD_LIBRARY_PATH":g' \
-i "${S}"/include/ccp4.setup-sh || die
# Setup scripts
insinto /etc/profile.d
# newins "${S}"/include/ccp4.setup-bash ccp4.setup.bash || die
newins "${S}"/include/ccp4.setup-csh 40ccp4.setup.csh || die
# newins "${S}"/include/ccp4.setup-zsh ccp4.setup.zsh || die
newins "${S}"/include/ccp4.setup-sh 40ccp4.setup.sh || die
rm -f "${S}"/include/ccp4.setup*
# Environment files, setup scripts, etc.
insinto /usr/share/ccp4/include
doins "${S}"/include/* || die
# smartie -- log parsing
insinto /usr/share/ccp4
doins -r "${S}"/share/smartie || die
# Install docs and examples
doman "${S}"/man/cat1/*
mv "${S}"/manual/README "${S}"/manual/README-manual
dodoc manual/* README CHANGES doc/* examples/README || die
rm "${D}"/usr/share/doc/${PF}/GNUmakefile.*
rm "${D}"/usr/share/doc/${PF}/COPYING.*
dohtml -r "${S}"/html/*
if use examples; then
for i in data rnase toxd; do
docinto examples/${i}
dodoc "${S}"/examples/${i}/*
done
docinto examples/tutorial
dohtml -r "${S}"/examples/tutorial/html examples/tutorial/tut.css
for i in data results; do
docinto examples/tutorial/${i}
dodoc "${S}"/examples/tutorial/${i}/*
done
for i in non-runnable runnable; do
docinto examples/unix/${i}
dodoc "${S}"/examples/unix/${i}/*
done
fi
# Needed for ccp4i docs to work
dosym ../../share/doc/${PF}/examples /usr/$(get_libdir)/ccp4/examples
dosym ../../share/doc/${PF}/html /usr/$(get_libdir)/ccp4/html
# Fix overlaps with other packages
rm -f "${D}"/usr/share/man/man1/rasmol.1* "${D}"/usr/lib/font84.dat || die
cat >> "${T}"/baubles <<- EOF
#!/bin/bash
exec python \${CCP4}/share/ccp4/smartie/baubles.py
EOF
dobin "${T}"/baubles || die
}
pkg_postinst() {
einfo "The Web browser defaults to firefox. Change CCP4_BROWSER"
einfo "in /etc/profile.d/ccp4.setup* to modify this."
}
# Epatch wrapper for bulk patching
ccp_patch() {
EPATCH_SINGLE_MSG=" ${1##*/} ..." epatch ${1}
}
reply other threads:[~2010-02-14 15:10 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=E1Ngg6y-0008HL-Tp@stork.gentoo.org \
--to=jlec@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox