[gentoo-commits] gentoo-x86 commit in app-text/kchmviewer: kchmviewer-5.1.ebuild ChangeLog kchmviewer-5.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/kchmviewer: kchmviewer-5.1.ebuild ChangeLog kchmviewer-5.0.ebuild

[Peter Volkov (pva)]

pva         09/12/17 18:15:35

  Modified:             ChangeLog
  Added:                kchmviewer-5.1.ebuild
  Removed:              kchmviewer-5.0.ebuild
  Log:
  Version bump. Thank Rion for report.
  (Portage version: 2.2_rc59/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 app-text/kchmviewer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/kchmviewer/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/kchmviewer/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/kchmviewer/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/kchmviewer/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	15 Dec 2009 10:44:25 -0000	1.24
+++ ChangeLog	17 Dec 2009 18:15:35 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/kchmviewer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/ChangeLog,v 1.24 2009/12/15 10:44:25 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/ChangeLog,v 1.25 2009/12/17 18:15:35 pva Exp $
+
+*kchmviewer-5.1 (17 Dec 2009)
+
+  17 Dec 2009; Peter Volkov <pva@gentoo.org> -kchmviewer-5.0.ebuild,
+  +kchmviewer-5.1.ebuild:
+  Version bump. Thank Rion for report.
 
 *kchmviewer-5.0 (15 Dec 2009)
 



1.1                  app-text/kchmviewer/kchmviewer-5.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/kchmviewer/kchmviewer-5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/kchmviewer/kchmviewer-5.1.ebuild?rev=1.1&content-type=text/plain

Index: kchmviewer-5.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/kchmviewer/kchmviewer-5.1.ebuild,v 1.1 2009/12/17 18:15:35 pva Exp $

EAPI="2"
KDE_REQUIRED="never"
inherit fdo-mime qt4 kde4-base

DESCRIPTION="KchmViewer is a feature rich chm file viewer, based on Qt."
HOMEPAGE="http://www.kchmviewer.net/"
SRC_URI="mirror://sourceforge/kchmviewer/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="kde"

RDEPEND="dev-libs/chmlib
	>=x11-libs/qt-dbus-4.5:4
	>=x11-libs/qt-webkit-4.5:4
	!kde? ( >=x11-libs/qt-gui-4.5:4 )
	kde? ( >=kde-base/kdelibs-4.1
			!kde-base/okular[chm] )"
DEPEND="${RDEPEND}
		kde? ( dev-util/cmake )"

S=${WORKDIR}/build-${PV}

pkg_setup() {
	use kde && kde4-base_pkg_setup
}

src_prepare() {
	sed -e "s:KDE4_SERVICES_INSTALL_DIR:SERVICES_INSTALL_DIR:" \
			-i lib/kio-msits/CMakeLists.txt
	sed -e "s:KDE4_ICON_INSTALL_DIR:ICON_INSTALL_DIR:" \
		-e "s:KDE4_XDG_APPS_INSTALL_DIR:XDG_APPS_INSTALL_DIR:" \
			-i packages/CMakeLists.txt
	sed -e "s:KDE4_BIN_INSTALL_DIR:BIN_INSTALL_DIR:" \
			-i src/CMakeLists.txt
	echo "CONFIG += ordered" >> kchmviewer.pro # parallel build fix #281954
}

src_configure() {
	if use kde; then
		kde4-base_src_configure
	else
		eqmake4
	fi
}

src_compile() {
	if use kde; then
		kde4-base_src_compile
	else
		emake || die
	fi
}

src_test() {
	einfo "No tests exist."
}

src_install() {
	if use kde; then
		kde4-base_src_install
	else
		dobin bin/kchmviewer || die "dobin kchmviewer failed"
		domenu packages/kchmviewer.desktop || die
		dodoc ChangeLog README || die
	fi
	insinto /usr/share/pixmaps/
	doins packages/kchmviewer.png || die
	dodoc DBUS-bindings FAQ || die
}

pkg_postinst() {
	use kde && kde4-base_pkg_postinst
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	use kde && kde4-base_pkg_postrm
	fdo-mime_desktop_database_update
}