[gentoo-commits] gentoo-x86 commit in dev-lang/gdl: ChangeLog gdl-0.9_rc4.ebuild gdl-0.9_rc1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/gdl: ChangeLog gdl-0.9_rc4.ebuild gdl-0.9_rc1.ebuild

[Markus Dittrich (markusle)]

markusle    10/02/05 04:22:45

  Modified:             ChangeLog
  Added:                gdl-0.9_rc4.ebuild
  Removed:              gdl-0.9_rc1.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.7.17/cvs/Linux x86_64)

Revision  Changes    Path
1.15                 dev-lang/gdl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	12 Jan 2010 03:52:29 -0000	1.14
+++ ChangeLog	5 Feb 2010 04:22:45 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/gdl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.14 2010/01/12 03:52:29 markusle Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.15 2010/02/05 04:22:45 markusle Exp $
+
+*gdl-0.9_rc4 (05 Feb 2010)
+
+  05 Feb 2010; Markus Dittrich <markusle@gentoo.org> -gdl-0.9_rc1.ebuild,
+  +files/gdl-0.9_rc4-antlr.patch, +gdl-0.9_rc4.ebuild:
+  Version bump.
 
 *gdl-0.9_rc3 (12 Jan 2010)
 



1.1                  dev-lang/gdl/gdl-0.9_rc4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc4.ebuild?rev=1.1&content-type=text/plain

Index: gdl-0.9_rc4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9_rc4.ebuild,v 1.1 2010/02/05 04:22:45 markusle Exp $

EAPI="2"

inherit eutils flag-o-matic autotools

MYP=${P/_/}
DESCRIPTION="An Interactive Data Language compatible incremental compiler"
LICENSE="GPL-2"
HOMEPAGE="http://gnudatalanguage.sourceforge.net/"
SRC_URI="mirror://sourceforge/gnudatalanguage/${MYP}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python fftw hdf hdf5 netcdf imagemagick proj"

RDEPEND=">=sys-libs/readline-4.3
	sci-libs/gsl
	=dev-java/antlr-2.7*[cxx]
	>=sci-libs/plplot-5.3
	imagemagick? ( media-gfx/imagemagick )
	hdf? ( sci-libs/hdf )
	hdf5? ( sci-libs/hdf5 )
	netcdf? ( sci-libs/netcdf )
	python? ( dev-python/numarray dev-python/matplotlib )
	fftw? ( >=sci-libs/fftw-3 )
	proj? ( sci-libs/proj )"

DEPEND="${RDEPEND}
	sys-devel/libtool"

S="${WORKDIR}/${MYP}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.9_rc3-proj4.patch
	epatch "${FILESDIR}"/${PN}-0.9_rc2-gcc4.4.patch
	epatch "${FILESDIR}"/${P}-antlr.patch

	# we need to blow away the directory with antlr
	# otherwise the build system picks up bogus
	# header files
	rm -fr "${S}"/src/antlr || die "failed to remove antlr directory"

	eautoreconf
}

src_configure() {
	# need to check for old plplot
	local myconf
	if has_version '<sci-libs/plplot-5.9.0'; then
		myconf="${myconf} --enable-oldplplot"
	fi

	# make sure we're hdf5-1.6 backward compatible
	use hdf5 && append-flags -DH5_USE_16_API

	use proj && append-cppflags -DPJ_LIB__
	econf \
	  $(use_with python) \
	  $(use_with fftw) \
	  $(use_with hdf) \
	  $(use_with hdf5) \
	  $(use_with netcdf) \
	  $(use_with imagemagick Magick) \
	  $(use_with proj libproj4) \
	  ${myconf} \
	  || die "econf failed"

}

src_test() {
	cd "${S}"/testsuite
	PATH="${S}"/src gdl <<-EOF
		test_suite
	EOF
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto /usr/share/${PN}
	doins -r src/pro src/py || die "install pro and py files failed"
	dodoc README PYTHON.txt AUTHORS ChangeLog NEWS TODO HACKING \
		|| die "Failed to install docs"

	# add GDL provided routines to IDL_PATH
	echo "GDL_STARTUP=/usr/share/${PN}/pro" > 99gdl
	echo "GDL_PATH=/usr/share/${PN}" >> 99gdl
	doenvd 99gdl || die "doenvd failed"
}