[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0.ebuild

[Alex Alexander (wired)]

wired       09/12/26 13:42:31

  Modified:             ChangeLog
  Added:                mc-4.7.0.ebuild
  Log:
  version bump, bug #298385
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.178                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.178&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.178&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?r1=1.177&r2=1.178

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.177
retrieving revision 1.178
diff -u -r1.177 -r1.178
--- ChangeLog	26 Nov 2009 18:34:35 -0000	1.177
+++ ChangeLog	26 Dec 2009 13:42:31 -0000	1.178
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.177 2009/11/26 18:34:35 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.178 2009/12/26 13:42:31 wired Exp $
+
+*mc-4.7.0 (26 Dec 2009)
+
+  26 Dec 2009; Alex Alexander <wired@gentoo.org> +mc-4.7.0.ebuild:
+  version bump, bug #298385
 
   26 Nov 2009; Raúl Porcel <armin76@gentoo.org> mc-4.7.0_pre3.ebuild:
   arm/ia64/s390/sh/sparc stable wrt #290347



1.1                  app-misc/mc/mc-4.7.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0.ebuild,v 1.1 2009/12/26 13:42:31 wired Exp $

EAPI=2
MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="+edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.14:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_with samba) \
		--with-configdir=/etc/samba \
		--with-codepagedir=/var/lib/samba/codepages \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". /usr/libexec/mc/mc.sh"
}