[gentoo-commits] gentoo-x86 commit in net-im/mcabber: ChangeLog mcabber-0.9.10.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/mcabber: ChangeLog mcabber-0.9.10.ebuild

[Wolfram Schlich (wschlich)]

wschlich    09/11/05 07:47:04

  Modified:             ChangeLog
  Added:                mcabber-0.9.10.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc33/cvs/Linux i686)

Revision  Changes    Path
1.48                 net-im/mcabber/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/mcabber/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/mcabber/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/mcabber/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/mcabber/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	30 Sep 2009 17:32:23 -0000	1.47
+++ ChangeLog	5 Nov 2009 07:47:04 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/mcabber
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/mcabber/ChangeLog,v 1.47 2009/09/30 17:32:23 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/mcabber/ChangeLog,v 1.48 2009/11/05 07:47:04 wschlich Exp $
+
+*mcabber-0.9.10 (04 Nov 2009)
+
+  04 Nov 2009; Wolfram Schlich <wschlich@gentoo.org> +mcabber-0.9.10.ebuild:
+  version bump
 
   30 Sep 2009; Raúl Porcel <armin76@gentoo.org> mcabber-0.9.9-r1.ebuild:
   sparc stable wrt #281836



1.1                  net-im/mcabber/mcabber-0.9.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/mcabber/mcabber-0.9.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/mcabber/mcabber-0.9.10.ebuild?rev=1.1&content-type=text/plain

Index: mcabber-0.9.10.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/mcabber/mcabber-0.9.10.ebuild,v 1.1 2009/11/05 07:47:04 wschlich Exp $

inherit flag-o-matic

DESCRIPTION="A small Jabber console client with various features, like MUC, SSL, PGP"
HOMEPAGE="http://mcabber.com/"
SRC_URI="http://mcabber.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86"

IUSE="crypt otr spell ssl"

LANGS="de en fr nl pl uk ru"
# localized help versions are installed only, when LINGUAS var is set
for i in ${LANGS}; do
	IUSE="${IUSE} linguas_${i}"
done;

RDEPEND="ssl? ( >=dev-libs/openssl-0.9.7-r1 )
	crypt? ( >=app-crypt/gpgme-1.0.0 )
	otr? ( >=net-libs/libotr-3.1.0 )
	spell? ( app-text/aspell )
	>=dev-libs/glib-2.0.0
	sys-libs/ncurses"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_compile() {
	use crypt && append-flags -D_FILE_OFFSET_BITS=64 # bug #277888
	econf \
		$(use_enable crypt gpgme) \
		$(use_enable otr) \
		$(use_enable spell aspell) \
		$(use_with ssl) \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	make install DESTDIR="${D}" || die "make install failed"
	# clean unneeded language documentation
	for i in ${LANGS}; do
		! use linguas_${i} && rm -rf "${D}"/usr/share/${PN}/help/${i}
	done

	dodoc AUTHORS ChangeLog NEWS README TODO mcabberrc.example
	dodoc doc/README_PGP.txt

	# contrib themes
	insinto /usr/share/${PN}/themes
	doins "${S}"/contrib/themes/*

	# contrib generic scripts
	exeinto /usr/share/${PN}/scripts
	doexe "${S}"/contrib/*.{pl,py,rb}

	# contrib event scripts
	exeinto /usr/share/${PN}/scripts/events
	doexe "${S}"/contrib/events/*
}

pkg_postinst() {
	elog
	elog "MCabber requires you to create a subdirectory .mcabber in your home"
	elog "directory and to place a configuration file there."
	elog "An example mcabberrc was installed as part of the documentation."
	elog "To create a new mcabberrc based on the example mcabberrc, execute the"
	elog "following commands:"
	elog
	elog "  mkdir -p ~/.mcabber"
	elog "  bzcat ${ROOT}usr/share/doc/${PF}/mcabberrc.example.bz2 >~/.mcabber/mcabberrc"
	elog
	elog "Then edit ~/.mcabber/mcabberrc with your favorite editor."
	elog
	elog "As of MCabber version 0.8.2, there is also a wizard script"
	elog "with which you can create all necessary configuration options."
	elog "To use it, simply execute the following command (please note that you need"
	elog "to have dev-lang/ruby installed for it to work!):"
	elog
	elog "  ${ROOT}usr/share/${PN}/scripts/mcwizz.rb"
	elog
	elog
	elog "See the CONFIGURATION FILE and FILES sections of the mcabber"
	elog "manual page (section 1) for more information."
	elog
	elog "From version 0.9.0 on, MCabber supports PGP encryption of messages."
	elog "See README_PGP.txt for details."
	elog
	elog "Check out ${ROOT}usr/share/${PN} for contributed themes and event scripts."
	elog
}