[gentoo-commits] gentoo-x86 commit in app-dicts/opendict: ChangeLog opendict-0.6.3.ebuild

["Ryan Hill (dirtyepic)" <dirtyepic@gentoo.org>]

dirtyepic    09/11/23 00:22:02

  Modified:             ChangeLog
  Added:                opendict-0.6.3.ebuild
  Log:
  Version bump. Require wxpython:2.8. Keyword ~amd64.
  (Portage version: 2.2_rc51/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 app-dicts/opendict/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-dicts/opendict/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-dicts/opendict/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-dicts/opendict/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-dicts/opendict/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	29 May 2008 15:33:19 -0000	1.16
+++ ChangeLog	23 Nov 2009 00:22:01 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for app-dicts/opendict
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-dicts/opendict/ChangeLog,v 1.16 2008/05/29 15:33:19 hawking Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-dicts/opendict/ChangeLog,v 1.17 2009/11/23 00:22:01 dirtyepic Exp $
+
+*opendict-0.6.3 (23 Nov 2009)
+
+  23 Nov 2009; Ryan Hill <dirtyepic@gentoo.org> +opendict-0.6.3.ebuild:
+  Version bump. Require wxpython:2.8. Keyword ~amd64.
 
   29 May 2008; Ali Polatel <hawking@gentoo.org> opendict-0.6.1.ebuild:
   python_mod_optimize is ROOT aware. Fixed python_mod_cleanup.



1.1                  app-dicts/opendict/opendict-0.6.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-dicts/opendict/opendict-0.6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-dicts/opendict/opendict-0.6.3.ebuild?rev=1.1&content-type=text/plain

Index: opendict-0.6.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-dicts/opendict/opendict-0.6.3.ebuild,v 1.1 2009/11/23 00:22:01 dirtyepic Exp $

EAPI=2

inherit eutils python gnome2

DESCRIPTION="OpenDict is a free cross-platform dictionary program."
HOMEPAGE="http://opendict.sourceforge.net/"
SRC_URI="http://opendict.idiles.com/files/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=">=virtual/python-2.3
	dev-python/wxpython:2.8
	dev-python/pyxml"

src_prepare() {
	#epatch "${FILESDIR}/${PN}-0.6.1-desktop.patch"
	sed -e "s:), '..')):), '../../../../..', 'share', 'opendict')):g" \
		-i "${S}/lib/info.py"
}

src_configure() {
	:
}

src_compile() {
	:
}

src_install() {
	python_version
	DHOME="/usr/lib/python${PYVER}/site-packages/opendict"

	dodir /usr/share/${PN}/dictionaries/plugins # global dictionary plugins folder

	# Needed by GUI
	insinto /usr/share/${PN}
	doins "${S}"/copying.html

	insinto "${DHOME}/lib"
	doins -r "${S}"/lib/*

	insinto /usr/share/${PN}/pixmaps
	doins "${S}"/pixmaps/*

	exeinto "${DHOME}"
	doexe opendict.py

	dosym "${DHOME}/opendict.py" /usr/bin/opendict

	domenu misc/${PN}.desktop

	insinto /usr/share/icons/hicolor/24x24/apps/
	newins "${S}/pixmaps/icon-24x24.png" opendict.png
	insinto /usr/share/icons/hicolor/32x32/apps/
	newins "${S}/pixmaps/icon-32x32.png" opendict.png
	insinto /usr/share/icons/hicolor/48x48/apps/
	newins "${S}/pixmaps/icon-48x48.png" opendict.png
	insinto /usr/share/icons/hicolor/scalable/apps/
	newins "${S}/pixmaps/SVG/icon-rune.svg" opendict.svg

	doman opendict.1
	dodoc README.txt TODO.txt doc/Plugin-HOWTO.html
}

pkg_postinst() {
	python_mod_optimize \
		/usr/$(get_libdir)/python${PYVER}/site-packages/opendict
	gnome2_icon_cache_update

	elog "If you want system-wide plugins, unzip them into"
	elog "${ROOT}usr/share/${PN}/dictionaries/plugins"
	elog "Some are available from http://opendict.sourceforge.net/?cid=3"
}

pkg_postrm() {
	python_mod_cleanup
	gnome2_icon_cache_update
}