* [gentoo-commits] gentoo-x86 commit in media-sound/mpd: ChangeLog mpd-0.15.6.ebuild
@ 2009-11-21 19:20 Christoph Mende (angelos)
0 siblings, 0 replies; 2+ messages in thread
From: Christoph Mende (angelos) @ 2009-11-21 19:20 UTC (permalink / raw
To: gentoo-commits
angelos 09/11/21 19:20:10
Modified: ChangeLog
Added: mpd-0.15.6.ebuild
Log:
Version bump
(Portage version: 2.2_rc50/cvs/Linux x86_64)
Revision Changes Path
1.188 media-sound/mpd/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?rev=1.188&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?rev=1.188&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?r1=1.187&r2=1.188
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v
retrieving revision 1.187
retrieving revision 1.188
diff -u -r1.187 -r1.188
--- ChangeLog 30 Oct 2009 16:40:35 -0000 1.187
+++ ChangeLog 21 Nov 2009 19:20:10 -0000 1.188
@@ -1,6 +1,11 @@
# ChangeLog for media-sound/mpd
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.187 2009/10/30 16:40:35 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.188 2009/11/21 19:20:10 angelos Exp $
+
+*mpd-0.15.6 (21 Nov 2009)
+
+ 21 Nov 2009; Christoph Mende <angelos@gentoo.org> +mpd-0.15.6.ebuild:
+ Version bump
*mpd-0.15.5 (30 Oct 2009)
1.1 media-sound/mpd/mpd-0.15.6.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild?rev=1.1&content-type=text/plain
Index: mpd-0.15.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild,v 1.1 2009/11/21 19:20:10 angelos Exp $
EAPI=2
inherit eutils flag-o-matic multilib
DESCRIPTION="The Music Player Daemon (mpd)"
HOMEPAGE="http://www.musicpd.org"
SRC_URI="mirror://sourceforge/musicpd/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="aac +alsa ao audiofile avahi bzip2 cdio cue +curl debug +fifo +ffmpeg flac
fluidsynth profile +id3 ipv6 jack lame lastfmradio libmms libsamplerate +mad
mikmod modplug musepack +network ogg oss pipe pulseaudio sid sqlite unicode
vorbis wavpack zip"
RDEPEND="!sys-cluster/mpich2
>=dev-libs/glib-2.4:2
aac? ( >=media-libs/faad2-2 )
alsa? ( media-sound/alsa-utils )
ao? ( >=media-libs/libao-0.8.4[alsa?,pulseaudio?] )
audiofile? ( media-libs/audiofile )
bzip2? ( app-arch/bzip2 )
cdio? ( dev-libs/libcdio )
cue? ( >=media-libs/libcue-0.13 )
curl? ( net-misc/curl )
ffmpeg? ( media-video/ffmpeg )
flac? ( media-libs/flac[ogg?] )
fluidsynth? ( media-sound/fluidsynth )
network? ( >=media-libs/libshout-2
!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
id3? ( media-libs/libid3tag )
jack? ( media-sound/jack-audio-connection-kit )
lame? ( network? ( media-sound/lame ) )
libmms? ( >=media-libs/libmms-0.4 )
libsamplerate? ( media-libs/libsamplerate )
mad? ( media-libs/libmad )
mikmod? ( media-libs/libmikmod )
modplug? ( media-libs/libmodplug )
musepack? ( >=media-sound/musepack-tools-444 )
ogg? ( media-libs/libogg )
pulseaudio? ( media-sound/pulseaudio )
sid? ( >=media-libs/libsidplay-2.1.1-r2:2 )
sqlite? ( dev-db/sqlite:3 )
vorbis? ( media-libs/libvorbis )
wavpack? ( media-sound/wavpack )
avahi? ( net-dns/avahi )
zip? ( dev-libs/zziplib )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
pkg_setup() {
use network || ewarn "Icecast and Shoutcast streaming needs networking."
use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
enewuser mpd "" "" "/var/lib/mpd" audio
}
src_prepare() {
cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
epatch "${FILESDIR}"/0.15.1-mpdconf.patch
}
src_configure() {
use profile && filter-flags -fomit-frame-pointer
local mpdconf="--enable-tcp --enable-un --disable-wildmidi
--disable-libOggFLACtest --disable-documentation"
if use network; then
mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
--enable-httpd-output $(use_enable lame lame-encoder)"
if ! use lame && ! use vorbis; then
ewarn "At least one encoder is required, enabling vorbis for you."
mpdconf+=" --enable-vorbis-encoder"
fi
else
mpdconf+=" --disable-shout --disable-vorbis-encoder
--disable-httpd-output --disable-lame-encoder"
fi
if use flac && use ogg; then
mpdconf+=" --enable-oggflac"
else
mpdconf+=" --disable-oggflac"
fi
append-lfs-flags
append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
cd "${S}"
econf \
$(use_enable ipv6) $(use_enable cue) \
$(use_enable sqlite) $(use_enable curl) \
$(use_enable lastfmradio lastfm) $(use_enable libmms mms) \
$(use_enable bzip2) $(use_enable zip) \
$(use_enable cdio iso9660) $(use_enable id3) \
$(use_enable audiofile) $(use_enable ffmpeg) \
$(use_enable flac) $(use_enable mad) \
$(use_enable mikmod) $(use_enable modplug) \
$(use_enable musepack mpc) $(use_enable vorbis) \
$(use_enable sid sidplay) $(use_enable fluidsynth) \
$(use_enable wavpack) $(use_enable libsamplerate lsr) \
$(use_enable alsa) $(use_enable ao) \
$(use_enable fifo) $(use_enable pipe pipe-output) \
$(use_enable jack) $(use_enable oss) \
$(use_enable pulseaudio pulse) $(use_enable aac) \
$(use_enable debug) $(use_enable profile gprof) \
$(use_with avahi zeroconf avahi) \
${mpdconf}
}
src_install() {
dodir /var/run/mpd
fowners mpd:audio /var/run/mpd
fperms 750 /var/run/mpd
keepdir /var/run/mpd
emake DESTDIR="${D}" install || die "emake install failed"
rm -rf "${D}"/usr/share/doc/mpd
dodoc AUTHORS NEWS README UPGRADING doc/mpdconf.dist
insinto /etc
newins doc/mpdconf.example mpd.conf
newinitd "${FILESDIR}"/mpd.rc mpd
if use unicode; then
dosed 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
/etc/mpd.conf || die "dosed failed"
fi
diropts -m0755 -o mpd -g audio
dodir /var/lib/mpd
keepdir /var/lib/mpd
dodir /var/lib/mpd/music
keepdir /var/lib/mpd/music
dodir /var/lib/mpd/playlists
keepdir /var/lib/mpd/playlists
dodir /var/log/mpd
keepdir /var/log/mpd
if use alsa; then
dosed 's:need :need alsasound :' /etc/init.d/mpd || die "dosed failed"
fi
}
pkg_postinst() {
elog "If you will be starting mpd via /etc/init.d/mpd, please make"
elog "sure that MPD's pid_file is set to /var/run/mpd/mpd.pid."
# also change the homedir if the user has existed before
usermod -d "/var/lib/mpd" mpd
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-sound/mpd: ChangeLog mpd-0.15.6.ebuild
@ 2009-12-21 14:46 Christoph Mende (angelos)
0 siblings, 0 replies; 2+ messages in thread
From: Christoph Mende (angelos) @ 2009-12-21 14:46 UTC (permalink / raw
To: gentoo-commits
angelos 09/12/21 14:46:40
Modified: ChangeLog mpd-0.15.6.ebuild
Log:
Added patch to fix compilation with USE=wavpack (bug #297599), thanks to Darren Smith
(Portage version: 2.2_rc60/cvs/Linux x86_64)
Revision Changes Path
1.194 media-sound/mpd/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/ChangeLog?r1=1.193&r2=1.194
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog 9 Dec 2009 14:54:24 -0000 1.193
+++ ChangeLog 21 Dec 2009 14:46:39 -0000 1.194
@@ -1,6 +1,11 @@
# ChangeLog for media-sound/mpd
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.193 2009/12/09 14:54:24 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.194 2009/12/21 14:46:39 angelos Exp $
+
+ 21 Dec 2009; Christoph Mende <angelos@gentoo.org> mpd-0.15.6.ebuild,
+ +files/mpd-0.15.6-wavpack-uchar.patch:
+ Added patch to fix compilation with USE=wavpack (bug #297599), thanks to
+ Darren Smith
09 Dec 2009; Brent Baude <ranger@gentoo.org> mpd-0.15.5.ebuild:
Marking mpd-0.15.5 ppc64 for bug 293975
1.2 media-sound/mpd/mpd-0.15.6.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild?r1=1.1&r2=1.2
Index: mpd-0.15.6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- mpd-0.15.6.ebuild 21 Nov 2009 19:20:10 -0000 1.1
+++ mpd-0.15.6.ebuild 21 Dec 2009 14:46:39 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild,v 1.1 2009/11/21 19:20:10 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.15.6.ebuild,v 1.2 2009/12/21 14:46:39 angelos Exp $
EAPI=2
inherit eutils flag-o-matic multilib
@@ -61,7 +61,8 @@
src_prepare() {
cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
- epatch "${FILESDIR}"/0.15.1-mpdconf.patch
+ epatch "${FILESDIR}"/0.15.1-mpdconf.patch \
+ "${FILESDIR}"/${P}-wavpack-uchar.patch
}
src_configure() {
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-12-21 14:46 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-12-21 14:46 [gentoo-commits] gentoo-x86 commit in media-sound/mpd: ChangeLog mpd-0.15.6.ebuild Christoph Mende (angelos)
-- strict thread matches above, loose matches on Subject: below --
2009-11-21 19:20 Christoph Mende (angelos)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox