[gentoo-commits] gentoo-x86 commit in app-text/a2ps: ChangeLog a2ps-4.14-r1.ebuild

["Matsuu Takuto (matsuu)" <matsuu@gentoo.org>]

matsuu      09/12/14 17:00:58

  Modified:             ChangeLog
  Added:                a2ps-4.14-r1.ebuild
  Log:
  Added RESTRICT="test", bug #171002. Replaced cjk USE flag to linguas_ja. Added a patch for obstack.h, bug #269638. clean up.
  (Portage version: 2.1.7.13/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 app-text/a2ps/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	8 Apr 2009 09:45:53 -0000	1.86
+++ ChangeLog	14 Dec 2009 17:00:57 -0000	1.87
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/a2ps
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v 1.86 2009/04/08 09:45:53 armin76 Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v 1.87 2009/12/14 17:00:57 matsuu Exp $
+
+*a2ps-4.14-r1 (14 Dec 2009)
+
+  14 Dec 2009; MATSUU Takuto <matsuu@gentoo.org> +a2ps-4.14-r1.ebuild,
+  +files/a2ps-4.14-psset.patch, +files/a2ps-4.14-ptrdiff_t.patch:
+  Added RESTRICT="test", bug #171002. Replaced cjk USE flag to linguas_ja.
+  Added a patch for obstack.h, bug #269638. clean up.
 
   08 Apr 2009; Raúl Porcel <armin76@gentoo.org> a2ps-4.14.ebuild:
   Add ~arm/~s390/~sh



1.1                  app-text/a2ps/a2ps-4.14-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/a2ps-4.14-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/a2ps-4.14-r1.ebuild?rev=1.1&content-type=text/plain

Index: a2ps-4.14-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/a2ps-4.14-r1.ebuild,v 1.1 2009/12/14 17:00:57 matsuu Exp $

inherit eutils autotools elisp-common

DESCRIPTION="Any to PostScript filter"
HOMEPAGE="http://www.inf.enst.fr/~demaille/a2ps/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz
	linguas_ja? ( mirror://gentoo/${P}-ja_nls.patch.gz )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="emacs nls latex vanilla userland_BSD userland_GNU linguas_ja"

RESTRICT="test"

DEPEND=">=dev-util/gperf-2.7.2
	|| ( >=dev-util/yacc-1.9.1 sys-devel/bison )
	virtual/ghostscript
	>=app-text/psutils-1.17
	emacs? ( virtual/emacs )
	latex? ( virtual/latex-base )
	nls? ( sys-devel/gettext )"
RDEPEND="virtual/ghostscript
	app-text/wdiff
	userland_GNU? ( || ( >=sys-apps/coreutils-6.10-r1 sys-apps/mktemp ) )
	userland_BSD? ( sys-freebsd/freebsd-ubin )
	>=app-text/psutils-1.17
	emacs? ( virtual/emacs )
	latex? ( virtual/latex-base )
	nls? ( virtual/libintl )"

SITEFILE="50${PN}-gentoo.el"

S="${WORKDIR}/${PN}-${PV:0:4}"

src_unpack() {
	unpack ${P}.tar.gz
	cd "${S}"

	epatch "${FILESDIR}/${PN}-4.13c-locale-gentoo.diff"
	# this will break
	#epatch "${FILESDIR}/${PN}-4.13c-stdarg.patch"
	use vanilla || epatch "${FILESDIR}/${PN}-4.13-stdout.diff"
	use linguas_ja && epatch "${DISTDIR}/${P}-ja_nls.patch.gz"

	# fix fnmatch replacement, bug #134546
	epatch "${FILESDIR}/${PN}-4.13c-fnmatch-replacement.patch"

	# bug #122026
	epatch "${FILESDIR}/${P}-psset.patch"

	# fix emacs printing, bug #114627
	epatch "${FILESDIR}/a2ps-4.13c-emacs.patch"

	# fix chmod error, #167670
	epatch "${FILESDIR}/a2ps-4.13-manpage-chmod.patch"

	# add configure check for mempcpy, bug 216588
	epatch "${FILESDIR}/${P}-check-mempcpy.patch"

	# fix compilation error due to invalid stpcpy() prototype, bug 216588
	epatch "${FILESDIR}/${P}-fix-stpcpy-proto.patch"

	# fix compilation error due to obstack.h issue, bug 269638
	epatch "${FILESDIR}/${P}-ptrdiff_t.patch"

	eautoreconf
}

src_compile() {
	local myconf="COM_netscape=no COM_acroread=no"

	if ! use emacs ; then
		myconf="${myconf} EMACS=no"
	fi

	if ! use latex ; then
		myconf="${myconf} COM_latex=no"
	fi

	export LANG=C LC_ALL=C

	econf \
		--sysconfdir=/etc/a2ps \
		$(use_enable nls) \
		${myconf} || die "econf failed"

	# parallel make b0rked
	emake -j1 || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" \
			|| die "elisp-site-file-install failed"
	fi

	dodoc ANNOUNCE AUTHORS ChangeLog FAQ NEWS README* THANKS TODO
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}