From: "Diego Petteno (flameeyes)" <flameeyes@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-0.9.20.ebuild ChangeLog pulseaudio-0.9.20-r50.ebuild
Date: Sun, 15 Nov 2009 19:05:00 +0000 [thread overview]
Message-ID: <E1N9kPE-0006vw-GQ@stork.gentoo.org> (raw)
flameeyes 09/11/15 19:05:00
Modified: ChangeLog
Added: pulseaudio-0.9.20.ebuild
pulseaudio-0.9.20-r50.ebuild
Log:
Version bump. Closes bug #293059.
(Portage version: 2.2_rc49/cvs/Linux x86_64)
Revision Changes Path
1.174 media-sound/pulseaudio/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.173&r2=1.174
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog 20 Oct 2009 13:34:12 -0000 1.173
+++ ChangeLog 15 Nov 2009 19:05:00 -0000 1.174
@@ -1,6 +1,13 @@
# ChangeLog for media-sound/pulseaudio
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.173 2009/10/20 13:34:12 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.174 2009/11/15 19:05:00 flameeyes Exp $
+
+*pulseaudio-0.9.20-r50 (15 Nov 2009)
+*pulseaudio-0.9.20 (15 Nov 2009)
+
+ 15 Nov 2009; Diego E. Pettenò <flameeyes@gentoo.org>
+ +pulseaudio-0.9.20.ebuild, +pulseaudio-0.9.20-r50.ebuild:
+ Version bump. Closes bug #293059.
*pulseaudio-0.9.19-r51 (20 Oct 2009)
*pulseaudio-0.9.19-r1 (20 Oct 2009)
1.1 media-sound/pulseaudio/pulseaudio-0.9.20.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20.ebuild?rev=1.1&content-type=text/plain
Index: pulseaudio-0.9.20.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20.ebuild,v 1.1 2009/11/15 19:05:00 flameeyes Exp $
EAPI=2
inherit eutils libtool flag-o-matic
DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
if [[ ${PV/_rc/} == ${PV} ]]; then
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
else
SRC_URI="http://0pointer.de/public/${P/_rc/-test}.tar.gz"
fi
S="${WORKDIR}/${P/_rc/-test}"
LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="+alsa avahi +caps jack lirc oss tcpd +X hal dbus libsamplerate gnome bluetooth +asyncns +glib test doc +udev ipv6"
RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE x11-libs/libXtst )
caps? ( sys-libs/libcap )
libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
alsa? ( >=media-libs/alsa-lib-1.0.19 )
glib? ( >=dev-libs/glib-2.4.0 )
avahi? ( >=net-dns/avahi-0.6.12[dbus] )
>=dev-libs/liboil-0.3.0
jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
tcpd? ( sys-apps/tcp-wrappers )
lirc? ( app-misc/lirc )
dbus? ( >=sys-apps/dbus-1.0.0 )
gnome? ( >=gnome-base/gconf-2.4.0 )
hal? (
>=sys-apps/hal-0.5.11
>=sys-apps/dbus-1.0.0
)
app-admin/eselect-esd
bluetooth? (
|| ( >=net-wireless/bluez-4
>=net-wireless/bluez-libs-3 )
>=sys-apps/dbus-1.0.0
)
asyncns? ( net-libs/libasyncns )
udev? ( >=sys-fs/udev-143[extras] )
>=media-libs/audiofile-0.2.6-r1
>=media-libs/speex-1.2_beta
>=media-libs/libsndfile-1.0.20
>=dev-libs/liboil-0.3.6
sys-libs/gdbm
>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
X? (
x11-proto/xproto
|| ( >=x11-libs/libXtst-1.0.99.2 <x11-proto/xextproto-7.0.99 )
)
dev-libs/libatomic_ops
dev-util/pkgconfig
dev-util/intltool"
RDEPEND="${RDEPEND}
gnome-extra/gnome-audio"
pkg_setup() {
enewgroup audio 18 # Just make sure it exists
enewgroup realtime
enewgroup pulse-access
enewgroup pulse
enewuser pulse -1 -1 /var/run/pulse pulse,audio
if use udev && use hal; then
elog "Please note that enabling both udev and hal will build both"
elog "discover modules, but only udev will be used automatically."
elog "If you wish to use hal you have to enable it explicitly"
elog "or you might just disable the hal USE flag entirely."
fi
}
src_prepare() {
elibtoolize
}
src_configure() {
# It's a binutils bug, once I can find time to fix that I'll add a
# proper dependency and fix this up. — flameeyes
append-ldflags $(no-as-needed)
econf \
--enable-largefile \
$(use_enable glib glib2) \
--disable-solaris \
$(use_enable asyncns) \
$(use_enable oss oss-output) \
$(use_enable alsa) \
$(use_enable lirc) \
$(use_enable tcpd tcpwrap) \
$(use_enable jack) \
$(use_enable lirc) \
$(use_enable avahi) \
$(use_enable hal) \
$(use_enable dbus) \
$(use_enable gnome gconf) \
$(use_enable libsamplerate samplerate) \
$(use_enable bluetooth bluez) \
$(use_enable X x11) \
$(use_enable test default-build-tests) \
$(use_enable udev) \
$(use_enable ipv6) \
$(use_with caps) \
--localstatedir=/var \
--with-realtime-group=realtime \
--disable-per-user-esound-socket \
|| die "econf failed"
if use doc; then
pushd doxygen
doxygen doxygen.conf || die
popd
fi
}
src_test() {
# We avoid running the toplevel check target because that will run
# po/'s tests too, and they are broken. Officially, it should work
# with intltool 0.41, but that doesn't look like a stable release.
emake -C src check || die
}
src_install() {
emake DESTDIR="${D}" install || die "make install failed"
if use X; then
dodir /etc/X11/xinit/xinitrc.d
ln -s ../../../usr/bin/start-pulseaudio-x11 "${D}"/etc/X11/xinit/xinitrc.d/95-pulseaudio
else
# Drop the script entirely
rm "${D}"/usr/bin/start-pulseaudio-x11
fi
use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
if use hal && ! use udev; then
sed -i -e 's:-udev:-hal:' "${D}/etc/pulse/default.pa" || die
fi
dodoc README ChangeLog todo || die
if use doc; then
pushd doxygen/html
dohtml * || die
popd
fi
# Create the state directory
diropts -o pulse -g pulse -m0755
keepdir /var/run/pulse
find "${D}" -name '*.la' -delete
}
pkg_postinst() {
elog "If you want to make use of realtime capabilities of PulseAudio"
elog "you should follow the realtime guide to create and set up a realtime"
elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
elog "Make sure you also have baselayout installed with pam USE flag"
elog "enabled, if you're using the rlimit method."
if use bluetooth; then
elog
elog "The BlueTooth proximity module is not enabled in the default"
elog "configuration file. If you do enable it, you'll have to have"
elog "your BlueTooth controller enabled and inserted at bootup or"
elog "PulseAudio will refuse to start."
elog
elog "Please note that the BlueTooth proximity module seems itself"
elog "still experimental, so please report to upstream if you have"
elog "problems with it."
fi
if use alsa &&
has_version media-plugins/alsa-plugins &&
!built_with_use --missing false media-plugins/alsa-plugins pulseaudio; then
elog
elog "You have alsa support enabled so you probably want to install"
elog "${pkg} with pulseaudio support to have"
elog "alsa using applications route their sound through pulseaudio"
fi
eselect esd update --if-unset
}
1.1 media-sound/pulseaudio/pulseaudio-0.9.20-r50.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20-r50.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20-r50.ebuild?rev=1.1&content-type=text/plain
Index: pulseaudio-0.9.20-r50.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.20-r50.ebuild,v 1.1 2009/11/15 19:05:00 flameeyes Exp $
EAPI=2
inherit eutils libtool flag-o-matic
DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
if [[ ${PV/_rc/} == ${PV} ]]; then
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
else
SRC_URI="http://0pointer.de/public/${P/_rc/-test}.tar.gz"
fi
S="${WORKDIR}/${P/_rc/-test}"
LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="+alsa avahi +caps jack lirc oss tcpd +X hal dbus libsamplerate gnome bluetooth +asyncns +glib test doc +udev ipv6"
RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE x11-libs/libXtst )
caps? ( sys-libs/libcap )
libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
alsa? ( >=media-libs/alsa-lib-1.0.19 )
glib? ( >=dev-libs/glib-2.4.0 )
avahi? ( >=net-dns/avahi-0.6.12[dbus] )
>=dev-libs/liboil-0.3.0
jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
tcpd? ( sys-apps/tcp-wrappers )
lirc? ( app-misc/lirc )
dbus? ( >=sys-apps/dbus-1.0.0 )
gnome? ( >=gnome-base/gconf-2.4.0 )
hal? (
>=sys-apps/hal-0.5.11
>=sys-apps/dbus-1.0.0
)
app-admin/eselect-esd
bluetooth? (
|| ( >=net-wireless/bluez-4
>=net-wireless/bluez-libs-3 )
>=sys-apps/dbus-1.0.0
)
asyncns? ( net-libs/libasyncns )
udev? ( >=sys-fs/udev-143[extras] )
>=media-libs/audiofile-0.2.6-r1
>=media-libs/speex-1.2_beta
>=media-libs/libsndfile-1.0.20
>=dev-libs/liboil-0.3.6
sys-libs/gdbm
>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
X? (
x11-proto/xproto
|| ( >=x11-libs/libXtst-1.0.99.2 <x11-proto/xextproto-7.0.99 )
)
dev-libs/libatomic_ops
dev-util/pkgconfig
|| ( dev-util/unifdef sys-freebsd/freebsd-ubin )
dev-util/intltool"
# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez-utils dep is for the bluetooth init.d script
RDEPEND="${RDEPEND}
sys-apps/openrc
gnome-extra/gnome-audio
alsa? ( media-sound/alsa-utils )
bluetooth? (
|| ( >=net-wireless/bluez-4
>=net-wireless/bluez-utils-3 ) )"
pkg_setup() {
enewgroup audio 18 # Just make sure it exists
enewgroup pulse-access
enewgroup pulse
enewuser pulse -1 -1 /var/run/pulse pulse,audio
if use udev && use hal; then
elog "Please note that enabling both udev and hal will build both"
elog "discover modules, but only udev will be used automatically."
elog "If you wish to use hal you have to enable it explicitly"
elog "or you might just disable the hal USE flag entirely."
fi
}
src_prepare() {
elibtoolize
}
src_configure() {
# It's a binutils bug, once I can find time to fix that I'll add a
# proper dependency and fix this up. — flameeyes
append-ldflags $(no-as-needed)
econf \
--enable-largefile \
$(use_enable glib glib2) \
--disable-solaris \
$(use_enable asyncns) \
$(use_enable oss oss-output) \
$(use_enable alsa) \
$(use_enable lirc) \
$(use_enable tcpd tcpwrap) \
$(use_enable jack) \
$(use_enable lirc) \
$(use_enable avahi) \
$(use_enable hal) \
$(use_enable dbus) \
$(use_enable gnome gconf) \
$(use_enable libsamplerate samplerate) \
$(use_enable bluetooth bluez) \
$(use_enable X x11) \
$(use_enable test default-build-tests) \
$(use_enable udev) \
$(use_enable ipv6) \
$(use_with caps) \
--localstatedir=/var \
--disable-per-user-esound-socket \
--with-database=gdbm \
|| die "econf failed"
if use doc; then
pushd doxygen
doxygen doxygen.conf || die
popd
fi
}
src_test() {
# We avoid running the toplevel check target because that will run
# po/'s tests too, and they are broken. Officially, it should work
# with intltool 0.41, but that doesn't look like a stable release.
emake -C src check || die
}
src_install() {
emake -j1 DESTDIR="${D}" install || die "make install failed"
if use X; then
dodir /etc/X11/xinit/xinitrc.d
ln -s ../../../usr/bin/start-pulseaudio-x11 "${D}"/etc/X11/xinit/xinitrc.d/95-pulseaudio
else
# Drop the script entirely
rm "${D}"/usr/bin/start-pulseaudio-x11
fi
newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
use_define() {
local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
use "$1" && echo "-D$define" || echo "-U$define"
}
unifdef $(use_define hal) \
$(use_define avahi) \
$(use_define alsa) \
$(use_define bluetooth) \
$(use_define udev) \
"${FILESDIR}/pulseaudio.init.d-4" \
> "${T}/pulseaudio"
doinitd "${T}/pulseaudio"
use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
if use hal && ! use udev; then
sed -i -e 's:-udev:-hal:' "${D}/etc/pulse/default.pa" || die
fi
dodoc README ChangeLog todo || die
if use doc; then
pushd doxygen/html
dohtml * || die
popd
fi
# Create the state directory
diropts -o pulse -g pulse -m0755
keepdir /var/run/pulse
find "${D}" -name '*.la' -delete
}
pkg_postinst() {
elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
elog "This support is enabled by starting the pulseaudio init.d ."
elog "To be able to access that you need to be in the group pulse-access."
elog "If you choose to use this feature, please make sure that you"
elog "really want to run PulseAudio this way:"
elog " http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
elog "For more information about system-wide support, please refer to:"
elog " http://pulseaudio.org/wiki/SystemWideInstance"
if use gnome; then
elog
elog "By enabling gnome USE flag, you enabled gconf support. Please note"
elog "that you might need to remove the gnome USE flag or disable the"
elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
elog "with a system-wide instance."
fi
elog
elog "To use the ESounD wrapper while using a system-wide daemon, you also"
elog "need to enable auth-anonymous for the esound-unix module, or to copy"
elog "/var/run/pulse/.esd_auth into each home directory."
elog
if use bluetooth; then
elog
elog "The BlueTooth proximity module is not enabled in the default"
elog "configuration file. If you do enable it, you'll have to have"
elog "your BlueTooth controller enabled and inserted at bootup or"
elog "PulseAudio will refuse to start."
elog
elog "Please note that the BlueTooth proximity module seems itself"
elog "still experimental, so please report to upstream if you have"
elog "problems with it."
fi
if use alsa; then
local pkg="media-plugins/alsa-plugins"
if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
elog
elog "You have alsa support enabled so you probably want to install"
elog "${pkg} with pulseaudio support to have"
elog "alsa using applications route their sound through pulseaudio"
fi
fi
eselect esd update --if-unset
}
reply other threads:[~2009-11-15 19:05 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=E1N9kPE-0006vw-GQ@stork.gentoo.org \
--to=flameeyes@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox