[gentoo-commits] gentoo-x86 commit in app-editors/gedit: ChangeLog gedit-2.28.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/gedit: ChangeLog gedit-2.28.1.ebuild

[Romain Perier (mrpouet)]

mrpouet     09/11/11 16:55:04

  Modified:             ChangeLog
  Added:                gedit-2.28.1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc49/cvs/Linux x86_64)

Revision  Changes    Path
1.284                app-editors/gedit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.284&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.284&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?r1=1.283&r2=1.284

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v
retrieving revision 1.283
retrieving revision 1.284
diff -u -r1.283 -r1.284
--- ChangeLog	5 Nov 2009 20:28:17 -0000	1.283
+++ ChangeLog	11 Nov 2009 16:55:04 -0000	1.284
@@ -1,6 +1,13 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.283 2009/11/05 20:28:17 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.284 2009/11/11 16:55:04 mrpouet Exp $
+
+*gedit-2.28.1 (11 Nov 2009)
+
+  11 Nov 2009; Romain Perier <mrpouet@gentoo.org>
+  +gedit-2.28.1.ebuild:
+  Version bump. Fix regressions in the External Tools plugin,
+  Misc bugfixes.
 
   05 Nov 2009; Markus Meier <maekke@gentoo.org> gedit-2.26.3.ebuild:
   arm stable, bug #281427



1.1                  app-editors/gedit/gedit-2.28.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.28.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.28.1.ebuild?rev=1.1&content-type=text/plain

Index: gedit-2.28.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.28.1.ebuild,v 1.1 2009/11/11 16:55:04 mrpouet Exp $

GCONF_DEBUG="no"

inherit gnome2 python

DESCRIPTION="A text editor for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc python spell xattr"

RDEPEND=">=gnome-base/gconf-2
	xattr? ( sys-apps/attr )
	>=x11-libs/libSM-1.0
	>=dev-libs/libxml2-2.5.0
	>=dev-libs/glib-2.18
	>=x11-libs/gtk+-2.17.1
	>=x11-libs/gtksourceview-2.5
	spell? (
		>=app-text/enchant-1.2
		>=app-text/iso-codes-0.35
	)
	python? (
		>=dev-python/pygobject-2.15.4
		>=dev-python/pygtk-2.12
		>=dev-python/pygtksourceview-2.2
	)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.40
	>=dev-util/pkgconfig-0.9
	>=app-text/scrollkeeper-0.3.11
	>=app-text/gnome-doc-utils-0.3.2
	~app-text/docbook-xml-dtd-4.1.2
	doc? ( >=dev-util/gtk-doc-1 )"
# gnome-common and gtk-doc-am needed to eautoreconf

DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"

if [[ "${ARCH}" == "PPC" ]] ; then
	# HACK HACK HACK: someone fix this garbage
	MAKEOPTS="${MAKEOPTS} -j1"
fi

pkg_setup() {
	# Installed for plugins, but they're dlopen()-ed
	G2PUNT_LA="yes"

	G2CONF="${G2CONF}
		--disable-scrollkeeper
		--disable-updater
		$(use_enable python)
		$(use_enable spell)
		$(use_enable xattr attr)"
}

src_unpack() {
	gnome2_src_unpack

	# disable pyc compiling
	mv "${S}"/py-compile "${S}"/py-compile.orig
	ln -s $(type -P true) "${S}"/py-compile
}

src_install() {
	gnome2_src_install
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	use python && python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
}