[gentoo-commits] gentoo-x86 commit in media-sound/sonic-visualiser: ChangeLog sonic-visualiser-1.7.1.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/sonic-visualiser: ChangeLog sonic-visualiser-1.7.1.ebuild

[Alexis Ballier (aballier)]

aballier    09/11/04 10:26:12

  Modified:             ChangeLog
  Added:                sonic-visualiser-1.7.1.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc48/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 media-sound/sonic-visualiser/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/sonic-visualiser/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	12 Oct 2009 07:53:08 -0000	1.16
+++ ChangeLog	4 Nov 2009 10:26:12 -0000	1.17
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/sonic-visualiser
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v 1.16 2009/10/12 07:53:08 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/ChangeLog,v 1.17 2009/11/04 10:26:12 aballier Exp $
+
+*sonic-visualiser-1.7.1 (04 Nov 2009)
+
+  04 Nov 2009; Alexis Ballier <aballier@gentoo.org>
+  +sonic-visualiser-1.7.1.ebuild,
+  +files/sonic-visualiser-1.7.1-liboggz11.patch:
+  version bump
 
 *sonic-visualiser-1.7 (12 Oct 2009)
 



1.1                  media-sound/sonic-visualiser/sonic-visualiser-1.7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: sonic-visualiser-1.7.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/sonic-visualiser/sonic-visualiser-1.7.1.ebuild,v 1.1 2009/11/04 10:26:12 aballier Exp $

EAPI=1

inherit eutils qt4

DESCRIPTION="Music audio files viewer and analiser"
HOMEPAGE="http://www.sonicvisualiser.org/"
SRC_URI="mirror://sourceforge/sv1/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="fftw id3tag jack mad ogg osc portaudio pulseaudio"

RDEPEND="x11-libs/qt-core:4
	x11-libs/qt-gui:4
	media-libs/libsndfile
	media-libs/libsamplerate
	fftw? ( =sci-libs/fftw-3* )
	app-arch/bzip2
	>=media-libs/dssi-0.9.1
	media-libs/raptor
	media-libs/liblrdf
	dev-libs/redland
	media-libs/ladspa-sdk
	osc? ( media-libs/liblo )
	media-libs/speex
	>=media-libs/vamp-plugin-sdk-2.0
	media-libs/rubberband
	jack? ( media-sound/jack-audio-connection-kit )
	!pulseaudio? ( !portaudio? ( media-sound/jack-audio-connection-kit ) )
	mad? ( media-libs/libmad )
	id3tag? ( media-libs/libid3tag )
	ogg? ( media-libs/libfishsound media-libs/liboggz )
	portaudio? ( >=media-libs/portaudio-19_pre20071207 )
	pulseaudio? ( media-sound/pulseaudio )"

DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.9"

pkg_setup() {
	use !jack && use !pulseaudio && use !portaudio && ewarn "You must have at least one of: jack, pulseaudio, portaudio enabled. We will enable jack for you."
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	# remove crap
	sed -i -e "s:-O3::" prf/sv.prf
	has_version '>=media-libs/liboggz-1.1.0' && epatch "${FILESDIR}/${P}-liboggz11.patch"
}

sv_disable_opt() {
	einfo "Disabling $1"
	sed -i -e "s/ $1//" "${S}/prf/sv.prf" || die "failed to remove $1 support"
}

src_compile() {
	(use jack || ( use !pulseaudio && use !portaudio)) || sv_disable_opt jack
	use ogg || sv_disable_opt fishsound
	use ogg || sv_disable_opt oggz
	use mad || sv_disable_opt mad
	use fftw || sv_disable_opt fftw3f
	use fftw || sv_disable_opt fftw3
	use id3tag || sv_disable_opt id3tag
	use pulseaudio || sv_disable_opt libpulse
	use portaudio || sv_disable_opt portaudio
	use osc || sv_disable_opt liblo

	eqmake4
	emake || die "Compilation failed"
}

src_install() {
	dobin sv/sonic-visualiser
	dodoc README README.OSC
	dodir /usr/share/${PN}
	#install samples
	insinto /usr/share/${PN}/samples
	doins sv/samples/*
	# desktop entry
	newicon "sv/icons/sv-48x48.png" "${PN}.png"
	make_desktop_entry "${PN}" "Sonic Visualiser" "${PN}"
}