[gentoo-commits] gentoo-x86 commit in games-arcade/lbreakout2: ChangeLog lbreakout2-2.6.1.ebuild

["Michael Sterrett (mr_bones_)" <mr_bones_@gentoo.org>]

mr_bones_    09/12/30 20:51:20

  Modified:             ChangeLog
  Added:                lbreakout2-2.6.1.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.22                 games-arcade/lbreakout2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/lbreakout2/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/lbreakout2/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/lbreakout2/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	22 Feb 2009 23:50:59 -0000	1.21
+++ ChangeLog	30 Dec 2009 20:51:20 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/lbreakout2
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v 1.21 2009/02/22 23:50:59 mr_bones_ Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v 1.22 2009/12/30 20:51:20 mr_bones_ Exp $
+
+*lbreakout2-2.6.1 (30 Dec 2009)
+
+  30 Dec 2009; Michael Sterrett <mr_bones_@gentoo.org>
+  +lbreakout2-2.6.1.ebuild, +files/lbreakout2-2.6.1-gentoo.patch:
+  version bump
 
   22 Feb 2009; Michael Sterrett <mr_bones_@gentoo.org>
   lbreakout2-2.5.2.ebuild:



1.1                  games-arcade/lbreakout2/lbreakout2-2.6.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.1.ebuild?rev=1.1&content-type=text/plain

Index: lbreakout2-2.6.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.1.ebuild,v 1.1 2009/12/30 20:51:20 mr_bones_ Exp $

EAPI=2
inherit autotools flag-o-matic eutils games

levels_V=20091026
themes_V=20070514

DESCRIPTION="Breakout clone written with the SDL library"
HOMEPAGE="http://lgames.sourceforge.net/index.php?project=LBreakout2"
SRC_URI=" mirror://sourceforge/lgames/${P}.tar.gz
	mirror://sourceforge/lgames/${PN}-levelsets-${levels_V}.tar.gz
	themes? ( mirror://sourceforge/lgames/${PN}-themes-${themes_V}.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~x86 ~x86-fbsd"
IUSE="nls themes"

RDEPEND="media-libs/libpng
	sys-libs/zlib
	media-libs/libsdl[audio,joystick,video]
	media-libs/sdl-net
	media-libs/sdl-mixer
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${P}.tar.gz

	cd "${S}/client/levels"
	unpack ${PN}-levelsets-${levels_V}.tar.gz

	if use themes ; then
		mkdir "${WORKDIR}/themes"
		cd "${WORKDIR}/themes"
		unpack ${PN}-themes-${themes_V}.tar.gz

		# Delete a few duplicate themes (already shipped with lbreakout2
		# tarball). Some of them have different case than built-in themes, so it
		# is harder to just compare if the filename is the same.
		rm -f absoluteB.zip oz.zip moiree.zip
		for f in *.zip; do
			unzip -q "$f"  &&  rm -f "$f"  ||  die "unpacking ${f}"
		done
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	eautoreconf
}

src_configure() {
	filter-flags -O?
	egamesconf \
		--enable-sdl-net \
		--localedir=/usr/share/locale \
		--with-docdir="/usr/share/doc/${PF}/html" \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS README TODO ChangeLog

	if use themes ; then
		insinto "${GAMES_DATADIR}/lbreakout2/gfx"
		doins -r "${WORKDIR}/themes/"*  || die
	fi

	newicon client/gfx/win_icon.png lbreakout2.png
	make_desktop_entry lbreakout2 LBreakout2

	prepgamesdirs
}