[gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.22.2.ebuild ChangeLog glib-2.18.4-r1.ebuild glib-2.18.4-r2.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.22.2.ebuild ChangeLog glib-2.18.4-r1.ebuild glib-2.18.4-r2.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/10/29 21:20:49

  Modified:             ChangeLog
  Added:                glib-2.22.2.ebuild
  Removed:              glib-2.18.4-r1.ebuild glib-2.18.4-r2.ebuild
  Log:
  New version for GNOME 2.28. Clean up old revisions.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.383                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.383&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.383&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.382&r2=1.383

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.382
retrieving revision 1.383
diff -u -r1.382 -r1.383
--- ChangeLog	26 Oct 2009 18:04:06 -0000	1.382
+++ ChangeLog	29 Oct 2009 21:20:48 -0000	1.383
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.382 2009/10/26 18:04:06 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.383 2009/10/29 21:20:48 eva Exp $
+
+*glib-2.22.2 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  -files/glib-2.18.1-gdesktopappinfo-memleak-fix.patch,
+  -glib-2.18.4-r1.ebuild, -glib-2.18.4-r2.ebuild,
+  -files/glib-2.18.4-gcc44.patch, -files/glib-2.20.1-gio-unref.patch,
+  +glib-2.22.2.ebuild:
+  New version for GNOME 2.28. Clean up old revisions.
 
   26 Oct 2009; Raúl Porcel <armin76@gentoo.org> glib-2.20.5.ebuild:
   ia64/m68k/s390/sh/sparc stable wrt #285586



1.1                  dev-libs/glib/glib-2.22.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.22.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.22.2.ebuild?rev=1.1&content-type=text/plain

Index: glib-2.22.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.22.2.ebuild,v 1.1 2009/10/29 21:20:48 eva Exp $

EAPI="2"

inherit gnome.org libtool eutils flag-o-matic

DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="debug doc fam hardened selinux xattr"

RDEPEND="virtual/libc
	virtual/libiconv
	xattr? ( sys-apps/attr )
	fam? ( virtual/fam )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.16
	>=sys-devel/gettext-0.11
	doc? (
		>=dev-libs/libxslt-1.0
		>=dev-util/gtk-doc-1.11
		~app-text/docbook-xml-dtd-4.1.2 )"

src_prepare() {
	if use ppc64 && use hardened ; then
		replace-flags -O[2-3] -O1
		epatch "${FILESDIR}/glib-2.6.3-testglib-ssp.patch"
	fi

	if use ia64 ; then
		# Only apply for < 4.1
		local major=$(gcc-major-version)
		local minor=$(gcc-minor-version)
		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
		fi
	fi

	# Don't fail gio tests when ran without userpriv, upstream bug 552912
	# This is only a temporary workaround, remove as soon as possible
	epatch "${FILESDIR}/${PN}-2.18.1-workaround-gio-test-failure-without-userpriv.patch"

	# Fix gmodule issues on fbsd; bug #184301
	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch

	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
}

src_configure() {
	local myconf

	epunt_cxx

	# Building with --disable-debug highly unrecommended.  It will build glib in
	# an unusable form as it disables some commonly used API.  Please do not
	# convert this to the use_enable form, as it results in a broken build.
	# -- compnerd (3/27/06)
	use debug && myconf="--enable-debug"

	# Always build static libs, see #153807
	# Always use internal libpcre, bug #254659
	econf ${myconf}                 \
		  $(use_enable xattr)       \
		  $(use_enable doc man)     \
		  $(use_enable doc gtk-doc) \
		  $(use_enable fam)         \
		  $(use_enable selinux)     \
		  --enable-static           \
		  --enable-regex            \
		  --with-pcre=internal      \
		  --with-threads=posix
}

src_install() {
	emake DESTDIR="${D}" install || die "Installation failed"

	# Do not install charset.alias even if generated, leave it to libiconv
	rm -f "${D}/usr/lib/charset.alias"

	dodoc AUTHORS ChangeLog* NEWS* README || die "dodoc failed"
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	export XDG_CONFIG_DIRS=/etc/xdg
	export XDG_DATA_DIRS=/usr/local/share:/usr/share
	export XDG_DATA_HOME=${T}
	emake check || die "tests failed"
}