[gentoo-commits] gentoo-x86 commit in www-apache/mod_httpbl: metadata.xml ChangeLog mod_httpbl-1.5.ebuild

[gentoo-commits] gentoo-x86 commit in www-apache/mod_httpbl: metadata.xml ChangeLog mod_httpbl-1.5.ebuild

[Diego Petteno (flameeyes)]

flameeyes    09/11/26 10:37:09

  Added:                metadata.xml ChangeLog mod_httpbl-1.5.ebuild
  Log:
  Initial import of mod_httpbl that allows using Project Honey Pot's blacklist to filter HTTP requests.
  (Portage version: 2.2_rc51/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  www-apache/mod_httpbl/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>apache</herd>
  <maintainer>
    <email>flameeyes@gentoo.org</email>
    <name>Diego E. Pettenò</name>
  </maintainer>
</pkgmetadata>



1.1                  www-apache/mod_httpbl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for www-apache/mod_httpbl
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/ChangeLog,v 1.1 2009/11/26 10:37:09 flameeyes Exp $

*mod_httpbl-1.5 (26 Nov 2009)

  26 Nov 2009; Diego E. Pettenò <flameeyes@gentoo.org>
  +files/99_mod_httpbl.conf, +mod_httpbl-1.5.ebuild, +metadata.xml:
  Initial import of mod_httpbl that allows using Project Honey Pot's
  blacklist to filter HTTP requests.




1.1                  www-apache/mod_httpbl/mod_httpbl-1.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5.ebuild?rev=1.1&content-type=text/plain

Index: mod_httpbl-1.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5.ebuild,v 1.1 2009/11/26 10:37:09 flameeyes Exp $

EAPI=2

inherit apache-module

DESCRIPTION="http:BL implementation for Apache 2"
HOMEPAGE="http://www.projecthoneypot.org/httpbl_download.php"
SRC_URI="http://httpbl.cvs.sourceforge.net/viewvc/*checkout*/httpbl/mod_httpbl_for_apache_2.0/mod_httpbl_source/mod_httpbl.c?revision=${PV} -> ${P}.c"

LICENSE="GPL-2"
SLOT="0"
IUSE=""

KEYWORDS="~amd64"

S=${WORKDIR}

APACHE2_MOD_FILE=".libs/${PN}.so"
APACHE2_MOD_CONF="99_mod_httpbl"
APACHE2_MOD_DEFINE="HTTPBL"

need_apache2

# We have to copy the file in the work directory because otherwise
# apxs will try to build it within distdir (which is luckily read
# only).
src_unpack() {
	cp "${DISTDIR}"/${P}.c ${PN}.c || die
}

src_compile() {
	APXS_FLAGS=
	for flag in ${CFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wc,${flag}"
	done

	# Yes we need to prefix it _twice_
	for flag in ${LDFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wl,${flag}"
	done

	${APXS} -c ${APXS_FLAGS} ${PN}.c || die
}

src_install() {
	apache-module_src_install

	keepdir /var/log/apache2/httpbl
	fowners apache:apache /var/log/apache2/httpbl || die
	fperms 0770 /var/log/apache2/httpbl || die

	keepdir /var/cache/mod_httpbl || die
	fowners apache:apache /var/cache/mod_httpbl || die
	fperms 0770 /var/cache/mod_httpbl || die
}

pkg_postinst() {
	apache-module_pkg_postinst

	elog "To use http:BL you will need the API key from Project Honey Pot"
	elog "that you can receive being an active member."
	elog "See ${HOMEPAGE} for details."
	elog ""
	elog "By default all requests are filtered with the blacklist, you probably"
	elog "want to restrict that to virtual hosts where actual applications are"
	elog "running and/or on possibly vulnerable locations."
}