[gentoo-commits] gentoo-x86 commit in sci-geosciences/qgis: metadata.xml ChangeLog qgis-1.3.0.ebuild

[gentoo-commits] gentoo-x86 commit in sci-geosciences/qgis: metadata.xml ChangeLog qgis-1.3.0.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    09/11/21 20:08:39

  Added:                metadata.xml ChangeLog qgis-1.3.0.ebuild
  Log:
  Initial import. Thanks everyone in bug #56262
  (Portage version: 2.2_rc50/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sci-geosciences/qgis/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sci-geosciences</herd>
<longdescription lang='en'>
  Quantum GIS (QGIS) is a user friendly Open Source Geographic
  Information System (GIS). QGIS supports vector, raster, and database
  formats. QGIS lets you browse and create map data on your
  computer. It supports many common spatial data formats (e.g. ESRI
  ShapeFile, geotiff). QGIS supports plugins to do things like display
  tracks from your GPS. 
</longdescription>
<use>
  <flag name="grass">Add support for <pkg>sci-geosciences/grass</pkg></flag>
</use>
</pkgmetadata>




1.1                  sci-geosciences/qgis/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sci-geosciences/qgis
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/qgis/ChangeLog,v 1.1 2009/11/21 20:08:39 bicatali Exp $

*qgis-1.3.0 (21 Nov 2009)

  21 Nov 2009; Sébastien Fabbro <bicatali@gentoo.org> +qgis-1.3.0.ebuild,
  +files/qgis-1.3.0-sip.patch, +metadata.xml:
  Initial import. Thanks everyone in bug #56262




1.1                  sci-geosciences/qgis/qgis-1.3.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/qgis-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-geosciences/qgis/qgis-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: qgis-1.3.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/qgis/qgis-1.3.0.ebuild,v 1.1 2009/11/21 20:08:39 bicatali Exp $

EAPI="2"

inherit cmake-utils eutils

DESCRIPTION="User friendly Geographic Information System"
HOMEPAGE="http://www.qgis.org/"
SRC_URI="http://download.osgeo.org/${PN}/src/${PN}_${PV}.tar.gz
	examples? ( http://download.osgeo.org/${PN}/data/${PN}_sample_data.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples gps grass gsl postgres python sqlite"

RDEPEND=">=sci-libs/gdal-1.6.1
	x11-libs/qt-core:4[qt3support]
	x11-libs/qt-gui:4
	x11-libs/qt-svg:4
	x11-libs/qt-sql:4
	sci-libs/geos
	sci-libs/proj
	gps? ( dev-libs/expat sci-geosciences/gpsbabel )
	grass? ( >=sci-geosciences/grass-6 sci-geosciences/gdal-grass )
	gsl? ( sci-libs/gsl )
	postgres? ( >=virtual/postgresql-base-8 dev-db/postgis )
	python? ( dev-python/PyQt4[sql,svg] )
	sqlite? ( dev-db/sqlite:3 )"

DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex"

src_prepare() {
	# patch to wor with all versions of sip, taken from upstream trunk
	epatch "${FILESDIR}"/${P}-sip.patch
}

src_configure() {
	local mycmakeargs
	mycmakeargs="${mycmakeargs}
		-D BUILD_SHARED_LIBS:BOOL=ON
		-D BINDINGS_GLOBAL_INSTALL:BOOL=ON
		-D QGIS_LIB_SUBDIR=/usr/$(get_libdir)
		-D QGIS_PLUGIN_SUBDIR=/usr/$(get_libdir)/qgis
		$(cmake-utils_use_with postgres POSTGRESQL)
		$(cmake-utils_use_with grass GRASS)
		$(cmake-utils_use_with gps EXPAT)
		$(cmake-utils_use_with gsl GSL)
		$(cmake-utils_use_with python BINDINGS)
		$(cmake-utils_use_with sqlite SPATIALITE)"

	if use grass; then
		GRASS_ENVD="/etc/env.d/99grass /etc/env.d/99grass-6 /etc/env.d/99grass-cvs";
		for file in ${GRASS_ENVD}; do
			if test -r ${file}; then
				GRASSPATH=$(sed -n 's/LDPATH="\(.*\)\/lib"$/\1/p' ${file});
			fi
		done
		mycmakeargs="${mycmakeargs} -DGRASS_PREFIX=${GRASSPATH}"
	fi
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS BUGS ChangeLog README SPONSORS CONTRIBUTORS

	newicon images/icons/qgis-icon.png qgis.png
	make_desktop_entry qgis "Quantum GIS " qgis.png

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins "${WORKDIR}"/qgis_sample_data/* || die "Unable to install examples"
	fi
}