* [gentoo-commits] gentoo-x86 commit in net-fs/samba-libs: ChangeLog samba-libs-3.3.8.ebuild
@ 2009-10-02 13:55 Patrick Lauer (patrick)
0 siblings, 0 replies; 3+ messages in thread
From: Patrick Lauer (patrick) @ 2009-10-02 13:55 UTC (permalink / raw
To: gentoo-commits
patrick 09/10/02 13:55:05
Modified: ChangeLog
Added: samba-libs-3.3.8.ebuild
Log:
Bump
(Portage version: 2.2_rc42/cvs/Linux x86_64)
Revision Changes Path
1.7 net-fs/samba-libs/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?r1=1.6&r2=1.7
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog 30 Sep 2009 20:09:26 -0000 1.6
+++ ChangeLog 2 Oct 2009 13:55:05 -0000 1.7
@@ -1,6 +1,11 @@
# ChangeLog for net-fs/samba-libs
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.6 2009/09/30 20:09:26 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.7 2009/10/02 13:55:05 patrick Exp $
+
+*samba-libs-3.3.8 (02 Oct 2009)
+
+ 02 Oct 2009; Patrick Lauer <patrick@gentoo.org> +samba-libs-3.3.8.ebuild:
+ Bump
30 Sep 2009; Jeroen Roovers <jer@gentoo.org> samba-libs-3.3.7.ebuild:
Marked ~hppa (bug #285952).
1.1 net-fs/samba-libs/samba-libs-3.3.8.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.1&content-type=text/plain
Index: samba-libs-3.3.8.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v 1.1 2009/10/02 13:55:05 patrick Exp $
EAPI="2"
inherit pam confutils versionator multilib
MY_P="samba-${PV}"
DESCRIPTION="Libraries from Samba"
HOMEPAGE="http://www.samba.org/"
SRC_URI="mirror://samba/${MY_P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc64 ~x86"
IUSE="ads aio caps cluster cups debug examples ldap pam syslog winbind"
DEPEND="dev-libs/popt
virtual/libiconv
ads? ( virtual/krb5 sys-fs/e2fsprogs )
caps? ( sys-libs/libcap )
cluster? ( dev-db/ctdb )
cups? ( net-print/cups )
debug? ( dev-libs/dmalloc )
ldap? ( net-nds/openldap )
pam? ( virtual/pam
winbind? ( dev-libs/iniparser ) )
syslog? ( virtual/logger )
!<net-fs/samba-3.3"
RDEPEND="${DEPEND}"
# Disable tests since we don't want to build that much here
RESTRICT="test"
S="${WORKDIR}/${MY_P}/source"
# TODO:
# - enable iPrint on Prefix/OSX and Darwin?
# - selftest-prefix? selftest?
CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
pkg_setup() {
confutils_use_depend_all ads ldap
}
src_prepare() {
sed -i \
-e 's|"lib32" ||' \
-e 's|if test -d "$i/$l" ;|if test -d "$i/$l" -o -L "$i/$l";|' \
configure || die "sed failed"
}
src_configure() {
local myconf
# Filter out -fPIE
[[ ${CHOST} == *-*bsd* ]] && myconf="${myconf} --disable-pie"
use hppa && myconf="${myconf} --disable-pie"
# Upstream refuses to make this configurable
use caps && export ac_cv_header_sys_capability_h=yes || export ac_cv_header_sys_capability_h=no
# Notes:
# - FAM is a plugin for the server
# - DNS-SD is only used in client/server code
# - AFS is a pw-auth-method and only used in client/server code
# - AFSACL is a server module
# - automount is only needed in conjunction with NIS and we don't have that
# anymore
# - quota-support is only needed in server-code
# - acl-support is only used in server-code
# - --without-dce-dfs and --without-nisplus-home can't be passed to configure but are disabled by default
econf ${myconf} \
--sysconfdir=/etc/samba \
--localstatedir=/var \
$(use_enable debug developer) \
--enable-largefile \
--enable-socket-wrapper \
--enable-nss-wrapper \
--disable-swat \
$(use_enable debug dmalloc) \
$(use_enable cups) \
--disable-iprint \
--disable-fam \
--enable-shared-libs \
--disable-dnssd \
--disable-avahi \
--with-fhs \
--with-privatedir=/var/lib/samba/private \
--with-rootsbindir=/var/cache/samba \
--with-lockdir=/var/cache/samba \
--with-swatdir=/usr/share/doc/${PF}/swat \
--with-configdir=/etc/samba \
--with-logfilebase=/var/log/samba \
--with-pammodulesdir=$(getpam_mod_dir) \
--without-afs \
--without-fake-kaserver \
--without-vfs-afsacl \
$(use_with ldap) \
$(use_with ads) \
$(use_with ads krb5 /usr) \
$(use_with ads dnsupdate) \
--without-automount \
--without-cifsmount \
--without-cifsupcall \
$(use_with pam) \
$(use_with pam pam_smbpass) \
$(use_with syslog) \
--without-quotas \
--without-sys-quotas \
--without-utmp \
--with-lib{talloc,tdb,netapi,smbclient,smbsharemodes} \
--without-libaddns \
$(use_with cluster ctdb /usr) \
$(use_with cluster cluster-support) \
--without-acl-support \
$(use_with aio aio-support) \
--with-sendfile-support \
$(use_with winbind) \
--without-included-popt \
--without-included-iniparser
}
src_compile() {
emake libs pam_modules nss_modules || die "emake failed"
}
src_install() {
emake DESTDIR="${D}" installlibs || die "emake installlibs failed"
if use pam ; then
emake DESTDIR="${D}" installpammodules || die "emake installpammodules failed"
fi
# Remove empty installation directories
rmdir \
"${D}/usr/$(get_libdir)/samba" \
"${D}/usr"/{sbin,bin} \
"${D}/usr/share"/{man,locale,} \
"${D}/var"/{run,lib/samba/private,lib/samba,lib,cache/samba,cache,} \
|| die "tried to remove non-empty dirs, this seems like a bug in the ebuild"
# Nsswitch extensions. Make link for wins and winbind resolvers
if use winbind ; then
dolib.so nsswitch/libnss_wins.so
dosym libnss_wins.so /usr/$(get_libdir)/libnss_wins.so.2
dolib.so nsswitch/libnss_winbind.so
dosym libnss_winbind.so /usr/$(get_libdir)/libnss_winbind.so.2
fi
if use pam ; then
if use winbind ; then
newpamd "${CONFDIR}/system-auth-winbind.pam" system-auth-winbind
doman ../docs/manpages/pam_winbind.7
dohtml ../docs/htmldocs/manpages/pam_winbind.7.html
if use examples ; then
insinto /usr/share/doc/${PF}/examples
doins -r ../examples/pam_winbind
fi
fi
newpamd "${CONFDIR}/samba.pam" samba
dodoc pam_smbpass/README
fi
if use examples ; then
insinto /usr/share/doc/${PF}/examples
doins -r ../examples/libsmbclient
use winbind && doins -r ../examples/nss
fi
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-fs/samba-libs: ChangeLog samba-libs-3.3.8.ebuild
@ 2009-10-11 12:01 Petteri Raty (betelgeuse)
0 siblings, 0 replies; 3+ messages in thread
From: Petteri Raty (betelgeuse) @ 2009-10-11 12:01 UTC (permalink / raw
To: gentoo-commits
betelgeuse 09/10/11 12:01:23
Modified: ChangeLog samba-libs-3.3.8.ebuild
Log:
Add blockers for collision with sys-libs/tdb and sys-libs/talloc. Fixes bug #288545.
(Portage version: 2.2_rc45/cvs/Linux i686)
Revision Changes Path
1.13 net-fs/samba-libs/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?r1=1.12&r2=1.13
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog 11 Oct 2009 11:11:06 -0000 1.12
+++ ChangeLog 11 Oct 2009 12:01:23 -0000 1.13
@@ -1,6 +1,11 @@
# ChangeLog for net-fs/samba-libs
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.12 2009/10/11 11:11:06 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.13 2009/10/11 12:01:23 betelgeuse Exp $
+
+ 11 Oct 2009; Petteri Räty <betelgeuse@gentoo.org>
+ samba-libs-3.3.8.ebuild:
+ Add blockers for collision with sys-libs/tdb and sys-libs/talloc. Fixes
+ bug #288545.
11 Oct 2009; Patrick Lauer <patrick@gentoo.org> samba-libs-3.4.2.ebuild:
Enable smbclient by default, used by most dependencies
1.3 net-fs/samba-libs/samba-libs-3.3.8.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?r1=1.2&r2=1.3
Index: samba-libs-3.3.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- samba-libs-3.3.8.ebuild 9 Oct 2009 17:21:09 -0000 1.2
+++ samba-libs-3.3.8.ebuild 11 Oct 2009 12:01:23 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v 1.2 2009/10/09 17:21:09 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v 1.3 2009/10/11 12:01:23 betelgeuse Exp $
EAPI="2"
@@ -27,7 +27,9 @@
pam? ( virtual/pam
winbind? ( dev-libs/iniparser ) )
syslog? ( virtual/logger )
- !<net-fs/samba-3.3"
+ !<net-fs/samba-3.3
+ !sys-libs/tdb
+ !sys-libs/talloc"
RDEPEND="${DEPEND}"
# Disable tests since we don't want to build that much here
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-fs/samba-libs: ChangeLog samba-libs-3.3.8.ebuild
@ 2009-10-24 11:20 Tobias Klausmann (klausman)
0 siblings, 0 replies; 3+ messages in thread
From: Tobias Klausmann (klausman) @ 2009-10-24 11:20 UTC (permalink / raw
To: gentoo-commits
klausman 09/10/24 11:20:46
Modified: ChangeLog samba-libs-3.3.8.ebuild
Log:
Keyworded on alpha, bug #285952
(Portage version: 2.1.7.1/cvs/Linux x86_64)
Revision Changes Path
1.19 net-fs/samba-libs/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/ChangeLog?r1=1.18&r2=1.19
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog 23 Oct 2009 17:32:54 -0000 1.18
+++ ChangeLog 24 Oct 2009 11:20:45 -0000 1.19
@@ -1,6 +1,10 @@
# ChangeLog for net-fs/samba-libs
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.18 2009/10/23 17:32:54 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/ChangeLog,v 1.19 2009/10/24 11:20:45 klausman Exp $
+
+ 24 Oct 2009; Tobias Klausmann <klausman@gentoo.org>
+ samba-libs-3.3.8.ebuild:
+ Keyworded on alpha, bug #285952
*samba-libs-3.4.2-r3 (23 Oct 2009)
1.4 net-fs/samba-libs/samba-libs-3.3.8.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild?r1=1.3&r2=1.4
Index: samba-libs-3.3.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- samba-libs-3.3.8.ebuild 11 Oct 2009 12:01:23 -0000 1.3
+++ samba-libs-3.3.8.ebuild 24 Oct 2009 11:20:45 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v 1.3 2009/10/11 12:01:23 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba-libs/samba-libs-3.3.8.ebuild,v 1.4 2009/10/24 11:20:45 klausman Exp $
EAPI="2"
@@ -13,7 +13,7 @@
SRC_URI="mirror://samba/${MY_P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
-KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc64 ~x86"
IUSE="ads aio caps cluster cups debug examples ldap pam syslog winbind"
DEPEND="dev-libs/popt
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2009-10-24 11:20 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-10-24 11:20 [gentoo-commits] gentoo-x86 commit in net-fs/samba-libs: ChangeLog samba-libs-3.3.8.ebuild Tobias Klausmann (klausman)
-- strict thread matches above, loose matches on Subject: below --
2009-10-11 12:01 Petteri Raty (betelgeuse)
2009-10-02 13:55 Patrick Lauer (patrick)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox