[gentoo-commits] gentoo-x86 commit in dev-libs/redland: ChangeLog redland-1.0.10-r1.ebuild

["Samuli Suominen (ssuominen)" <ssuominen@gentoo.org>]

ssuominen    09/12/18 13:42:27

  Modified:             ChangeLog
  Added:                redland-1.0.10-r1.ebuild
  Log:
  LIBADD librdf.la for librdf_storage_virtuoso.so wrt #297363.
  (Portage version: 2.2_rc59/cvs/Linux x86_64)

Revision  Changes    Path
1.60                 dev-libs/redland/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/redland/ChangeLog?rev=1.60&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/redland/ChangeLog?rev=1.60&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/redland/ChangeLog?r1=1.59&r2=1.60

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/redland/ChangeLog,v
retrieving revision 1.59
retrieving revision 1.60
diff -u -r1.59 -r1.60
--- ChangeLog	17 Dec 2009 14:14:01 -0000	1.59
+++ ChangeLog	18 Dec 2009 13:42:26 -0000	1.60
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/redland
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland/ChangeLog,v 1.59 2009/12/17 14:14:01 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland/ChangeLog,v 1.60 2009/12/18 13:42:26 ssuominen Exp $
+
+*redland-1.0.10-r1 (18 Dec 2009)
+
+  18 Dec 2009; Samuli Suominen <ssuominen@gentoo.org>
+  +redland-1.0.10-r1.ebuild,
+  +files/redland-1.0.10-librdf_storage_register_factory.patch:
+  LIBADD librdf.la for librdf_storage_virtuoso.so wrt #297363.
 
 *redland-1.0.10 (17 Dec 2009)
 



1.1                  dev-libs/redland/redland-1.0.10-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/redland/redland-1.0.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/redland/redland-1.0.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: redland-1.0.10-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland/redland-1.0.10-r1.ebuild,v 1.1 2009/12/18 13:42:26 ssuominen Exp $

EAPI=2
inherit autotools eutils

DESCRIPTION="High-level interface for the Resource Description Framework"
HOMEPAGE="http://librdf.org/"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"

LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="berkdb iodbc mysql postgres sqlite ssl threads xml"

RDEPEND="mysql? ( virtual/mysql )
	sqlite? ( =dev-db/sqlite-3* )
	berkdb? ( sys-libs/db )
	xml? ( dev-libs/libxml2 )
	!xml? ( dev-libs/expat )
	ssl? ( dev-libs/openssl )
	>=media-libs/raptor-1.4.17
	>=dev-libs/rasqal-0.9.16
	postgres? ( virtual/postgresql-base )
	iodbc? ( dev-db/libiodbc )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2
	dev-util/gtk-doc-am
	dev-util/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${P}-librdf_storage_register_factory.patch

	sed -i \
		-e '/SHAVE/d' configure.ac || die
	eautoreconf
}

src_configure() {
	local parser="expat"

	use xml && parser="libxml"

	econf \
		--disable-dependency-tracking \
		$(use_with berkdb bdb) \
		--with-xml-parser=${parser} \
		$(use_with ssl openssl-digests) \
		$(use_with mysql) \
		$(use_with sqlite) \
		$(use_with postgres postgresql) \
		$(use_with iodbc virtuoso) \
		$(use_with threads) \
		--with-html-dir=/usr/share/doc/${PF}/html
}

src_test() {
	# Remove this hack from next release.
	if use threads; then
		ewarn "Test suite is known to be broken with USE threads, skipping."
	else
		emake check || die
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README TODO
	dohtml {FAQS,NEWS,README,RELEASE,TODO}.html
}