* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.7.6-r1.ebuild libvirt-0.7.6.ebuild
@ 2010-02-04 7:05 Doug Goldstein (cardoe)
0 siblings, 0 replies; only message in thread
From: Doug Goldstein (cardoe) @ 2010-02-04 7:05 UTC (permalink / raw
To: gentoo-commits
cardoe 10/02/04 07:05:49
Modified: ChangeLog
Added: libvirt-0.7.6-r1.ebuild
Removed: libvirt-0.7.6.ebuild
Log:
fix virt-pki-validate. clean up some elog/ewarn messages
(Portage version: 2.1.7.17/cvs/Linux x86_64)
Revision Changes Path
1.49 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.48&r2=1.49
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog 3 Feb 2010 19:57:01 -0000 1.48
+++ ChangeLog 4 Feb 2010 07:05:48 -0000 1.49
@@ -1,6 +1,13 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.48 2010/02/03 19:57:01 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.49 2010/02/04 07:05:48 cardoe Exp $
+
+*libvirt-0.7.6-r1 (04 Feb 2010)
+
+ 04 Feb 2010; Doug Goldstein <cardoe@gentoo.org> -libvirt-0.7.6.ebuild,
+ +libvirt-0.7.6-r1.ebuild,
+ +files/libvirt-0.7.6-virt-pki-validate-sysconfdir.patch:
+ fix virt-pki-validate. clean up some elog/ewarn messages
*libvirt-0.7.6 (03 Feb 2010)
1.1 app-emulation/libvirt/libvirt-0.7.6-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.7.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.7.6-r1.ebuild?rev=1.1&content-type=text/plain
Index: libvirt-0.7.6-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.7.6-r1.ebuild,v 1.1 2010/02/04 07:05:48 cardoe Exp $
BACKPORTS=
EAPI="2"
inherit eutils python
DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz
${BACKPORTS:+mirror://gentoo/${P}-backports-${BACKPORTS}.tar.bz2}"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi caps iscsi +libvirtd lvm +lxc +network nfs nls numa openvz \
parted phyp policykit python qemu sasl selinux uml virtualbox xen udev"
# IUSE=one : bug #293416 & bug# 299011
# Some tests are simply broken in the released tarball, ignore them
# for now.
RESTRICT=test
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=net-misc/curl-7.18.0
>=dev-libs/libxml2-2.7.6
>=net-libs/gnutls-1.0.25
dev-lang/python
sys-fs/sysfsutils
sys-apps/util-linux
>=net-analyzer/netcat6-1.0-r2
avahi? ( >=net-dns/avahi-0.6[dbus] )
caps? ( sys-libs/libcap-ng )
iscsi? ( sys-block/open-iscsi )
libvirtd? ( net-misc/bridge-utils )
lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
nfs? ( net-fs/nfs-utils )
numa? ( sys-process/numactl )
openvz? ( sys-kernel/openvz-sources )
parted? ( >=sys-apps/parted-1.8 )
phyp? ( net-libs/libssh2 )
policykit? ( >=sys-auth/polkit-0.9 )
qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 ) )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( sys-libs/libselinux )
virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
xen? ( app-emulation/xen-tools app-emulation/xen )
udev? ( >=sys-fs/udev-145 >=x11-libs/libpciaccess-0.10.9 )"
# one? ( dev-libs/xmlrpc-c )
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
src_prepare() {
[[ -n ${BACKPORTS} ]] && \
EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" epatch
epatch "${FILESDIR}"/${P}-virt-pki-validate-sysconfdir.patch
}
src_configure() {
local myconf=""
## enable/disable daemon, otherwise client only utils
myconf="${myconf} $(use_with libvirtd)"
## enable/disable the daemon using avahi to find VMs
myconf="${myconf} $(use_with avahi)"
## hypervisors on the local host
myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
if ! use policykit && use xen; then
myconf="${myconf} --with-xen-proxy"
fi
myconf="${myconf} $(use_with openvz)"
myconf="${myconf} $(use_with lxc)"
myconf="${myconf} $(use_with virtualbox vbox)"
myconf="${myconf} $(use_with uml)"
myconf="${myconf} $(use_with qemu)"
# doesn't belong with hypervisors but links to libvirtd for some reason
#myconf="${myconf} $(use_with one)"
## hypervisor protocols
myconf="${myconf} $(use_with phyp)"
myconf="${myconf} --with-esx"
## additional host drivers
myconf="${myconf} $(use_with network)"
myconf="${myconf} --with-storage-fs"
myconf="${myconf} $(use_with lvm storage-lvm)"
myconf="${myconf} $(use_with iscsi storage-iscsi)"
myconf="${myconf} $(use_with parted storage-disk)"
myconf="${myconf} $(use_with lvm storage-mpath)"
myconf="${myconf} $(use_with numa numactl)"
myconf="${myconf} $(use_with selinux)"
# udev for device support details
myconf="${myconf} $(use_with udev)"
# linux capability support so we don't need privileged accounts
myconf="${myconf} $(use_with caps capng)"
## auth stuff
myconf="${myconf} $(use_with policykit polkit)"
myconf="${myconf} $(use_with sasl)"
## other
myconf="${myconf} $(use_enable nls)"
myconf="${myconf} $(use_with python)"
## stuff we don't yet support
myconf="${myconf} --without-netcf"
# we use udev over hal
myconf="${myconf} --without-hal"
econf \
${myconf} \
--disable-static \
--docdir=/usr/share/doc/${PF} \
--with-remote \
--localstatedir=/var \
--with-remote-pid-file=/var/run/libvirtd.pid
}
src_test() {
# Explicitly allow parallel build of tests
emake check || die "tests failed"
}
src_install() {
emake install \
DESTDIR="${D}" \
HTML_DIR=/usr/share/doc/${PF}/html \
DOCS_DIR=/usr/share/doc/${PF}/python \
EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
|| die "emake install failed"
newinitd "${FILESDIR}/libvirtd.init" libvirtd || die
newconfd "${FILESDIR}/libvirtd.confd" libvirtd || die
keepdir /var/lib/libvirt/images
find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
# we only ever want to generate this once
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
fi
}
pkg_postinst() {
use python && python_mod_optimize $(python_get_sitedir)/libvirt.py
elog
if use policykit; then
elog "You must have run the following at least once:"
elog
elog "$ polkit-auth --grant org.libvirt.unix.manage --user \"USERNAME\""
elog
elog "to grant USERNAME access to libvirt when using USE=policykit"
else
elog "To allow normal users to connect to libvirtd you must change the"
elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
fi
elog
elog "For the basic networking support (bridged and routed networks)"
elog "you don't need any extra software. For more complex network modes"
elog "including but not limited to NATed network, you'll need the"
elog "following packages":
elog
elog " net-dns/dnsmasq"
elog " net-firewall/iptables"
elog " net-firewall/ebtables"
elog
if has_version net-dns/dnsmasq; then
ewarn "If you have a DNS server setup on your machine, you will have"
ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
ewarn " bind-interfaces"
ewarn " interface or except-interface"
ewarn
ewarn "Otherwise you might have issues with your existing DNS server."
fi
}
pkg_postrm() {
use python && python_mod_cleanup
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-02-04 7:05 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-02-04 7:05 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.7.6-r1.ebuild libvirt-0.7.6.ebuild Doug Goldstein (cardoe)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox