[gentoo-commits] gentoo-x86 commit in sys-fs/cryptsetup: ChangeLog cryptsetup-1.0.7.ebuild

[gentoo-commits] gentoo-x86 commit in sys-fs/cryptsetup: ChangeLog cryptsetup-1.0.7.ebuild

[Robin H. Johnson (robbat2)]

robbat2     09/11/28 00:32:54

  Modified:             ChangeLog
  Added:                cryptsetup-1.0.7.ebuild
  Log:
  Version bump per bug #277990.
  (Portage version: 2.2_rc51/cvs/Linux x86_64)

Revision  Changes    Path
1.77                 sys-fs/cryptsetup/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -p -w -b -B -u -u -r1.76 -r1.77
--- ChangeLog	31 Aug 2009 15:05:29 -0000	1.76
+++ ChangeLog	28 Nov 2009 00:32:54 -0000	1.77
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/cryptsetup
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v 1.76 2009/08/31 15:05:29 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v 1.77 2009/11/28 00:32:54 robbat2 Exp $
+
+*cryptsetup-1.0.7 (28 Nov 2009)
+
+  28 Nov 2009; Robin H. Johnson <robbat2@gentoo.org>
+  +cryptsetup-1.0.7.ebuild:
+  Version bump per bug #277990.
 
   31 Aug 2009; Raúl Porcel <armin76@gentoo.org> cryptsetup-1.0.6-r2.ebuild:
   arm/ia64/s390/sh/sparc stable wrt #259253



1.1                  sys-fs/cryptsetup/cryptsetup-1.0.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.0.7.ebuild?rev=1.1&content-type=text/plain

Index: cryptsetup-1.0.7.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.0.7.ebuild,v 1.1 2009/11/28 00:32:54 robbat2 Exp $

EAPI=2

inherit linux-info eutils flag-o-matic multilib

DESCRIPTION="Tool to setup encrypted devices with dm-crypt"
HOMEPAGE="http://luks.endorphin.org/ http://code.google.com/p/cryptsetup/"
SRC_URI="http://cryptsetup.googlecode.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="dynamic nls selinux"

DEPEND="|| (
		>=sys-fs/lvm2-2.02.45
		>=sys-fs/device-mapper-1.00.07-r1
	)
	>=dev-libs/libgcrypt-1.1.42
	>=dev-libs/libgpg-error-1.0-r1
	>=dev-libs/popt-1.7
	>=sys-fs/udev-124
	|| ( >=sys-libs/e2fsprogs-libs-1.41 <sys-fs/e2fsprogs-1.41 )
	selinux? ( sys-libs/libselinux )
	!sys-fs/cryptsetup-luks"

dm-crypt_check() {
	local CONFIG_CHECK="~DM_CRYPT"
	local WARNING_DM_CRYPT="CONFIG_DM_CRYPT:\tis not set (required for cryptsetup)\n"
	check_extra_config
}

crypto_check() {
	local CONFIG_CHECK="~CRYPTO"
	local WARNING_CRYPTO="CONFIG_CRYPTO:\tis not set (required for cryptsetup)\n"
	check_extra_config
}

cbc_check() {
	local CONFIG_CHECK="~CRYPTO_CBC"
	local WARNING_CRYPTO_CBC="CONFIG_CRYPTO_CBC:\tis not set (required for kernel 2.6.19)\n"
	check_extra_config
}

pkg_setup() {
	dm-crypt_check
	crypto_check
	cbc_check

	if use dynamic ; then
		ewarn "If you need cryptsetup for an initrd or initramfs then you"
		ewarn "should NOT use the dynamic USE flag"
		epause 5
	fi
}

src_configure() {
	use selinux || export ac_cv_lib_selinux_is_selinux_enabled=no
	econf \
		--sbindir=/sbin \
		$(use_enable !dynamic static) \
		--enable-libgcrypt \
		--enable-libdevmapper \
		--libdir=/usr/$(get_libdir) \
		$(use_enable nls) \
		|| die
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	rmdir "${D}"/usr/$(get_libdir)/cryptsetup
	insinto /$(get_libdir)/rcscripts/addons
	newins "${FILESDIR}"/1.0.6-r2-dm-crypt-start.sh dm-crypt-start.sh || die
	newins "${FILESDIR}"/1.0.5-dm-crypt-stop.sh dm-crypt-stop.sh || die
	newconfd "${FILESDIR}"/1.0.6-dmcrypt.confd dmcrypt || die
	newinitd "${FILESDIR}"/1.0.5-dmcrypt.rc dmcrypt || die
}

pkg_postinst() {
	ewarn "This ebuild introduces a new set of scripts and configuration"
	ewarn "than the last version. If you are currently using /etc/conf.d/cryptfs"
	ewarn "then you *MUST* copy your old file to:"
	ewarn "/etc/conf.d/dmcrypt"
	ewarn "Or your encrypted partitions will *NOT* work."
	elog "Please see the example for configuring a LUKS mountpoint"
	elog "in /etc/conf.d/dmcrypt"
	elog
	elog "If you are using baselayout-2 then please do:"
	elog "rc-update add dmcrypt boot"
	elog "This version introduces a command line arguement 'key_timeout'."
	elog "If you want the search for the removable key device to timeout"
	elog "after 10 seconds add the following to your bootloader config:"
	elog "key_timeout=10"
	elog "A timeout of 0 will mean it will wait indefinitely."
}