[gentoo-commits] gentoo-x86 commit in net-misc/wicd: ChangeLog wicd-1.7.0_beta4.ebuild wicd-1.7.0_alpha3.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/wicd: ChangeLog wicd-1.7.0_beta4.ebuild wicd-1.7.0_alpha3.ebuild

[Jeremy Olexa (darkside)]

darkside    10/01/04 14:09:07

  Modified:             ChangeLog
  Added:                wicd-1.7.0_beta4.ebuild
  Removed:              wicd-1.7.0_alpha3.ebuild
  Log:
  Version bump, more small changes in prep for a final release
  (Portage version: 2.1.7.16/cvs/Linux x86_64)

Revision  Changes    Path
1.62                 net-misc/wicd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	24 Dec 2009 03:03:32 -0000	1.61
+++ ChangeLog	4 Jan 2010 14:09:07 -0000	1.62
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/wicd
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.61 2009/12/24 03:03:32 darkside Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.62 2010/01/04 14:09:07 darkside Exp $
+
+*wicd-1.7.0_beta4 (04 Jan 2010)
+
+  04 Jan 2010; Jeremy Olexa <darkside@gentoo.org> -wicd-1.7.0_alpha3.ebuild,
+  +wicd-1.7.0_beta4.ebuild:
+  Version bump, more small changes in prep for a final release
 
 *wicd-1.7.0_alpha3 (24 Dec 2009)
 



1.1                  net-misc/wicd/wicd-1.7.0_beta4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/wicd-1.7.0_beta4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/wicd-1.7.0_beta4.ebuild?rev=1.1&content-type=text/plain

Index: wicd-1.7.0_beta4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.7.0_beta4.ebuild,v 1.1 2010/01/04 14:09:07 darkside Exp $

EAPI=2

MY_P=${P/_beta/b}
inherit distutils

DESCRIPTION="A lightweight wired and wireless network manager for Linux"
HOMEPAGE="http://wicd.sourceforge.net/"
SRC_URI="http://downloads.wicd.net/src/testing/1.7.x/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="X +gtk ioctl libnotify ncurses nls +pm-utils"

DEPEND=""
# Maybe virtual/dhcp would work, but there are enough problems with
# net-misc/dhcp that I want net-misc/dhcpcd to be guarenteed to be considered
# first if none are installed.
RDEPEND="
	dev-python/dbus-python
	X? ( gtk? ( dev-python/pygtk
		|| (
			x11-misc/ktsuss
			x11-libs/gksu
			kde-base/kdesu
			)
		)
	)
	|| (
		net-misc/dhcpcd
		net-misc/dhcp
		net-misc/pump
	)
	net-wireless/wireless-tools
	net-wireless/wpa_supplicant
	|| (
		sys-apps/net-tools
		sys-apps/ethtool
	)
	ioctl? ( dev-python/python-iwscan dev-python/python-wpactrl )
	libnotify? ( dev-python/notify-python )
	ncurses? ( dev-python/urwid )
	pm-utils? ( >=sys-power/pm-utils-1.1.1 )
	"

S="${WORKDIR}/${MY_P}"

src_compile() {
	local myconf
	use gtk || myconf="${myconf} --no-install-gtk"
	use libnotify || myconf="${myconf} --no-use-notifications"
	use ncurses || myconf="${myconf} --no-install-ncurses"
	use pm-utils || myconf="${myconf} --no-install-pmutils"
	${python} ./setup.py configure --no-install-docs --resume=/usr/share/wicd/scripts/ --suspend=/usr/share/wicd/scripts/ --verbose ${myconf}
	distutils_src_compile
}

src_install() {
	DOCS="CHANGES NEWS AUTHORS README"
	distutils_src_install
	keepdir /var/lib/wicd/configurations \
		|| die "keepdir failed, critical for this app"
	keepdir /etc/wicd/scripts/{postconnect,disconnect,preconnect} \
		|| die "keepdir failed, critical for this app"
	keepdir /var/log/wicd \
		|| die "keepdir failed, critical for this app"
	use nls || rm -rf ${D}/usr/share/locale
}

pkg_postinst() {
	distutils_pkg_postinst

	elog "You may need to restart the dbus service after upgrading wicd."
	echo
	elog "To start wicd at boot, add /etc/init.d/wicd to a runlevel and:"
	elog "- Remove all net.* initscripts (except for net.lo) from all runlevels"
	elog "- Add these scripts to the RC_PLUG_SERVICES line in /etc/conf.d/rc"
	elog "(For example, RC_PLUG_SERVICES=\"!net.eth0 !net.wlan0\")"
	# Maintainer's note: the consolekit use flag short circuits a dbus rule and
	# allows the connection. Else, you need to be in the group.
	if has_version sys-auth/pambase; then
		if ! built_with_use sys-auth/pambase consolekit; then
			ewarn "Wicd-1.6 and newer requires your user to be in the 'users' group. If"
			ewarn "you are not in that group, then modify /etc/dbus-1/system.d/wicd.conf"
		fi
	fi
}