[gentoo-commits] gentoo-x86 commit in gnome-base/gvfs: metadata.xml ChangeLog gvfs-1.4.1.ebuild gvfs-1.2.2.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-base/gvfs: metadata.xml ChangeLog gvfs-1.4.1.ebuild gvfs-1.2.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/10/29 21:56:05

  Modified:             metadata.xml ChangeLog
  Added:                gvfs-1.4.1.ebuild
  Removed:              gvfs-1.2.2.ebuild
  Log:
  New version for GNOME 2.28. Clean up old revision.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  gnome-base/gvfs/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gvfs/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	22 Jul 2009 15:53:56 -0000	1.4
+++ metadata.xml	29 Oct 2009 21:56:04 -0000	1.5
@@ -14,6 +14,8 @@
 		transparently via <pkg>app-arch/libarchive</pkg></flag>
 	<flag name='fuse'>Enables fuse mount points in $HOME/.gvfs for legacy
 		application access</flag>
+	<flag name="gdu">Enable <pkg>sys-apps/gnome-disk-utility</pkg> integration</flag>
+	<flag name="udev">Enable udev base replacement code for cdda feature</flag>
 </use>
 </pkgmetadata>
 



1.82                 gnome-base/gvfs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	24 Oct 2009 16:49:34 -0000	1.81
+++ ChangeLog	29 Oct 2009 21:56:04 -0000	1.82
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/gvfs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.81 2009/10/24 16:49:34 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.82 2009/10/29 21:56:04 eva Exp $
+
+*gvfs-1.4.1 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org> -gvfs-1.2.2.ebuild,
+  +gvfs-1.4.1.ebuild, metadata.xml:
+  New version for GNOME 2.28. Clean up old revision.
 
   24 Oct 2009; nixnut <nixnut@gentoo.org> gvfs-1.2.3.ebuild:
   ppc stable #281427



1.1                  gnome-base/gvfs/gvfs-1.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/gvfs-1.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gvfs/gvfs-1.4.1.ebuild?rev=1.1&content-type=text/plain

Index: gvfs-1.4.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.4.1.ebuild,v 1.1 2009/10/29 21:56:04 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools bash-completion gnome2 eutils

DESCRIPTION="GNOME Virtual Filesystem Layer"
HOMEPAGE="http://www.gnome.org"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="archive avahi bluetooth cdda doc fuse gdu gnome gnome-keyring gphoto2 hal samba +udev"

RDEPEND=">=dev-libs/glib-2.21.2
	>=sys-apps/dbus-1.0
	>=net-libs/libsoup-2.25.1[gnome]
	dev-libs/libxml2
	net-misc/openssh
	>=sys-fs/udev-138
	archive? ( app-arch/libarchive )
	avahi? ( >=net-dns/avahi-0.6 )
	bluetooth? (
		dev-libs/dbus-glib
		net-wireless/bluez
		dev-libs/expat )
	fuse? ( sys-fs/fuse )
	gdu? ( >=sys-apps/gnome-disk-utility-2.28 )
	gnome? ( >=gnome-base/gconf-2.0 )
	gnome-keyring? ( >=gnome-base/gnome-keyring-1.0 )
	gphoto2? ( >=media-libs/libgphoto2-2.4.7 )
	udev? (
		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
		>=sys-fs/udev-145[extras] )
	hal? (
		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
		>=sys-apps/hal-0.5.10 )
	samba? ( >=net-fs/samba-3 )"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40
	>=dev-util/pkgconfig-0.19
	dev-util/gtk-doc-am
	doc? ( >=dev-util/gtk-doc-1 )"

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	if use cdda && ! use hal && ! use gudev; then
		ewarn "You have \"+cdda\", but you have \"-hal\" and \"-gudev\""
		ewarn "cdda support will NOT be built unless you enable EITHER hal OR gudev"
	fi

	G2CONF="${G2CONF}
		--enable-udev
		--enable-http
		--disable-bash-completion
		$(use_enable archive)
		$(use_enable avahi)
		$(use_enable bluetooth obexftp)
		$(use_enable cdda)
		$(use_enable fuse)
		$(use_enable gdu)
		$(use_enable gnome gconf)
		$(use_enable gphoto2)
		$(use_enable udev gudev)
		$(use_enable hal)
		$(use_enable gnome-keyring keyring)
		$(use_enable samba)"
}

src_prepare() {
	gnome2_src_prepare

	# Conditional patching purely to avoid eautoreconf
	use gphoto2 && epatch "${FILESDIR}/${PN}-1.2.2-gphoto2-stricter-checks.patch"

	if use archive; then
		epatch "${FILESDIR}/${PN}-1.2.2-expose-archive-backend.patch"
		echo "mount-archive.desktop.in" >> po/POTFILES.in
		echo "mount-archive.desktop.in.in" >> po/POTFILES.in
	fi

	use gphoto2 || use archive && eautoreconf
}

src_install() {
	gnome2_src_install
	use bash-completion && \
		dobashcompletion programs/gvfs-bash-completion.sh ${PN}
}

pkg_postinst() {
	gnome2_pkg_postinst
	use bash-completion && bash-completion_pkg_postinst

	ewarn "In order to use the new gvfs services, please reload dbus configuration"
}