[gentoo-commits] gentoo-x86 commit in dev-python/lxml: lxml-2.2.3.ebuild ChangeLog

["Arfrever Frehtes Taifersar Arahesis (arfrever)" <arfrever@gentoo.org>]

arfrever    09/10/30 21:11:36

  Modified:             ChangeLog
  Added:                lxml-2.2.3.ebuild
  Log:
  Version bump. Add dependency on dev-python/beautifulsoup (bug #285482).
  (Portage version: 14746-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.66                 dev-python/lxml/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	10 Oct 2009 17:35:47 -0000	1.65
+++ ChangeLog	30 Oct 2009 21:11:35 -0000	1.66
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/lxml
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.65 2009/10/10 17:35:47 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.66 2009/10/30 21:11:35 arfrever Exp $
+
+*lxml-2.2.3 (30 Oct 2009)
+
+  30 Oct 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +lxml-2.2.3.ebuild:
+  Version bump. Add dependency on dev-python/beautifulsoup (bug #285482).
 
   10 Oct 2009; Fabian Groffen <grobian@gentoo.org> lxml-2.2.2.ebuild:
   Merge from Prefix



1.1                  dev-python/lxml/lxml-2.2.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.2.3.ebuild?rev=1.1&content-type=text/plain

Index: lxml-2.2.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/lxml-2.2.3.ebuild,v 1.1 2009/10/30 21:11:35 arfrever Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils flag-o-matic

DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
HOMEPAGE="http://codespeak.net/lxml/ http://pypi.python.org/pypi/lxml"
SRC_URI="http://codespeak.net/lxml/${P}.tgz"

LICENSE="BSD ElementTree GPL-2 PSF-2.4"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE="doc examples +threads"

RDEPEND=">=dev-libs/libxml2-2.7.2
		>=dev-libs/libxslt-1.1.15
		dev-python/beautifulsoup"
DEPEND="${RDEPEND}
	>=dev-python/cython-0.9.8
	>=dev-python/setuptools-0.6_rc5"
RESTRICT_PYTHON_ABIS="3.*"

pkg_setup() {
	# Tests fail with some optimizations.
	replace-flags -O[2-9s]* -O1
}

src_prepare() {
	# Use Cython instead of own bundled version of Pyrex.
	epatch "${FILESDIR}/${PN}-2.0.3-no-fake-pyrex.patch"
}

src_compile() {
	local myconf
	use threads || myconf+=" --without-threading"
	distutils_src_compile ${myconf}
}

src_test() {
	testing() {
		local module
		for module in lxml/etree lxml/objectify; do
			ln -fs "../../$(ls -d build-${PYTHON_ABI}/lib.*)/${module}.so" "src/${module}.so" || die "ln -fs src/${module} failed"
		done

		einfo "Running test"
		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" test.py || die "test.py failed with Python ${PYTHON_ABI}"
		einfo "Running selftest"
		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" selftest.py || die "selftest.py failed with Python ${PYTHON_ABI}"
		einfo "Running selftest2"
		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" selftest2.py || die "selftest2.py failed with Python ${PYTHON_ABI}"
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml doc/html/*
		dodoc *.txt
		docinto doc
		dodoc doc/*.txt
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r samples/*
	fi
}