[gentoo-commits] gentoo-x86 commit in sys-process/audit: ChangeLog audit-1.7.17.ebuild

[gentoo-commits] gentoo-x86 commit in sys-process/audit: ChangeLog audit-1.7.17.ebuild

[Robin H. Johnson (robbat2)]

robbat2     09/12/19 22:08:44

  Modified:             ChangeLog
  Added:                audit-1.7.17.ebuild
  Log:
  Version bump, also fix BL2 issue per bug #241884.
  (Portage version: 2.2_rc58/cvs/Linux x86_64)

Revision  Changes    Path
1.56                 sys-process/audit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -p -w -b -B -u -u -r1.55 -r1.56
--- ChangeLog	24 Sep 2009 04:10:24 -0000	1.55
+++ ChangeLog	19 Dec 2009 22:08:44 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for sys-process/audit
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v 1.55 2009/09/24 04:10:24 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/ChangeLog,v 1.56 2009/12/19 22:08:44 robbat2 Exp $
+
+*audit-1.7.17 (19 Dec 2009)
+
+  19 Dec 2009; Robin H. Johnson <robbat2@gentoo.org>
+  +files/auditd-init.d-1.7.17, +audit-1.7.17.ebuild:
+  Version bump, also fix BL2 issue per bug #241884.
 
   24 Sep 2009; Jeremy Olexa <darkside@gentoo.org> -audit-1.6.8.ebuild:
   remove vuln version wrt bug 271746



1.1                  sys-process/audit/audit-1.7.17.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/audit-1.7.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-process/audit/audit-1.7.17.ebuild?rev=1.1&content-type=text/plain

Index: audit-1.7.17.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/audit/audit-1.7.17.ebuild,v 1.1 2009/12/19 22:08:44 robbat2 Exp $

inherit autotools multilib toolchain-funcs python

DESCRIPTION="Userspace utilities for storing and processing auditing records"
HOMEPAGE="http://people.redhat.com/sgrubb/audit/"
SRC_URI="http://people.redhat.com/sgrubb/audit/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="ldap"
# Testcases are pretty useless as they are built for RedHat users/groups and
# kernels.
RESTRICT="test"

RDEPEND=">=dev-lang/python-2.4
		ldap? ( net-nds/openldap )"
DEPEND="${RDEPEND}
	dev-lang/swig
	>=sys-kernel/linux-headers-2.6.23"
# Do not use os-headers as this is linux specific

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Old patch applies fine
	#EPATCH_OPTS="-p0 -d${S}" epatch "${FILESDIR}"/${PN}-1.5.4-build.patch

	# Applied by upstream
	#EPATCH_OPTS="-p1 -d${S}" epatch "${FILESDIR}"/${PN}-1.5.4-swig-gcc-attribute.patch

	# Do not build GUI tools
	sed -i \
		-e '/AC_CONFIG_SUBDIRS.*system-config-audit/d' \
		"${S}"/configure.ac
	sed -i \
		-e 's,system-config-audit,,g' \
		-e '/^SUBDIRS/s,\\$,,g' \
		"${S}"/Makefile.am
	rm -rf "${S}"/system-config-audit

	# Probably goes away in 1.6.9
	#EPATCH_OPTS="-p1 -d${S}" epatch "${FILESDIR}"/audit-1.6.8-subdirs-fix.patch

	if ! use ldap; then
		sed -i \
			-e '/^AC_OUTPUT/s,audisp/plugins/zos-remote/Makefile,,g' \
			"${S}"/configure.ac
		sed -i \
			-e '/^SUBDIRS/s,zos-remote,,g' \
			"${S}"/audisp/plugins/Makefile.am
	fi

	# Regenerate autotooling
	eautoreconf
}

src_compile() {
	#append-flags -D'__attribute__(x)='
	econf --sbindir=/sbin --without-prelude || die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README* THANKS TODO
	docinto contrib
	dodoc contrib/*
	docinto contrib/plugin
	dodoc contrib/plugin/*

	newinitd "${FILESDIR}"/auditd-init.d-1.7.17 auditd
	newconfd "${FILESDIR}"/auditd-conf.d-1.2.3 auditd

	# things like shadow use this so we need to be in /
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/lib*.so* "${D}"/$(get_libdir)/ || die
	gen_usr_ldscript libaudit.so libauparse.so

	# remove RedHat garbage
	rm -r "${D}"/etc/{rc.d,sysconfig} || die

	# Gentoo rules
	insinto /etc/audit/
	doins "${FILESDIR}"/audit.rules*

	# audit logs go here
	keepdir /var/log/audit/

	# Security
	lockdown_perms "${D}"
}

pkg_postinst() {
	lockdown_perms "${ROOT}"
	python_mod_optimize
}

pkg_postrm() {
	python_mod_cleanup
}

lockdown_perms() {
	# upstream wants these to have restrictive perms
	basedir="$1"
	chmod 0750 "${basedir}"/sbin/au{ditctl,report,dispd,ditd,search,trace} 2>/dev/null
	chmod 0750 "${basedir}"/var/log/audit/ 2>/dev/null
	chmod 0640 "${basedir}"/etc/{audit/,}{auditd.conf,audit.rules*} 2>/dev/null
}