[gentoo-commits] gentoo-x86 commit in app-text/evince: ChangeLog evince-2.28.2.ebuild

["Gilles Dartiguelongue (eva)" <eva@gentoo.org>]

eva         09/12/18 00:03:00

  Modified:             ChangeLog
  Added:                evince-2.28.2.ebuild
  Log:
  Version bump. Rendering fixes, documentation and translation updates.
  (Portage version: 2.2_rc60/cvs/Linux x86_64)

Revision  Changes    Path
1.181                app-text/evince/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?rev=1.181&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?rev=1.181&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?r1=1.180&r2=1.181

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v
retrieving revision 1.180
retrieving revision 1.181
diff -u -r1.180 -r1.181
--- ChangeLog	3 Dec 2009 17:16:21 -0000	1.180
+++ ChangeLog	18 Dec 2009 00:02:59 -0000	1.181
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/evince
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.180 2009/12/03 17:16:21 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.181 2009/12/18 00:02:59 eva Exp $
+
+*evince-2.28.2 (18 Dec 2009)
+
+  18 Dec 2009; Gilles Dartiguelongue <eva@gentoo.org> +evince-2.28.2.ebuild:
+  Version bump. Rendering fixes, documentation and translation updates.
 
   03 Dec 2009; Brent Baude <ranger@gentoo.org> evince-2.26.2.ebuild:
   Marking evince-2.26.2 ppc64 stable for bug 281427



1.1                  app-text/evince/evince-2.28.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/evince-2.28.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/evince-2.28.2.ebuild?rev=1.1&content-type=text/plain

Index: evince-2.28.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/evince/evince-2.28.2.ebuild,v 1.1 2009/12/18 00:02:59 eva Exp $

EAPI="2"

inherit autotools eutils gnome2

DESCRIPTION="Simple document viewer for GNOME"
HOMEPAGE="http://www.gnome.org/projects/evince/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="dbus debug djvu doc dvi gnome gnome-keyring nautilus t1lib tiff"
# tests introspection

# Since 2.26.2, can handle poppler without cairo support. Make it optional ?
# not mature enough
#	introspection? ( >=dev-libs/gobject-introspection-0.6 )
RDEPEND="
	>=app-text/libspectre-0.2.0
	>=dev-libs/glib-2.18.0
	>=dev-libs/libxml2-2.5
	>=x11-libs/gtk+-2.14
	>=x11-libs/libSM-1
	>=x11-themes/gnome-icon-theme-2.17.1
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	gnome? ( >=gnome-base/gconf-2 )
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.22.0 )
	nautilus? ( >=gnome-base/nautilus-2.10 )
	>=virtual/poppler-glib-0.11[cairo]
	dvi? (
		virtual/tex-base
		t1lib? ( >=media-libs/t1lib-5.0.0 ) )
	tiff? ( >=media-libs/tiff-3.6 )
	djvu? ( >=app-text/djvu-3.5.17 )"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.3.2
	~app-text/docbook-xml-dtd-4.1.2
	>=dev-util/pkgconfig-0.9
	sys-devel/gettext
	>=dev-util/intltool-0.35
	dev-util/gtk-doc-am
	doc? ( dev-util/gtk-doc )"

DOCS="AUTHORS ChangeLog NEWS README TODO"
ELTCONF="--portage"

# Needs dogtail and pyspi from http://fedorahosted.org/dogtail/
# Releases: http://people.redhat.com/zcerza/dogtail/releases/
RESTRICT="test"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-introspection
		--disable-scrollkeeper
		--disable-static
		--disable-tests
		--enable-pdf
		--enable-comics
		--enable-impress
		--enable-thumbnailer
		--with-smclient=xsmp
		--with-platform=gnome
		$(use_enable dbus)
		$(use_enable djvu)
		$(use_enable dvi)
		$(use_with gnome gconf)
		$(use_with gnome-keyring keyring)
		$(use_enable t1lib)
		$(use_enable tiff)
		$(use_enable nautilus)"
#		$(use_enable introspection)
}

src_prepare() {
	gnome2_src_prepare

	# Fix .desktop file so menu item shows up
	epatch "${FILESDIR}"/${PN}-0.7.1-display-menu.patch

	# Fix bug #279591, compilation error with
	# --with-smclient=xsmp gave to the configure script
	epatch "${FILESDIR}"/${PN}-2.27.4-smclient-configure.patch

	# Make it libtool-1 compatible
	rm -v m4/lt* m4/libtool.m4 || die "removing libtool macros failed"

	# gconf-2.m4 is needed for autoconf; bug 291339
	if ! use gnome; then
		cp "${FILESDIR}/gconf-2.m4" m4/ || die "Copying gconf-2.m4 failed!"
	fi

	intltoolize --force --automake --copy || die "intltoolized failed"
	eautoreconf
}

src_install() {
	gnome2_src_install
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}