[gentoo-commits] gentoo-x86 commit in app-misc/gramps: ChangeLog gramps-3.1.2-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/gramps: ChangeLog gramps-3.1.2-r1.ebuild

[Christian Faulhammer (fauli)]

fauli       09/10/29 10:56:02

  Modified:             ChangeLog
  Added:                gramps-3.1.2-r1.ebuild
  Log:
  use dev-python/bsddb3 instead of internal berkdb of Python, because the latter is deprecated, see bug 286496, patch by flameeyes; ported ebuild really to EAPI 2
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.111                app-misc/gramps/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/gramps/ChangeLog?rev=1.111&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/gramps/ChangeLog?rev=1.111&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/gramps/ChangeLog?r1=1.110&r2=1.111

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v
retrieving revision 1.110
retrieving revision 1.111
diff -u -r1.110 -r1.111
--- ChangeLog	7 Oct 2009 14:45:38 -0000	1.110
+++ ChangeLog	29 Oct 2009 10:56:01 -0000	1.111
@@ -1,6 +1,14 @@
 # ChangeLog for app-misc/gramps
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v 1.110 2009/10/07 14:45:38 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/ChangeLog,v 1.111 2009/10/29 10:56:01 fauli Exp $
+
+*gramps-3.1.2-r1 (29 Oct 2009)
+
+  29 Oct 2009; Christian Faulhammer <fauli@gentoo.org>
+  +gramps-3.1.2-r1.ebuild, +files/gramps-3.1.2-use_bsddb3.patch:
+  use dev-python/bsddb3 instead of internal berkdb of Python, because the
+  latter is deprecated, see bug 286496, patch by flameeyes; ported ebuild
+  really to EAPI 2
 
   07 Oct 2009; Mounir Lamouri <volkmar@gentoo.org> gramps-3.1.1-r1.ebuild,
   gramps-3.1.2.ebuild:



1.1                  app-misc/gramps/gramps-3.1.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/gramps/gramps-3.1.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/gramps/gramps-3.1.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gramps-3.1.2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/gramps/gramps-3.1.2-r1.ebuild,v 1.1 2009/10/29 10:56:01 fauli Exp $

EAPI=2

inherit autotools eutils gnome2 python

DESCRIPTION="Genealogical Research and Analysis Management Programming System"
HOMEPAGE="http://www.gramps-project.org/"
SRC_URI="mirror://sourceforge/gramps/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gnome mozembed reports spell webkit"

RDEPEND=">=dev-lang/python-2.5
	dev-python/bsddb3
	>=dev-python/pygtk-2.10.0
	x11-misc/xdg-utils
	gnome-base/librsvg:2
	gnome? ( dev-python/libgnome-python
		dev-python/gconf-python )
	mozembed? ( dev-python/gtkmozembed-python )
	spell? ( dev-python/gtkspell-python
		dev-python/pyenchant )
	reports? ( media-gfx/graphviz )
	webkit? ( dev-python/pywebkitgtk )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/libiconv
	dev-util/pkgconfig"

DOCS="NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF} --disable-mime-install"
}

src_prepare() {
	gnome2_src_prepare
	eautoreconf

	epatch "${FILESDIR}"/${P}-use_bsddb3.patch
	# This is for bug 215944, so .pyo/.pyc files don't get into the
	# file system
	mv "${S}"/py-compile "${S}"/py-compile.orig
	ln -s $(type -P true) "${S}"/py-compile

	python_version

	# Fix install path.
	einfo "Fix installation path"
	find . -iname 'Makefile.in' | xargs \
		sed "s;\(pkgdatadir = \)\(\$(datadir)\);\1$(python_get_sitedir);" -i \
		|| die

	sed "s;\$(prefix)/share/gramps;/$(python_get_sitedir)/@PACKAGE@;" \
		-i src/Makefile.in || die

	sed "s;\$(prefix)/share/gramps;/$(python_get_sitedir)/@PACKAGE@;" \
	-i src/docgen/Makefile.in || die

	einfo "Fix wrapper script"
	sed "s;@datadir@;$(python_get_sitedir);" \
		-i gramps.sh.in || die

	einfo "Fix icon location"
	sed "s;gramps/;pixmap/;g" -i data/gramps.keys.in || die
}

src_install() {
	python_need_rebuild
	gnome2_src_install
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_version
	python_mod_optimize $(python_get_sitedir)/${PN}
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_version
	python_mod_cleanup $(python_get_sitedir)/${PN}
}